I_CHGRECDREFRECIPETP

CDS View

Change Record Object Reference Recipe

I_CHGRECDREFRECIPETP is a CDS View in S/4HANA. Change Record Object Reference Recipe. It contains 5 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 5 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ChangeRecordObjPgRecipe view from CONSUMPTION Change Record Reference Obj Page Recipe

Fields (5)

KeyField CDS FieldsUsed in Views
Recipe Recipe 1
RecipeAlternativeNumber RecipeAlternativeNumber 1
RecipePrimaryOutput RecipePrimaryOutput 1
RecipePrimaryOutputInternalID RecipePrimaryOutputInternalID 1
RecipeVersionNumber RecipeVersionNumber 1 
@AbapCatalog.sqlViewName: 'ICHGRECREFRCPTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@EndUserText.label: 'Change Record Object Reference Recipe'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
semanticKey: ['RecipePrimaryOutput'],
                writeDraftPersistence: 'PLMCRREFRCP_D',
                createEnabled : 'EXTERNAL_CALCULATION',
                deleteEnabled : 'EXTERNAL_CALCULATION',
                updateEnabled : 'EXTERNAL_CALCULATION'
              }
@AccessControl.personalData.blocking: #NOT_REQUIRED

define view I_ChgRecdRefRecipeTP
  as select from           I_ChgRecdRefRecipeBsc as reference_rcp
    left outer to one join I_Recipe              as _recipe on reference_rcp.ChangeRecordRefObjectUUID = _recipe.RecipeUUID

  association [1..1] to I_ChangeRecordDraftTP      as _ChangeRecord             on $projection.ChangeRecordUUID = _ChangeRecord.ChangeRecordUUID

  association [1..1] to I_SpecificationNonHistoric as _SpecificationNonHistoric on $projection.RecipePrimaryOutputInternalID = _SpecificationNonHistoric.SpecificationInternalID

  association [0..1] to E_ChgRecdRefRecipeBsc      as _RecipeExtension          on $projection.ChangeRecordReferenceUUID = _RecipeExtension.ChangeRecordReferenceUUID

{
  key ChangeRecordReferenceUUID,
      _recipe.RecipeUUID,
      // should not be used

      _recipe.Recipe       as Recipe,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      case
      when _SpecificationNonHistoric.Specification is null then cast(substring( reference_rcp.ChangeRecordReference, 1, 12) as /plmb/rcp_prim_output_id)
      else cast(_SpecificationNonHistoric.Specification as /plmb/rcp_prim_output_id)
        end                as RecipePrimaryOutput,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      case
      when _recipe.RecipeAlternativeNumber is null then  cast(substring( reference_rcp.ChangeRecordReference, 13, 3) as /plmb/rcp_alt_no)
      else cast(_recipe.RecipeAlternativeNumber as /plmb/rcp_alt_no)
             end           as RecipeAlternativeNumber,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      case
      when _recipe.RecipeVersionNumber is null then cast (substring( reference_rcp.ChangeRecordReference, 16, 3) as /plmb/rcp_vers_no)
      else cast(_recipe.RecipeVersionNumber as /plmb/rcp_vers_no)
             end           as RecipeVersionNumber,
      // should not be used

      cast('' as esesubid) as Specification,
      _recipe.RecipePrimaryOutputInternalID,
      reference_rcp.ChangeRecordUUID,
      reference_rcp.ChangeRecord,
      reference_rcp.ChangeRecordType,
      reference_rcp.ChangeRecordReferenceType,
      reference_rcp.ChangeRecordReferenceSubtype,
      reference_rcp.ChangeRecordReference,
      reference_rcp.ParentChangeRecordRefUUID,
      reference_rcp.IsMainReference, 
      ChgRecdReasonForChange,
      ExpdCompltnDte,
      ChgRecdAuthznGrpText,
      ChgRecdNmbrChgSts,
      ChangeNumber,
      @Semantics.user.createdBy: true
      @ObjectModel.readOnly: true
      reference_rcp.CreatedByUser,
      reference_rcp.CreationDateTime,
      @Semantics.user.lastChangedBy: true
      @ObjectModel.readOnly: true
      reference_rcp.LastChangedByUser,
      reference_rcp.LastChangeDateTime,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      reference_rcp.ChangeRecordItemRelevance,
      reference_rcp.ChangeRecordVirtualRefInd,
      reference_rcp.ChangeRecordRefObjectUUID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      reference_rcp.ChangeRecordItemProcgStatus,
      @ObjectModel.readOnly: true
      reference_rcp.ChgRecdCurrentItemProcgStatus,
      @ObjectModel.readOnly: true
      reference_rcp.ChgRecdItmTgtSts,
      @ObjectModel.readOnly: true
      reference_rcp.ChgRecdItmDSgntr,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ChangeRecord
}   
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHGRECDREFRECIPEBSC",
"I_RECIPE",
"I_SPECIFICATIONNONHISTORIC"
],
"ASSOCIATED":
[
"E_CHGRECDREFRECIPEBSC",
"I_CHANGERECORDDRAFTTP",
"I_SPECIFICATIONNONHISTORIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More