I_CHGRECDREFRATERTGTSKLISTTP

CDS View

Chg Red Ref Rate Route Task List - TP

I_CHGRECDREFRATERTGTSKLISTTP is a CDS View in S/4HANA. Chg Red Ref Rate Route Task List - TP. It contains 3 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 3 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ChgRecdRefRateRtgTskList view from CONSUMPTION Change Recrd Obj Ref Rate Rout Task List

Fields (3)

KeyField CDS FieldsUsed in Views
BillOfOperationsGroup BillOfOperationsGroup 1
BillOfOperationsType BillOfOperationsType 1
BillOfOperationsVariant BillOfOperationsVariant 1 
@AbapCatalog.sqlViewName: 'ICRREFRRTTP'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Chg Red Ref Rate Route Task List - TP'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL

@ObjectModel: { semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
                writeDraftPersistence: 'PLMCRREFRRT_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
define view I_ChgRecdRefRateRtgTskListTP
  as select from           I_ChgRecdRefRateRtgTskListBsc as RefRateRtgTaskListReference
    left outer to one join I_BillOfOperations            as RefRateRtgTaskList on  RefRateRtgTaskListReference.ChgRecRefInternalKey1 = RefRateRtgTaskList.BillOfOperationsType
                                                                               and RefRateRtgTaskListReference.ChgRecRefInternalKey2 = RefRateRtgTaskList.BillOfOperationsGroup
                                                                               and RefRateRtgTaskListReference.ChgRecRefInternalKey3 = RefRateRtgTaskList.BillOfOperationsVariant

  association [1..1] to I_ChangeRecordDraftTP         as _ChangeRecordTP              on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefRateRtgTskListBsc as _RefRateRtgTaskListExtension on $projection.ChangeRecordReferenceUUID = _RefRateRtgTaskListExtension.ChangeRecordReferenceUUID
{
  key   RefRateRtgTaskListReference.ChangeRecordReferenceUUID,
        case
           when RefRateRtgTaskList.BillOfOperationsType is null then cast(SUBSTRING( RefRateRtgTaskListReference.ChangeRecordReference, 1, 1) as plnty)
           else cast(RefRateRtgTaskList.BillOfOperationsType as plnty)
           end                          as BillOfOperationsType,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
        when RefRateRtgTaskList.BillOfOperationsGroup is null then  cast(SUBSTRING( RefRateRtgTaskListReference.ChangeRecordReference, 2, 9) as plnnr)
        else cast(RefRateRtgTaskList.BillOfOperationsGroup as plnnr)
        end                             as BillOfOperationsGroup,

        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        case
         when RefRateRtgTaskList.BillOfOperationsVariant is null then cast (SUBSTRING( RefRateRtgTaskListReference.ChangeRecordReference, 10, 2) as plnal)
         else cast(RefRateRtgTaskList.BillOfOperationsVariant as plnal)
         end                            as BillOfOperationsVariant,

        //  deprecated,should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,
        // deprecated,  should not be used

        cast ('00000000' as plantext )  as BillOfOperationsDesc,

        RefRateRtgTaskListReference.ChangeRecordUUID,
        RefRateRtgTaskListReference.ChangeRecordReferenceType,
        RefRateRtgTaskListReference.ChangeRecordReferenceSubtype,
        RefRateRtgTaskListReference.ChangeRecordRefObjectUUID,
        RefRateRtgTaskListReference.ChangeRecordReference,
        RefRateRtgTaskListReference.ParentChangeRecordRefUUID,
        RefRateRtgTaskListReference.IsMainReference,
        ChgRecdReasonForChange,
        ExpdCompltnDte,
        ChgRecdAuthznGrpText,
        ChgRecdNmbrChgSts,
        
        @Semantics.user.createdBy: true
        @ObjectModel.readOnly: true
        RefRateRtgTaskListReference.CreatedByUser,
        RefRateRtgTaskListReference.CreationDateTime,
        @Semantics.user.lastChangedBy: true
        @ObjectModel.readOnly: true
        RefRateRtgTaskListReference.LastChangedByUser,
        RefRateRtgTaskListReference.LastChangeDateTime,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        RefRateRtgTaskListReference.ChangeRecordItemRelevance,
        RefRateRtgTaskListReference.ChangeRecordVirtualRefInd,
        @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
        RefRateRtgTaskListReference.ChangeRecordItemProcgStatus,
        @ObjectModel.readOnly: true
        RefRateRtgTaskListReference.ChgRecdCurrentItemProcgStatus,
        RefRateRtgTaskListReference.ChangeNumber,
         @ObjectModel.readOnly: true
        RefRateRtgTaskListReference.ChgRecdItmTgtSts,
         @ObjectModel.readOnly: true
        RefRateRtgTaskListReference.ChgRecdItmDSgntr,        
        @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
        _ChangeRecordTP
}
where
     RefRateRtgTaskList.BillOfOperationsType = 'M'
  or RefRateRtgTaskList.BillOfOperationsType is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHGRECDREFRATERTGTSKLISTBSC"
],
"ASSOCIATED":
[
"E_CHGRECDREFRATERTGTSKLISTBSC",
"I_CHANGERECORDDRAFTTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More