I_CHGRECDREFBOM

CDS View

Change Record Reference BOM

I_CHGRECDREFBOM is a CDS View in S/4HANA. Change Record Reference BOM. It contains 16 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 16 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_ChangeRecordReferenceBOMTP view from TRANSACTIONAL Change Record Reference Object BOM
I_ChangeRecordReferenceBOMTP_2 view from TRANSACTIONAL Change Record Reference Object BOM

Fields (16)

KeyField CDS FieldsUsed in Views
BillOfMaterialVariant BillOfMaterialVariant 2
BillOfMaterialVariantUsage BillOfMaterialVariantUsage 2
ChangeNumber ChangeNumber 1
ChangeNumberValidFromDate ChangeNumberValidFromDate 1
ChangeRecordRefObjectUUID ChangeRecordRefObjectUUID 2
ChgRecdAuthznGrpText ChgRecdAuthznGrpText 1
ChgRecdCurrentItemProcgStatus ChgRecdCurrentItemProcgStatus 1
ChgRecdNmbrChgSts ChgRecdNmbrChgSts 1
ChgRecdReasonForChange ChgRecdReasonForChange 1
CreatedByUser CreatedByUser 2
CreationDateTime CreationDateTime 2
ExpdCompltnDte ExpdCompltnDte 1
LastChangeDateTime LastChangeDateTime 1
LastChangedByUser LastChangedByUser 2
Material Material 2
Plant Plant 2 
@AbapCatalog.sqlViewName: 'ICHGRECDREFBOM'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Change Record Reference BOM'
define view I_ChgRecdRefBOM
  as select from I_ChgRecdRefBOMDataMigrtn
  association [0..1] to I_ChangeRecordItemValidity as _ChangeRecord on $projection.ChangeRecordUUID = _ChangeRecord.ChangeRecordUUID
  association [0..1] to I_ChangeMaster             as _ChangeMaster on $projection.ChangeNumber = _ChangeMaster.ChangeNumber // Line item Change Number

  association [0..1] to I_CalendarDate             as _calendar     on _calendar.CalendarDate = $session.system_date
{
  key ChangeRecordReferenceUUID,
      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      case
        when Material is null then cast(substring( ChangeRecordReference, 1, 40) as matnr)
        else cast(Material as matnr)
        end                       as Material,

      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      case
       when Plant is null then  cast(substring( ChangeRecordReference, 41, 4) as werks_d)
       else cast(Plant as werks_d)
       end                        as Plant,

      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      case
       when BillOfMaterialVariantUsage is null then cast (substring( ChangeRecordReference, 45, 1) as stlan)
       else cast(BillOfMaterialVariantUsage as stlan)
       end                        as BillOfMaterialVariantUsage,

      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      case
       when BillOfMaterialVariant is null then cast(substring( ChangeRecordReference, 46, 2) as stalt)
       else cast(BillOfMaterialVariant as stalt)
       end                        as BillOfMaterialVariant,
      //@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'

      case
         when _ChangeMaster.ChangeNumber is not initial
         then _ChangeMaster.ChangeNumberValidFromDate
         when _ChangeRecord.ChangeNumber is not initial
         then _ChangeRecord.ChangeNumberValidFromDate
         else _calendar.CalendarDate
         end                      as ChangeNumberValidFromDate,

      BillOfMaterial,
      BillOfMaterialCategory,
      ChangeRecord,
      ChangeRecordUUID,
      ChangeRecordReferenceType,
      ChangeRecordReferenceSubtype,
      ParentChangeRecordRefUUID,
      IsMainReference,
      ChangeRecordReference,
      ChgRecRefInternalKey1,
      ChgRecRefInternalKey2,
      ChgRecRefInternalKey3,
      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      LastChangeDateTime,
      ChangeRecordVirtualRefInd,
      ChangeRecordItemRelevance,
      ChangeRecordRefObjectUUID,
      ChangeRecordItemProcgStatus,
      ChangeRecordItemProcgStatus as ChgRecdCurrentItemProcgStatus,
      ChangeNumber,
      ChgRecdItmTgtSts,
      ChgRecdItmDSgntr,
      ChgRecdReasonForChange,
      ExpdCompltnDte,
      ChgRecdAuthznGrpText,
      ChgRecdNmbrChgSts,
      ChangeRecordLifecycleStatus,
      ChangeRecordStatus

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CALENDARDATE",
"I_CHANGEMASTER",
"I_CHANGERECORDITEMVALIDITY",
"I_CHGRECDREFBOMDATAMIGRTN"
],
"ASSOCIATED":
[
"I_CALENDARDATE",
"I_CHANGEMASTER",
"I_CHANGERECORDITEMVALIDITY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More