I_CHGRECDCMNTTOPTP

CDS View

Change Record Comment - TP

I_CHGRECDCMNTTOPTP is a CDS View in S/4HANA. Change Record Comment - TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ChgRecdCmntTop view from CONSUMPTION Change Record Comment 
@AbapCatalog.sqlViewName: 'ICHGRECDCOMTP'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
                semanticKey: ['ChgRecordCommentaryUUID'],
                writeDraftPersistence: 'PLMCRCOMM_D',
                createEnabled,
                deleteEnabled,
                updateEnabled
              }
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Change Record Comment - TP'

@ObjectModel.usageType: { serviceQuality: #C,
                          dataClass: #MIXED,
                          sizeCategory: #XXL}

define view I_ChgRecdCmntTopTP
  as select from I_ChgRecdCmntBsc as com
  association [1..1] to I_ChangeRecordDraftTP    as _ChangeRecord             on $projection.ChangeRecordUUID = _ChangeRecord.ChangeRecordUUID
  association [0..*] to I_ChgRecdCmntChildRcrsTP as _ChildComment             on $projection.ChgRecordCommentaryUUID = _ChildComment.ChgRecordParentCommentUUID
  association [0..1] to I_UserContactCard        as _CommentLastChangedByUser on $projection.ChgRecordLastChgByUserName = _CommentLastChangedByUser.ContactCardID
  association [0..1] to I_UserContactCard        as _CommentCreatedByUser     on $projection.ChgRecordCreatedByUserName = _CommentCreatedByUser.ContactCardID
{
  key ChangeRecordCommentUUID as ChgRecordCommentaryUUID,
      ChangeRecordUUID,
      ChgRecordParentCommentUUID,
      ChgRecordIsHierarchyTop,
      ChgRecordCommentText,
      @Semantics.user.createdBy: true
      @ObjectModel.foreignKey.association: '_CommentCreatedByUser'
      ChgRecordCreatedByUserName,
      _CommentCreatedByUser.FullName as CreatedByUserFullName,
      _CommentCreatedByUser,
      ChgRecordCreatedDateTime,
      @Semantics.user.lastChangedBy: true
      @ObjectModel.foreignKey.association: '_CommentLastChangedByUser'
      ChgRecordLastChgByUserName,
      _CommentLastChangedByUser.FullName as LastChangedByUserFullName,
      _CommentLastChangedByUser,
      ChgRecordLastChgDateTime,
      ChgRecordDeletedFlagValue,
      ChgRecordChangeableFlagValue,
      ChangeRecordLifecycleStatus,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _ChangeRecord,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _ChildComment


}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHGRECDCMNTBSC",
"I_USERCONTACTCARD"
],
"ASSOCIATED":
[
"I_CHANGERECORDDRAFTTP",
"I_CHGRECDCMNTCHILDRCRSTP",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More