I_CHANGERECDREFMSTRRECIPETP_2

CDS View

Change Record Reference Object Master Recipe

I_CHANGERECDREFMSTRRECIPETP_2 is a CDS View in S/4HANA. Change Record Reference Object Master Recipe. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_ChangeRecordRefMasterRecipe view_entity from COMPOSITE Master Recipe Assignments to Change Records 
@AbapCatalog.sqlViewName: 'ICRECREFMRCPTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #TRANSACTIONAL
@EndUserText.label: 'Change Record Reference Object Master Recipe'
@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass: #MIXED,
                          sizeCategory: #XXL}
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
define view I_ChangeRecdRefMstrRecipeTP_2
  as select distinct from  I_ChgRecdRefMasterRecipeBsc as reference_mrcp
    left outer to one join I_BillOfOperations          as MasterRecipe on  reference_mrcp.ChgRecRefInternalKey1 = MasterRecipe.BillOfOperationsType
                                                                       and reference_mrcp.ChgRecRefInternalKey2 = MasterRecipe.BillOfOperationsGroup
                                                                       and reference_mrcp.ChgRecRefInternalKey3 = MasterRecipe.BillOfOperationsVariant

  association        to parent I_ChangeRecordTP_2   as _ChangeRecordAPITP     on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID
  association [0..1] to E_ChgRecdRefMasterRecipeBsc as _MasterRecipeExtension on $projection.ChangeRecordReferenceUUID = _MasterRecipeExtension.ChangeRecordReferenceUUID
{
  key   reference_mrcp.ChangeRecordReferenceUUID,
        reference_mrcp.ChangeRecord,
        case
        when MasterRecipe.BillOfOperationsType is null then cast(SUBSTRING( reference_mrcp.ChangeRecordReference, 1, 1) as plnty)
        else cast(MasterRecipe.BillOfOperationsType as plnty)
        end                             as BillOfOperationsType,

        case
        when MasterRecipe.BillOfOperationsGroup is null then  cast(SUBSTRING( reference_mrcp.ChangeRecordReference, 2, 9) as plnnr)
        else cast(MasterRecipe.BillOfOperationsGroup as plnnr)
        end                             as MasterRecipeGroup,

        case
         when MasterRecipe.BillOfOperationsVariant is null then cast (SUBSTRING( reference_mrcp.ChangeRecordReference, 10, 2) as plnal)
         else cast(MasterRecipe.BillOfOperationsVariant as plnal)
         end                            as MasterRecipe,

        // deprecated,  should not be used

        cast ('00000000' as cim_count ) as BOOInternalVersionCounter,

        reference_mrcp.ChangeRecordUUID,
        reference_mrcp.ChangeRecordReferenceType,
        reference_mrcp.ChangeRecordReferenceSubtype,
        reference_mrcp.ChangeRecordRefObjectUUID,
        reference_mrcp.ChangeRecordReference,
        reference_mrcp.ParentChangeRecordRefUUID,
        reference_mrcp.IsMainReference,
        reference_mrcp.CreatedByUser,
        reference_mrcp.CreationDateTime,
        reference_mrcp.LastChangedByUser,
        reference_mrcp.LastChangeDateTime,
        reference_mrcp.ChangeRecordItemRelevance,
        reference_mrcp.ChangeRecordVirtualRefInd,
        reference_mrcp.ChangeRecordItemProcgStatus,
        _ChangeRecordAPITP
}
where
     MasterRecipe.BillOfOperationsType = '2'
  or MasterRecipe.BillOfOperationsType is null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_CHGRECDREFMASTERRECIPEBSC"
],
"ASSOCIATED":
[
"E_CHGRECDREFMASTERRECIPEBSC",
"I_CHANGERECORDTP_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More