I_CHANGERECDREFCHARCTP_2

CDS View

Change Record Ref Object Characteristic

I_CHANGERECDREFCHARCTP_2 is a CDS View in S/4HANA. Change Record Ref Object Characteristic. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_ChangeRecordRefCharc view_entity from COMPOSITE Characteristic Assignments to Change Records 
@AbapCatalog.sqlViewName: 'ICHGRECREFCHRTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Change Record Ref Object Characteristic'
define view I_ChangeRecdRefCharcTP_2
  as select from           I_ChangeRecordRefCharcBsc as reference_charc

    left outer to one join I_ClfnCharcBasic          as Characteristic on  reference_charc.ChgRecRefInternalKey1 =  Characteristic.Characteristic
                                                                       and reference_charc.ChgRecRefInternalKey2 =  Characteristic.ChangeNumber
                                                                       and reference_charc.ChgRecRefInternalKey3 =  Characteristic.CharcDataType
                                                                       and Characteristic.Characteristic         <> ''

  association [1..1] to I_ChangeRecordDraftTP     as _ChangeRecordTP    on $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID

  association [0..1] to E_ChangeRecordRefCharcBsc as _CharcExtension    on $projection.ChangeRecordReferenceUUID = _CharcExtension.ChangeRecordReferenceUUID
  association        to parent I_ChangeRecordTP_2 as _ChangeRecordAPITP on $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID
{
  key        ChangeRecordReferenceUUID,


             case
               when Characteristic.Characteristic is null then cast(SUBSTRING( reference_charc.ChangeRecordReference, 1, 30) as atnam)
               else cast(Characteristic.Characteristic as atnam)
               end as Characteristic,


             case
              when Characteristic.ChangeNumber is null then  cast(SUBSTRING( reference_charc.ChangeRecordReference, 31, 12) as aennr)
              else cast(Characteristic.ChangeNumber as aennr)
              end  as ChangeNumber,


             case
              when Characteristic.CharcDataType is null then  cast(SUBSTRING( reference_charc.ChangeRecordReference, 43, 4) as atfor)
              else cast(Characteristic.CharcDataType as atfor)
              end  as CharcDataType,

             Characteristic.CharcStatus,
             Characteristic.ValidityStartDate,
             Characteristic.CharcInternalID,
             Characteristic.CharcDecimals,
             Characteristic.CharcLength,
             Characteristic.CharcValueUnit,

             reference_charc.ChangeRecord,
             reference_charc.ChangeRecordUUID,
             reference_charc.ChangeRecordReferenceType,
             reference_charc.ChangeRecordReferenceSubtype,
             reference_charc.ChangeRecordReference,
             reference_charc.ParentChangeRecordRefUUID,
             reference_charc.IsMainReference,

             reference_charc.CreatedByUser,
             reference_charc.CreationDateTime,
             reference_charc.LastChangedByUser,
             reference_charc.LastChangeDateTime,


             reference_charc.ChangeRecordItemRelevance,
             reference_charc.ChangeRecordVirtualRefInd,
             reference_charc.ChangeRecordRefObjectUUID,
             reference_charc.ChangeRecordItemProcgStatus,

             _ChangeRecordAPITP,
             _ChangeRecordTP


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGERECORDREFCHARCBSC",
"I_CLFNCHARCBASIC"
],
"ASSOCIATED":
[
"E_CHANGERECORDREFCHARCBSC",
"I_CHANGERECORDDRAFTTP",
"I_CHANGERECORDTP_2"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More