I_CASHFLOW

@VDM.viewType: #BASIC
@Analytics: { dataCategory: #FACT, dataExtraction.enabled: false }
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'ICSHFLW'
@AbapCatalog.preserveKey:true
@EndUserText.label: 'Cash Flow'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
define view I_CashFlow
  as select from P_CashFlowCombn as flow
  association [1..1] to I_CompanyCode                  as _CompanyCode       on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_CompanyCode                  as _SourceCompanyCode on  $projection.SourceCompanyCode = _SourceCompanyCode.CompanyCode
  association [0..1] to I_BankAccount                  as _BankAccount       on  $projection.BankAccountInternalID = _BankAccount.BankAccountInternalID
  association [0..1] to I_Currency                     as _Currency          on  $projection.TransactionCurrency = _Currency.Currency
  association [0..1] to I_CashPlanningGroup            as _CashPlanningGroup on  $projection.CashPlanningGroup = _CashPlanningGroup.CashPlanningGroup
  association [0..1] to I_PlanningLevel                as _PlanningLevel     on  $projection.PlanningLevel = _PlanningLevel.PlanningLevel
  association [0..1] to I_LiquidityItem                as _LiquidityItem     on  $projection.LiquidityItem = _LiquidityItem.LiquidityItem
  association [0..1] to I_Glaccountwithaccountcurrency as _GLAccount         on  $projection.CompanyCode = _GLAccount.CompanyCode
                                                                             and $projection.GLAccount   = _GLAccount.GLAccount
  association [0..1] to I_WBSElementByInternalKey      as _WBSElement        on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [0..1] to I_AccountingDocument           as _AccountingDocument on $projection.CompanyCode = _AccountingDocument.CompanyCode
                                                                             and $projection.FiscalYear = _AccountingDocument.FiscalYear
                                                                             and $projection.AccountingDocument = _AccountingDocument.AccountingDocument

{
  key flow.OriginSystem,
  key flow.OriginApplication,
  key flow.OriginDocument,
  key flow.OriginTransaction,
  key flow.OriginTransQualifier                                                                                                                     as OriginTransactionQualifier,
  key flow.CashFlow,
  @Semantics.systemDateTime.createdAt: true
  key cast( flow.ValidFrom as timestampl )                                                                                                          as ValidFrom,
  @Semantics.systemDateTime.lastChangedAt: true
  key cast( flow.ValidTo as timestampl )                                                                                                            as ValidTo,

      // general fields

      flow.flow_id                                                                                                                                  as CashFlowID,
      flow.IsValid,
      flow.CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      cast( flow.CreationDateTime as timestampl )                                                                                                   as CreationDateTime,
      flow.LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      cast( flow.LastChangeDateTime as timestampl )                                                                                                 as LastChangeDateTime,
      flow.Owner                                                                                                                                    as CashTransactionOwner,
      @ObjectModel.foreignKey.association: '_CompanyCode'
      flow.CompanyCode,
      flow.TransactionDate,
      flow.CertaintyLevel,
      @Semantics.currencyCode: true
      flow.TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      @DefaultAggregation: #SUM
      flow.AmountInTransactionCurrency,
      @Semantics.currencyCode: true
      flow.CompanyCodeCurrency,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      @DefaultAggregation: #SUM
      flow.AmountInCompanyCodeCurrency,
      case when _BankAccount._BankAccountCurrency.BankAccountCurrency is not null and _BankAccount._BankAccountCurrency.BankAccountCurrency <> ''
      then _BankAccount._BankAccountCurrency.BankAccountCurrency
      when _GLAccount.GLAccountCurrency is not null and _GLAccount.GLAccountCurrency <> ''
      then _GLAccount.GLAccountCurrency
      else TransactionCurrency end                                                                                                                  as BankAccountCurrency,
      flow.rel_status                                                                                                                               as CashReleaseStatus,

      // accouting fields

      @ObjectModel.foreignKey.association: '_AccountingDocument'
      flow.AccountingDocument,
      flow.AccountingDocumentItem,
      flow.FiscalYear,
      flow.FiscalPeriod                                                                                                                             as PostingFiscalPeriod,
      flow.AccountingDocumentType,
      flow.PaymentMethod,
      @ObjectModel.foreignKey.association: '_GLAccount'
      flow.GLAccount,
      flow.FinancialAccountType,
      flow.DocumentItemText,
      flow.PostingDate,
      flow.ValueDate,
      flow.fi_due_date                                                                                                                              as NetDueDate,
      @ObjectModel.foreignKey.association: '_CashPlanningGroup'
      flow.CashPlanningGroup,
      @ObjectModel.foreignKey.association: '_PlanningLevel'
      flow.PlanningLevel,

      // bank fields

      flow.HouseBank,
      flow.HouseBankAccount,
      @ObjectModel.foreignKey.association: '_BankAccount'
      flow.BankAccountInternalID,

      // account assignment

      flow.Customer,
      flow.Vendor                                                                                                                                   as Supplier,
      flow.BusinessPartner,
      flow.Material,
      flow.BusinessArea,
      flow.ProfitCenter,
      @ObjectModel.foreignKey.association: '_WBSElement'
      WBSElementInternalID,
      _WBSElement.WBSElement,
      flow.PartnerCompany,
      flow.CostCenter,
      flow.Segment,
      @ObjectModel.foreignKey.association: '_LiquidityItem'
      flow.LiquidityItem,
      flow.SourceCompanyCode,
      flow.Fund,
      flow.GrantID,

      // trm fields

      flow.ProductType                                                                                                                              as FinancialInstrumentProductType,
      flow.FinancialTransactionType,
      flow.SecurityClass,
      flow.TrmSecurityAccount                                                                                                                       as SecurityAccount,
      flow.ContractNumber                                                                                                                           as AssetContract,
      flow.Portfolio,
      
      // memo record fields

      flow.ExpirationDate, 
      cast( flow.BankStatementShortKey as kukey_eb )                                                                                                as BankStatementShortID,
      flow.BankStatementItem,

      /* Associations */
      _CompanyCode,
      _BankAccount,
      _Currency,
      _CashPlanningGroup,
      _PlanningLevel,
      _LiquidityItem,
      _GLAccount,
      _WBSElement,
      _SourceCompanyCode,
      _AccountingDocument
}
where flow.cmm_state = '0' or flow.cmm_state = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANKACCOUNT",
"I_BANKACCOUNTCURRENCY",
"I_GLACCOUNTWITHACCOUNTCURRENCY",
"I_WBSELEMENTBYINTERNALKEY",
"P_CASHFLOWCOMBN"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENT",
"I_BANKACCOUNT",
"I_CASHPLANNINGGROUP",
"I_COMPANYCODE",
"I_CURRENCY",
"I_GLACCOUNTWITHACCOUNTCURRENCY",
"I_LIQUIDITYITEM",
"I_PLANNINGLEVEL",
"I_WBSELEMENTBYINTERNALKEY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/