I_CALCDEFRESULTHEADER

CDS View

Calculation Definition - Result Header

I_CALCDEFRESULTHEADER is a CDS View in S/4HANA. Calculation Definition - Result Header. It contains 11 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 11 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_EHSCalcDefResultHeaderDEX view_entity from CONSUMPTION Calculation Header Data Extraction
I_EHSAmountsForActivity view inner COMPOSITE Amounts for Activity
I_EHSDataSet view union COMPOSITE Data Sets
I_EnvrmtAmountsForActivity view inner COMPOSITE Amounts for Activities

Fields (11)

KeyField CDS FieldsUsed in Views
KEY CalculationResultHeaderUUID CalculationResultHeaderUUID,EHSComplianceScenActivityUUID 2
_EHSDataPeriod _EHSDataPeriod 1
_EHSLocation _EHSLocation 1
CalculationResultHeaderID CalculationResultHeaderID,EHSComplianceScenActivityID 2
CalculationResultHeaderName CalculationResultHeaderName,EHSClassifiedDataName 2
CalculationResultHeaderTitle CalculationResultHeaderTitle,EHSClassifiedDataTitle,EHSComplianceScenActivityTitle 3
DataUsagePeriodicity DataUsagePeriodicity 2
EHSCalculationSetupName EHSComplianceScenActivityName 1
EHSLocationUUID EHSLocationUUID 3
EHSSubjectType EHSSubjectType 1
EHSSubjectUUID EHSSubjectUUID 1 
@AbapCatalog.sqlViewName: 'ICDEFRESH'
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.preserveKey:true
@VDM.viewType: #BASIC
@EndUserText.label: 'Calculation Definition - Result Header'

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@AccessControl.authorizationCheck: #NOT_REQUIRED

define view I_CalcDefResultHeader
  as select from ehenvd_cdef_resh as cdef_resh
  association [1..1] to I_EHSCalculationDefinitionRoot as _EHSCalculationDefinitionRoot on _EHSCalculationDefinitionRoot.CalculationRootUUID = cdef_resh.parent_key
  association [0..1] to I_User                as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [0..1] to I_UnitOfMeasure       as _UnitText          on $projection.UnitOfMeasureName = _UnitText.UnitOfMeasure
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [1..1] to I_EHSLocationRevision as _EHSLocation       on $projection.EHSLocationUUID     = _EHSLocation.EHSLocationUUID
                                                                    and(
                                                                      _EHSLocation.RevisionStartDate   <= $session.system_date
                                                                      and _EHSLocation.RevisionEndDate >= $session.system_date
                                                                    )
  association [0..1] to I_EHSDataPeriod as _EHSDataPeriod           on $projection.DataUsagePeriodicity = _EHSDataPeriod.EHSDataPeriod
{
  key cdef_resh.db_key                                                                as  CalculationResultHeaderUUID,
      cdef_resh.parent_key                                                            as  CalculationRootUUID,

      cdef_resh.datetime_cr                                                           as  CreationDateTime,
      cdef_resh.user_id_cr                                                            as  CreatedByUser,
      _CreatedByUser,

      cdef_resh.datetime_ch                                                           as  LastChangeDateTime,
      cdef_resh.user_id_ch                                                            as  LastChangedByUser,
      _LastChangedByUser,

      id                                                                              as  CalculationResultHeaderID,
      cdef_resh.name                                                                  as  CalculationResultHeaderName,
      _EHSCalculationDefinitionRoot.EHSCalculationSetupName,
      title                                                                           as  CalculationResultHeaderTitle,
      cast ( cdef_resh.usage_period as ehfnd_calc_usage_period_nc preserving type )   as  DataUsagePeriodicity,

      subject_type_code                                                               as  EHSSubjectType,
      subject_root_key_ref                                                            as  EHSSubjectUUID,

      _EHSCalculationDefinitionRoot.EHSCalcMigrationSource,

      @ObjectModel.foreignKey.association: '_EHSLocation'
      cast( cdef_resh.loc_root_key_ref as ehfnd_location_uuid_ref preserving type )   as  EHSLocationUUID,
      _EHSLocation,

      @Semantics.unitOfMeasure
      @ObjectModel.foreignKey.association: '_UnitText'
      unit                                                                            as  UnitOfMeasureName,
      _UnitText,
      _EHSDataPeriod,
      _EHSCalculationDefinitionRoot
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EHSCALCULATIONDEFINITIONROOT",
"EHENVD_CDEF_RESH"
],
"ASSOCIATED":
[
"I_EHSCALCULATIONDEFINITIONROOT",
"I_EHSDATAPERIOD",
"I_EHSLOCATIONREVISION",
"I_UNITOFMEASURE",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More