I_COLLCUSTDSPUTCOCODEASSGMT

CDS View

Customers Company Code Assignment

I_COLLCUSTDSPUTCOCODEASSGMT is a CDS View in S/4HANA. Customers Company Code Assignment. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_CollCustDsputCoCodeAssgmt view_entity projection CONSUMPTION Company Code assignment 
@AbapCatalog: { sqlViewName: 'ICLSCSTDSPCMPCD',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText: { label: 'Customers Company Code Assignment' }
@VDM: { viewType:  #COMPOSITE,
        lifecycle: { contract: { type: #PUBLIC_LOCAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #C,
                             sizeCategory: #S,
                             dataClass: #MIXED },
                semanticKey: [ 'CompanyCode' ],
                representativeKey: 'CompanyCode' }

define root view I_CollCustDsputCoCodeAssgmt
  as select distinct from P_CollsAccountCollsSegment
    inner join            I_CollsSgmtCompanyCodeAssgmt  on P_CollsAccountCollsSegment.CollectionSegment = I_CollsSgmtCompanyCodeAssgmt.CollectionSegment
    inner join            I_CustomerCompany             on  I_CollsSgmtCompanyCodeAssgmt.CompanyCode = I_CustomerCompany.CompanyCode
                                                        and P_CollsAccountCollsSegment.Customer      = I_CustomerCompany.Customer
    inner join            I_DsputCaseCompanyCodeDfltVal on I_CustomerCompany.CompanyCode = I_DsputCaseCompanyCodeDfltVal.CompanyCode

  // VDM Associations

  // Customer

  association [0..1] to I_Customer          as _Customer          on $projection.Customer = _Customer.Customer

  // Company Code

  association [0..1] to I_CompanyCode       as _CompanyCode       on $projection.CompanyCode = _CompanyCode.CompanyCode

  // Business Partner

  association [0..1] to I_BusinessPartner   as _BusinessPartner   on $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  // Collection Segment

  association [0..1] to I_CollectionSegment as _CollectionSegment on $projection.CollectionSegment = _CollectionSegment.CollectionSegment

{

      // VDM Fields

  key P_CollsAccountCollsSegment.Customer          as Customer,
  key P_CollsAccountCollsSegment.CollectionSegment as CollectionSegment,
  key I_DsputCaseCompanyCodeDfltVal.CompanyCode    as CompanyCode,
      P_CollsAccountCollsSegment.BusinessPartner   as BusinessPartner,

      // Exposed Associations

      _Customer,
      _CompanyCode,
      _CollectionSegment,
      _BusinessPartner

}

where
  OriginType = '000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COLLSSGMTCOMPANYCODEASSGMT",
"I_CUSTOMERCOMPANY",
"I_DSPUTCASECOMPANYCODEDFLTVAL",
"P_COLLSACCOUNTCOLLSSEGMENT"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_COLLECTIONSEGMENT",
"I_COMPANYCODE",
"I_CUSTOMER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More