I_CAINVCGREQUEST

@AbapCatalog.sqlViewName: 'ICAINV_TRIG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Fakturierungsaufträge'
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_CAInvcgRequest
  as select from dfkkinv_trig
  association [0..1] to I_BusinessPartner           as _BusinessPartner           on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_ContractAccountHeader     as _ContractAccountHeader     on  $projection.ContractAccount = _ContractAccountHeader.ContractAccount
  association [0..1] to I_ContractAccountHeader     as _AltvContractAccountHeader on  $projection.AltvContractAcctForCollvBills = _AltvContractAccountHeader.ContractAccount

  association [0..1] to I_CAInvcgSourceDocCat       as _CAInvcgSourceDocCat       on  $projection.CAInvcgSourceDocumentCat = _CAInvcgSourceDocCat.CAInvcgSourceDocumentCat
  association [0..1] to I_CAInvcgCategory           as _CAInvcgCategory           on  $projection.CAInvcgCategory = _CAInvcgCategory.CAInvcgCategory
  association [0..1] to I_CAInvcgSourceDocType      as _CAInvcgSourceDocType      on  $projection.CAInvcgSourceDocumentType = _CAInvcgSourceDocType.CAInvcgSourceDocumentType
                                                                                  and $projection.CAInvcgSourceDocumentCat  = _CAInvcgSourceDocType.CAInvcgSourceDocumentCat
  association [0..1] to I_CAInvcgTargetProc         as _CAInvcgTargetProc         on  $projection.CAInvcgTargetProcess = _CAInvcgTargetProc.CAInvcgTargetProcess
  association [0..1] to I_CAInvcgDocTechDocType     as _CAInvcgDocTechDocType     on  $projection.CAInvcgTechnicalDocumentType = _CAInvcgDocTechDocType.CAInvcgTechnicalDocumentType
  association [0..1] to I_CAApplicationArea         as _CAApplicationArea         on  $projection.CAApplicationArea = _CAApplicationArea.CAApplicationArea
  association [0..1] to I_CASubApplication          as _CASubApplication          on  $projection.CASubApplication = _CASubApplication.CASubApplication
  association [0..1] to I_CAInvcgMasterDataType     as _CAInvcgMasterDataType     on  $projection.CAInvcgMasterDataType = _CAInvcgMasterDataType.CAInvcgMasterDataType
  association [0..1] to I_CABillgDocOriginProcess   as _CABillgDocOriginProcess   on  $projection.CABillgDocOriginProcess = _CABillgDocOriginProcess.CABillgDocOriginProcess
  association [0..1] to I_CAInvcgCorrectionCat      as _CAInvcgCorrectionCat      on  $projection.CAInvcgCorrectionCategory = _CAInvcgCorrectionCat.CAInvcgCorrectionCategory
  association [0..1] to I_CAInvcgControlOfInvcgUnit as _CAInvcgControlOfInvcgUnit on  $projection.CAInvcgControlOfInvoicingUnit = _CAInvcgControlOfInvcgUnit.CAInvcgControlOfInvoicingUnit
  association [0..1] to I_CACompanyCode             as _CACompanyCode             on  $projection.CompanyCode = _CACompanyCode.CompanyCode
  association [0..1] to I_Division                  as _Division                  on  $projection.Division = _Division.Division
  association [0..1] to I_Currency                  as _TransactionCurrency       on  $projection.TransactionCurrency = _TransactionCurrency.Currency
  association [0..1] to I_User                      as _User                      on  $projection.CAInvcgReqCreationUser = _User.UserID

{
      @ObjectModel.foreignKey.association: '_CAInvcgSourceDocCat'
  key cast(srcdoccat as srcdoccat_gfn_kk preserving type)               as CAInvcgSourceDocumentCat,
  key cast(srcdocno as srcdocno_gfn_kk preserving type)                 as CAInvcgSourceDocumentNumber,
      @ObjectModel.foreignKey.association: '_AltvContractAccountHeader'
      abwvk                                                             as AltvContractAcctForCollvBills,
      //       agrmt            as ,

      //       agrty            as ,

      @ObjectModel.foreignKey.association: '_CAApplicationArea'
      applk                                                             as CAApplicationArea,
      //       archived         as ,

      @ObjectModel.foreignKey.association: '_CACompanyCode'
      bukrs                                                             as CompanyCode,
      bupla                                                             as BusinessPlace,
      @ObjectModel.foreignKey.association: '_CAInvcgCorrectionCat'
      cast(corrcat as corrcat_gfn_kk preserving type)                   as CAInvcgCorrectionCategory,
      @Semantics.systemDate.createdAt: true
      crdate                                                            as CAInvcgReqCreationDate,
      @Semantics.user.createdBy: true
      crname                                                            as CAInvcgReqCreationUser,
      cast(date_from as bill_period_from_gfn_kk preserving type)        as CAInvcgReqStartDate,
      cast(date_to as bill_period_to_gfn_kk preserving type)            as CAInvcgReqEndDate,
      //       dummy            as ,

      //       faedn_sel        as ,

      @ObjectModel.foreignKey.association: '_BusinessPartner'
      cast(gpart as bu_partner preserving type)                         as BusinessPartner,
      //       gpart_sel        as ,

      //       gpart_srcdoc     as ,

      @ObjectModel.foreignKey.association: '_CAInvcgCategory'
      inv_category                                                      as CAInvcgCategory,
      //       invdocno_old     as ,

      invoice_basedate                                                  as CAInvcgBaseDate,
      invoice_first                                                     as CAInvcgFirstDate,
      invtriglock                                                       as CAInvcgReqIsLockedForInvoicing,
      log_system                                                        as LogicalSystem,
      //       makey            as CAMasterAgreement,

      //       mandt            as ,

      @ObjectModel.foreignKey.association: '_CAInvcgMasterDataType'
      mdcat                                                             as CAInvcgMasterDataType,
      //       process          as ,

      ptsrl                                                             as CAPartnerSettlementRule,
      recnum                                                            as CASourceDocumentNumberOfItems,
      cast(separate_inv as separate_inv_bitpack_gfn_kk preserving type) as CAInvcgControlOfInvoicingUnit,
      cast(simulated as invtrig_simulated_gfn_kk preserving type)       as CAInvcgReqIsDocumentSimulated,
      @ObjectModel.foreignKey.association: '_Division'
      spart                                                             as Division,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      srcdoc_amount                                                     as CAInvcgSourceDocumentAmount,
      @Semantics.systemDate.createdAt: true
      srcdoc_crdate                                                     as CASourceDocumentCreationDate,
      @ObjectModel.foreignKey.association: '_CAInvcgSourceDocType'
      srcdoctype                                                        as CAInvcgSourceDocumentType,
      //       srcproc_ref      as ,

      @ObjectModel.foreignKey.association: '_CABillgDocOriginProcess'
      srcprocess                                                        as CABillgDocOriginProcess,
      @ObjectModel.foreignKey.association: '_CASubApplication'
      subap                                                             as CASubApplication,
      @ObjectModel.foreignKey.association: '_CAInvcgTargetProc'
      targprocess                                                       as CAInvcgTargetProcess,
      @ObjectModel.foreignKey.association: '_CAInvcgDocTechDocType'
      cast(techdoctype as techdoctype_gfn_kk preserving type)           as CAInvcgTechnicalDocumentType,
      @ObjectModel.foreignKey.association: '_ContractAccountHeader'
      vkont                                                             as ContractAccount,
      //       vkont_sel        as ,

      //       vkont_srcdoc     as ,

      vtref                                                             as CAContract,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode: true
      waers                                                             as TransactionCurrency,

      // Make associations public

      _BusinessPartner,
      _ContractAccountHeader,
      _AltvContractAccountHeader,
      _CAInvcgSourceDocCat,
      _CAInvcgCategory,
      _CAInvcgSourceDocType,
      _CAInvcgTargetProc,
      _CAInvcgDocTechDocType,
      _CAApplicationArea,
      _CASubApplication,
      _CAInvcgMasterDataType,
      _CABillgDocOriginProcess,
      _CAInvcgCorrectionCat,
      _CAInvcgControlOfInvcgUnit,
      _CACompanyCode,
      _Division,
      _TransactionCurrency,
      _User
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DFKKINV_TRIG"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CAAPPLICATIONAREA",
"I_CABILLGDOCORIGINPROCESS",
"I_CACOMPANYCODE",
"I_CAINVCGCATEGORY",
"I_CAINVCGCONTROLOFINVCGUNIT",
"I_CAINVCGCORRECTIONCAT",
"I_CAINVCGDOCTECHDOCTYPE",
"I_CAINVCGMASTERDATATYPE",
"I_CAINVCGSOURCEDOCCAT",
"I_CAINVCGSOURCEDOCTYPE",
"I_CAINVCGTARGETPROC",
"I_CASUBAPPLICATION",
"I_CONTRACTACCOUNTHEADER",
"I_CURRENCY",
"I_DIVISION",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/