I_CABILLGREQDOCHEADER

CDS View

Abrechnungsauftrag

I_CABILLGREQDOCHEADER is a CDS View in S/4HANA. Abrechnungsauftrag. It contains 25 fields. 6 CDS views read from this table.

Used by 6 CDS view(s) 25 fields

CDS Views using this table (6)

ViewTypeJoinVDMDescription
C_CABillgReqDocName view from CONSUMPTION Formatierter Name fuer den Titel
C_CAInvcgOvwBillgReq view from CONSUMPTION Abrechnungsauftragkopf
I_CABillgReqDocHeaderTP view from TRANSACTIONAL Abrechnungsauftrag
I_CABillPrntBillgReqHeader view from COMPOSITE Abrechnungsauftrag
I_CAInvcgDocMassCreate view left_outer COMPOSITE Abrechnungsauftrag (Mass)
R_CABillgRequestTP view_entity from TRANSACTIONAL Billing Request - TP

Fields (25)

KeyField CDS FieldsUsed in Views
KEY CABillgReqDocument CABillgReqDocument 3
BusinessPartner BusinessPartner 2
CAApplicationArea CAApplicationArea 2
CABillgReqCategory CABillgReqCategory 2
CABillgReqChangeDate CABillgReqChangeDate 2
CABillgReqChangeTime CABillgReqChangeTime 2
CABillgReqChangeUser CABillgReqChangeUser 2
CABillgReqCompletionDate CABillgReqCompletionDate 2
CABillgReqCreationDate CABillgReqCreationDate 2
CABillgReqCreationTime CABillgReqCreationTime 2
CABillgReqCreationUser CABillgReqCreationUser 2
CABillgReqDescription CABillgReqDescription 2
CABillgReqNumberOfItems CABillgReqNumberOfItems 2
CABillgReqReason CABillgReqReason 2
CABillgReqReference CABillgReqReference 2
CABillgReqStatus CABillgReqStatus 2
CABillgReqTotalAmount CABillgReqTotalAmount 2
CABillgReqTotalAmountCurrency CABillgReqTotalAmountCurrency 2
CABillgReqType CABillgReqType 2
CABllbleItmListId CABllbleItmListId 2
CAClrfctnExist CAClrfctnExist 2
CADeletionDate CADeletionDate 2
CAInvoicingDocument CAInvoicingDocument 2
ContractAccount ContractAccount 2
LogicalSystem LogicalSystem 2 
@AbapCatalog.sqlViewName: 'ICABILLGREQHEAD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory: #XL,
    dataClass: #TRANSACTIONAL
  },
  representativeKey: 'CABillgReqDocument'
}

@EndUserText.label: 'Abrechnungsauftrag'
define view I_CABillgReqDocHeader
  as select from dfkkbix_req_h

  association [0..1] to I_CABillgReqStatus       as _CABillgReqStatus              on  $projection.CABillgReqStatus = _CABillgReqStatus.CABillgReqStatus
  association [0..1] to I_CABillgReqCategory     as _CABillgReqCategory            on  $projection.CABillgReqCategory = _CABillgReqCategory.CABillgReqCategory
  association [0..1] to I_CABillgReqType         as _CABillgReqType                on  $projection.CABillgReqType = _CABillgReqType.CABillgReqType
  association [0..1] to I_CABillgReqReason       as _CABillgReqReason              on  $projection.CABillgReqReason = _CABillgReqReason.CABillgReqReason
                                                                                   and $projection.CABillgReqType   = _CABillgReqReason.CABillgReqType
  association [1..1] to I_CAApplicationArea      as _CAApplicationArea             on  $projection.CAApplicationArea = _CAApplicationArea.CAApplicationArea
  association [1..1] to I_Currency               as _CABillgReqTotalAmountCurrency on  $projection.CABillgReqTotalAmountCurrency = _CABillgReqTotalAmountCurrency.Currency

  association [0..1] to I_BusinessPartner        as _BusinessPartner               on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [1..1] to I_ContractAccountHeader  as _ContractAccountHeader         on  $projection.ContractAccount = _ContractAccountHeader.ContractAccount
  association [1..1] to I_ContractAccountPartner as _ContractAccountPartner        on  $projection.ContractAccount = _ContractAccountPartner.ContractAccount
                                                                                   and $projection.BusinessPartner = _ContractAccountPartner.BusinessPartner
  association [0..1] to I_CAInvcgDocHeader       as _CAInvcgDocHeader              on  $projection.CAInvoicingDocument = _CAInvcgDocHeader.CAInvoicingDocument

{
  key billreqno                                 as CABillgReqDocument,
      @ObjectModel.foreignKey.association: '_CABillgReqCategory'
      billreqcat                                as CABillgReqCategory,
      @ObjectModel.foreignKey.association: '_CABillgReqType'
      billreqtype                               as CABillgReqType,
      @ObjectModel.foreignKey.association: '_CABillgReqReason'
      billreqrsn                                as CABillgReqReason,
      @ObjectModel.foreignKey.association: '_CAApplicationArea'
      applk                                     as CAApplicationArea,
      @ObjectModel.foreignKey.association: '_ContractAccountHeader'
      vkont                                     as ContractAccount,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
      cast(gpart as bu_partner preserving type) as BusinessPartner,
      inv_ref                                   as CAInvoicingDocument,
      billreq_descr                             as CABillgReqDescription,
      @ObjectModel.foreignKey.association: '_CABillgReqStatus'
      billreqstatus                             as CABillgReqStatus,
      @Semantics.amount.currencyCode: 'CABillgReqTotalAmountCurrency'
      @DefaultAggregation: #SUM
      billreq_total_amt                         as CABillgReqTotalAmount,
      @ObjectModel.foreignKey.association: '_CABillgReqTotalAmountCurrency'
      @Semantics.currencyCode: true
      billreq_total_curr                        as CABillgReqTotalAmountCurrency,
      billreq_total_tax_included                as CABillgReqTotalAmtTxIsIncluded,
      @Semantics.user.createdBy: true
      crname                                    as CABillgReqCreationUser,
      @Semantics.systemDate.createdAt: true
      crdate                                    as CABillgReqCreationDate,
      @Semantics.systemTime.createdAt: true
      crtime                                    as CABillgReqCreationTime,
      @Semantics.user.lastChangedBy: true
      chname                                    as CABillgReqChangeUser,
      @Semantics.systemDate.lastChangedAt: true
      chdate                                    as CABillgReqChangeDate,
      @Semantics.systemTime.lastChangedAt: true
      chtime                                    as CABillgReqChangeTime,
      cfc_exists                                as CAClrfctnExist,
      reference                                 as CABillgReqReference,
      billreq_recnum                            as CABillgReqNumberOfItems,
      log_system                                as LogicalSystem,
      bitlist_id                                as CABllbleItmListId,
      loedt                                     as CADeletionDate,
      completion_date                           as CABillgReqCompletionDate,

      _CABillgReqStatus,
      _CABillgReqCategory,
      _CABillgReqType,
      _CABillgReqReason,
      _CAApplicationArea,
      _CABillgReqTotalAmountCurrency,
      _BusinessPartner,
      _ContractAccountPartner,
      _ContractAccountHeader,
      _CAInvcgDocHeader

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DFKKBIX_REQ_H"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CAAPPLICATIONAREA",
"I_CABILLGREQCATEGORY",
"I_CABILLGREQREASON",
"I_CABILLGREQSTATUS",
"I_CABILLGREQTYPE",
"I_CAINVCGDOCHEADER",
"I_CONTRACTACCOUNTHEADER",
"I_CONTRACTACCOUNTPARTNER",
"I_CURRENCY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More