I_BUSINESSUSERTP

CDS View

Business User - Transactional Processing

I_BUSINESSUSERTP is a CDS View in S/4HANA. Business User - Transactional Processing. It contains 14 fields. 6 CDS views read from this table.

Used by 6 CDS view(s) 14 fields

CDS Views using this table (6)

ViewTypeJoinVDMDescription
C_CollaborationBusinessUserTP view from CONSUMPTION Collaboration Business User TP - Consumption View
C_EmployeeBusinessUserTP view from CONSUMPTION Employee Business User TP - Consumption View
C_ExtResourceBusinessUserTP view from CONSUMPTION External Resource Business User TP - Consumption View
C_PPM_ProjectResourceTP view from CONSUMPTION Main Consumption View for Maintain Resource
P_BPUserPrsnlAddrNmbrConcat view from CONSUMPTION Return concat ids for Change Doc
P_BPUsrRoleCustomizingType view from CONSUMPTION

Fields (14)

KeyField CDS FieldsUsed in Views
AuthorizationGroup AuthorizationGroup 2
BusinessPartner BusinessPartner 1
DataController1 DataController1 1
DataController10 DataController10 1
DataController2 DataController2 1
DataController3 DataController3 1
DataController4 DataController4 1
DataController5 DataController5 1
DataController6 DataController6 1
DataController7 DataController7 1
DataController8 DataController8 1
DataController9 DataController9 1
DataControllerSet DataControllerSet 1
IsBusinessPurposeCompleted IsBusinessPurposeCompleted 2 
@AbapCatalog.sqlViewName: 'IBUSINESSUSERTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Business User - Transactional Processing'
@VDM.viewType: #TRANSACTIONAL
@Metadata.allowExtensions: true

@ObjectModel: {
    semanticKey: ['BusinessPartner'],

    transactionalProcessingEnabled: true,
    compositionRoot:                true,
    draftEnabled:                   true,

    createEnabled: true,
    deleteEnabled: 'EXTERNAL_CALCULATION',
    updateEnabled: 'EXTERNAL_CALCULATION',

    writeDraftPersistence: 'IBUSINESSUSER_D',
    entityChangeStateId: 'LastChangeDateTime'
}
define view I_BusinessUserTP
  as select from P_BusinessUser
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_BPRelationship     as _BPRelationshipBUR025 on  $projection.BusinessPartner                = _BPRelationshipBUR025.BusinessPartnerPerson
                                                                      and _BPRelationshipBUR025.RelationshipCategory = 'BUR025'
                                                                      and _BPRelationshipBUR025.ValidityStartDate    <= $session.system_date
                                                                      and _BPRelationshipBUR025.ValidityEndDate      >= $session.system_date
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_BPRelationship     as _BPRelationshipBUR028 on  $projection.BusinessPartner                = _BPRelationshipBUR028.BusinessPartnerPerson
                                                                      and _BPRelationshipBUR028.RelationshipCategory = 'BUR028'
                                                                      and _BPRelationshipBUR028.ValidityStartDate    <= $session.system_date
                                                                      and _BPRelationshipBUR028.ValidityEndDate      >= $session.system_date
  association [0..1] to C_BPUsrRelshpBPOrgVH as _BPUsrRelShpBUR025    on  $projection.BusinessPartnerCompanyBUR025 = _BPUsrRelShpBUR025.BusinessPartner
  association [0..1] to C_BPUsrRelshpBPOrgVH as _BPUsrRelShpBUR028    on  $projection.BusinessPartnerCompanyBUR028 = _BPUsrRelShpBUR028.BusinessPartner
{
      @ObjectModel.readOnly: true
  key BusinessPartnerUUID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      P_BusinessUser.BusinessPartner                   as BusinessPartner,
      @ObjectModel.readOnly: true
      _BusinessPartnerRole.BusinessPartnerRoleCategory as BusinessPartnerRoleCategory,
      @ObjectModel.readOnly: true
      _BusinessPartnerRole.BusinessPartnerRole         as BusinessPartnerRole,      
      @ObjectModel.readOnly: true
      PersonNumber,

      // Basic Data //

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'      
      BPIdentificationNumber                           as PersonExternalID,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      FormOfAddress,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      FirstName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: true
      LastName,

      // Validity Period //

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      _BusinessPartnerRole.ValidFrom                   as ValidityStartDate,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      _BusinessPartnerRole.ValidTo                     as ValidityEndDate,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      IsMarkedForArchiving,

      // Business User //

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      UserID,
      @ObjectModel.readOnly: true
      _UserDetail.UserName                             as UserName,
      @ObjectModel.readOnly: true
      _UserDetail.UserDescription                      as UserDescription,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.foreignKey.association: '_BPUsrRelShpBUR025'
      _BPRelationshipBUR025.BusinessPartnerCompany     as BusinessPartnerCompanyBUR025,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.foreignKey.association: '_BPUsrRelShpBUR028'
      _BPRelationshipBUR028.BusinessPartnerCompany     as BusinessPartnerCompanyBUR028,

      // Contact //

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      @ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.DefaultEmailAddress            as EmailAddress,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      CorrespondenceLanguage,

      // Telephone //

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.DestinationLocationCountry     as DestinationLocationCountry,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.PhoneNumber                    as PhoneNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.PhoneNumberExtension           as PhoneNumberExtension,

      // Mobile Phone //

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.MblPhoneDestinationLocCountry  as MblPhoneDestinationLocCountry,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.MobilePhoneNumber              as MobilePhoneNumber,

      // Fax //

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.FaxNumberCountry               as FaxNumberCountry,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.FaxAreaCodeSubscriberNumber    as FaxAreaCodeSubscriberNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.FaxExtensionNumber             as FaxExtensionNumber,

      // WorkPlace Data //

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.Building                       as Building,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.RoomNumber                     as RoomNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.Department                     as Department,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      _WorkplaceAddress.FunctionalTitlename            as FunctionalTitleName,

      // Name Data //

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      AdditionalLastName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      LastNamePrefix,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      LastNameSecondPrefix,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BirthName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      NickName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      MiddleName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      AcademicTitle,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      AcademicSecondTitle,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      NameSupplement,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Initials,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      PersonFullName,

      // Other hidden fields //

      @ObjectModel.readOnly: true
      AuthorizationGroup,
      @ObjectModel.readOnly: true
      CreationDateTime,
      @ObjectModel.readOnly: true
      CreatedByUser,
      @ObjectModel.readOnly: true
      LastChangeDateTime,
      @ObjectModel.readOnly: true
      LastChangedByUser,
      @ObjectModel.readOnly: true
      IsBusinessPurposeCompleted,

      @Consumption.hidden:true
      DataControllerSet,
      @Consumption.hidden:true
      DataController1,
      @Consumption.hidden:true
      DataController2,
      @Consumption.hidden:true
      DataController3,
      @Consumption.hidden:true
      DataController4,
      @Consumption.hidden:true
      DataController5,
      @Consumption.hidden:true
      DataController6,
      @Consumption.hidden:true
      DataController7,
      @Consumption.hidden:true
      DataController8,
      @Consumption.hidden:true
      DataController9,
      @Consumption.hidden:true
      DataController10,
      
      _BPRelationshipBUR025._BusinessPartnerCompany    as _BusinessPartnerCompanyBUR025,
      _BPRelationshipBUR028._BusinessPartnerCompany    as _BusinessPartnerCompanyBUR028,

      _BPUsrRelShpBUR025,
      _BPUsrRelShpBUR028
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPRELATIONSHIP",
"I_WORKPLACEADDRESS",
"P_BPUSRDETAIL",
"P_BPUSRROLE",
"P_BUSINESSUSER"
],
"ASSOCIATED":
[
"C_BPUSRRELSHPBPORGVH",
"I_BPRELATIONSHIP",
"I_BUSINESSPARTNER"
],
"BASE":
[
"I_BPRELATIONSHIP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More