I_BUSINESSPARTNERTP
Business Partner
I_BUSINESSPARTNERTP is a CDS View in S/4HANA. Business Partner. It contains 60 fields. 3 CDS views read from this table.
CDS Views using this table (3)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_BusinessPartner | view | from | CONSUMPTION | Business Partner |
| C_BusinessPartnerCustomer | view | from | CONSUMPTION | Business Partner |
| C_BusinessPartnerSupplier | view | from | CONSUMPTION | Business Partner Supplier |
Fields (60)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | BusinessPartner | BusinessPartner | 3 |
| AcademicTitle | AcademicTitle | 3 | |
| AdditionalName | AdditionalName | 3 | |
| AuthorizationGroup | AuthorizationGroup | 3 | |
| BirthDate | BirthDate | 3 | |
| BPDataControllerIsNotRequired | BPDataControllerIsNotRequired | 3 | |
| BPFirstNameSearchHelp | BPFirstNameSearchHelp | 3 | |
| BPLastNameSearchHelp | BPLastNameSearchHelp | 3 | |
| BusinessPartnerBirthDateStatus | BusinessPartnerBirthDateStatus | 1 | |
| BusinessPartnerBirthplaceName | BusinessPartnerBirthplaceName | 3 | |
| BusinessPartnerCategory | BusinessPartnerCategory | 3 | |
| BusinessPartnerForEdit | BusinessPartnerForEdit | 3 | |
| BusinessPartnerGrouping | BusinessPartnerGrouping | 3 | |
| BusinessPartnerIDByExtSystem | BusinessPartnerIDByExtSystem | 3 | |
| BusinessPartnerIsBlocked | BusinessPartnerIsBlocked | 3 | |
| BusinessPartnerName | BusinessPartnerName | 3 | |
| BusinessPartnerType | BusinessPartnerType | 3 | |
| BusinessPartnerUUID | BusinessPartnerUUID | 3 | |
| CreatedByUser | CreatedByUser | 3 | |
| CreationDate | CreationDate | 3 | |
| CreationTime | CreationTime | 3 | |
| DataController1 | DataController1 | 3 | |
| DataController10 | DataController10 | 3 | |
| DataController2 | DataController2 | 3 | |
| DataController3 | DataController3 | 3 | |
| DataController4 | DataController4 | 3 | |
| DataController5 | DataController5 | 3 | |
| DataController6 | DataController6 | 3 | |
| DataController7 | DataController7 | 3 | |
| DataController8 | DataController8 | 3 | |
| DataController9 | DataController9 | 3 | |
| DataControllerSet | DataControllerSet | 3 | |
| FirstName | FirstName | 3 | |
| FormOfAddressOrganization | FormOfAddressOrganization | 3 | |
| FormOfAddressPerson | FormOfAddressPerson | 3 | |
| FullName | FullName | 3 | |
| GenderCodeName | GenderCodeName | 3 | |
| IndependentAddressID | IndependentAddressID | 1 | |
| Industry | Industry | 3 | |
| InternationalLocationNoPart1 | InternationalLocationNoPart1 | 3 | |
| InternationalLocationNoPart2 | InternationalLocationNoPart2 | 3 | |
| InternationalLocationNoPart3 | InternationalLocationNoPart3 | 3 | |
| IsBusinessPurposeCompleted | IsBusinessPurposeCompleted | 3 | |
| IsMarkedForArchiving | IsMarkedForArchiving | 3 | |
| IsNaturalPerson | IsNaturalPerson | 3 | |
| LastChangeDate | LastChangeDate | 3 | |
| LastChangedByUser | LastChangedByUser | 3 | |
| LastChangeTime | LastChangeTime | 3 | |
| LastName | LastName | 3 | |
| LegalForm | LegalForm | 3 | |
| Name | Name | 3 | |
| OrganizationBPName1 | OrganizationBPName1 | 3 | |
| OrganizationBPName2 | OrganizationBPName2 | 3 | |
| OrganizationBPName3 | OrganizationBPName3 | 3 | |
| OrganizationBPName4 | OrganizationBPName4 | 3 | |
| OrganizationFoundationDate | OrganizationFoundationDate | 3 | |
| OrganizationLiquidationDate | OrganizationLiquidationDate | 3 | |
| SearchTerm1 | SearchTerm1 | 3 | |
| SearchTerm2 | SearchTerm2 | 3 | |
| TradingPartner | TradingPartner | 3 |
@AbapCatalog.sqlViewName: 'IBUPATP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Business Partner'
@ObjectModel.transactionalProcessingEnabled : true
@ObjectModel.modelCategory: #BUSINESS_OBJECT
@ObjectModel.compositionRoot: true
@ObjectModel.writeDraftPersistence: 'bupa_root_d'
@ObjectModel.draftEnabled: true
@ObjectModel.semanticKey: ['BusinessPartner']
@ObjectModel.createEnabled
@ObjectModel.deleteEnabled
@ObjectModel.updateEnabled
@ObjectModel.lifecycle : {
enqueue : {
expiryBehavior :
#RELATIVE_TO_ENQUEUE_START,
expiryInterval : 'PT15M',
notificationBeforeExpiryInterval : 'PT5M'
},
processing : {
expiryBehavior :
#RELATIVE_TO_ENQUEUE_START,
expiryInterval : 'PT30M',
notificationBeforeExpiryInterval : 'PT10M'
}
}
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.entityChangeStateId: 'ETag'
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
define view I_BusinessPartnerTP
as select from I_BusinessPartner as BusinessPartner
association [0..1] to E_BP_D as _DraftExtension on $projection.BusinessPartner = _DraftExtension.BusinessPartner
association [0..1] to E_BP_D as _ActiveExtension on $projection.BusinessPartner = _ActiveExtension.BusinessPartner
association [0..1] to I_BusinessPartnerSupplierTP as _BusinessPartnerSupplier on $projection.BusinessPartner = _BusinessPartnerSupplier.BusinessPartner
association [0..1] to I_BusinessPartnerCustomerTP as _BusinessPartnerCustomer on $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner
association [0..*] to I_BusinessPartnerSuplrCoTP as _BusinessPartnerSupplierCo on $projection.BusinessPartner = _BusinessPartnerSupplierCo.BusinessPartner
association [0..*] to I_BusinessPartnerAddressTP as _BusinessPartnerAddress on $projection.BusinessPartner = _BusinessPartnerAddress.BusinessPartner
association [0..*] to I_BusinessPartnerBankTP as _BusinessPartnerBank on $projection.BusinessPartner = _BusinessPartnerBank.BusinessPartner
association [0..*] to I_BusinessPartnerTaxNumberTP as _BusinessPartnerTaxNumber on $projection.BusinessPartner = _BusinessPartnerTaxNumber.BusinessPartner
association [0..*] to I_BusinessPartnerContactTP as _BusinessPartnerContact on $projection.BusinessPartner = _BusinessPartnerContact.BusinessPartner
association [0..*] to I_BusinessPartnerPurgOrgTP as _BusinessPartnerPurgOrg on $projection.BusinessPartner = _BusinessPartnerPurgOrg.BusinessPartner
association [0..*] to I_BusinessPartnerSalesAreaTP as _BusinessPartnerSalesArea on $projection.BusinessPartner = _BusinessPartnerSalesArea.BusinessPartner
association [0..*] to I_BusinessPartnerCustCoTP as _BusinessPartnerCustomerCo on $projection.BusinessPartner = _BusinessPartnerCustomerCo.BusinessPartner
association [0..*] to I_BusinessPartnerRoleTP as _BusinessPartnerRole on $projection.BusinessPartner = _BusinessPartnerRole.BusinessPartner
association [0..*] to I_PaymentCardTP as _PaymentCard on $projection.BusinessPartner = _PaymentCard.BusinessPartner
association [0..*] to I_BuPaIdentificationTP as _BPIdentificationNumbers on $projection.BusinessPartner = _BPIdentificationNumbers.BusinessPartner
association [0..*] to I_BuPaIndustryTP as _BPIndustry on $projection.BusinessPartner = _BPIndustry.BusinessPartner
association [0..*] to I_BPUnloadingPointTP as _BusinessPartnerUnloadingPoint on $projection.BusinessPartner = _BusinessPartnerUnloadingPoint.BusinessPartner
association [0..*] to I_BPSiteReceivingPointTP as _BPCustReceivingPoint on $projection.BusinessPartner = _BPCustReceivingPoint.BusinessPartner
association [0..*] to I_BPCustRcvgPtAddrDepdntInfoTP as _BPCustRcvgPtAddrDepdntInfo on $projection.BusinessPartner = _BPCustRcvgPtAddrDepdntInfo.BusinessPartner
association [0..*] to I_BPCustDeptAddrDepdntInfoTP as _BPCustDepartmentAddrDepdnt on $projection.BusinessPartner = _BPCustDepartmentAddrDepdnt.BusinessPartner
association [0..*] to I_CustomerDepartmentTP as _CustomerDepartment on $projection.BusinessPartner = _CustomerDepartment.BusinessPartner
association [0..*] to I_BPAdditionalCustomerTP as _BPAdditionalCustomer on $projection.BusinessPartner = _BPAdditionalCustomer.BusinessPartner
association [0..*] to I_BPAdditionalSupplierTP as _BPAdditionalSupplier on $projection.BusinessPartner = _BPAdditionalSupplier.BusinessPartner
association [0..*] to I_BPSupplierTaxGroupingTP as _BPSupplierTaxGrouping on $projection.BusinessPartner = _BPSupplierTaxGrouping.BusinessPartner
association [0..*] to I_BPCustomerTaxGroupingTP as _BPCustomerTaxGrouping on $projection.BusinessPartner = _BPCustomerTaxGrouping.BusinessPartner
association [0..1] to P_BPWithEmployeeRoles as _BPWithEmployeeRoles on $projection.BusinessPartner = _BPWithEmployeeRoles.BusinessPartner
association [0..*] to I_BusinessPartnerLongTextTP as _BusinessPartnerLongText on $projection.BusinessPartner = _BusinessPartnerLongText.BusinessPartner
association [0..*] to I_BusinessPartnerCustomerTxtTP as _BusinessPartnerCustomerTxt on $projection.BusinessPartner = _BusinessPartnerCustomerTxt.BusinessPartner
association [0..*] to I_BusinessPartnerSupplierTxtTP as _BusinessPartnerSupplierTxt on $projection.BusinessPartner = _BusinessPartnerSupplierTxt.BusinessPartner
association [0..*] to I_BusPartRelationshipTP_2 as _BusPartRelationship on $projection.BusinessPartner = _BusPartRelationship.BusinessPartner1
association [0..*] to I_BPAddressIndependentPhoneTP as _BPAddressIndependentPhone on $projection.BusinessPartner = _BPAddressIndependentPhone.BusinessPartner
association [0..*] to I_BPAddressIndependentEmailTP as _BPAddressIndependentEmail on $projection.BusinessPartner = _BPAddressIndependentEmail.BusinessPartner
association [0..*] to I_BPAddressIndependentMobileTP as _BPAddressIndependentMobile on $projection.BusinessPartner = _BPAddressIndependentMobile.BusinessPartner
association [0..*] to I_BPCustAddressDependentInfoTP as _BPCustAddressDependentInfo on $projection.BusinessPartner = _BPCustAddressDependentInfo.BusinessPartner
association [0..*] to I_BPDataControllerTP as _BPDataController on $projection.BusinessPartner = _BPDataController.BusinessPartner
association [0..*] to I_BPCustUnldgPtAddrDepdntTP as _BPCustUnldgPtAddrDepdnt on $projection.BusinessPartner = _BPCustUnldgPtAddrDepdnt.BusinessPartner
association [0..*] to I_BusPartAddrDepdntTaxNmbrTP as _BusinessPartnerTaxNumberAdr on $projection.BusinessPartner = _BusinessPartnerTaxNumberAdr.BusinessPartner
association [0..*] to I_CustAddrDepdntIdentifierTP as _CustAddrDepdntExtIdentifier on $projection.BusinessPartner = _CustAddrDepdntExtIdentifier.BusinessPartner
association [0..*] to I_BPAddrDepdntIntlLocNumberTP as _BusinessPartnerAddrDepILN on $projection.BusinessPartner = _BusinessPartnerAddrDepILN.BusinessPartner
association [0..1] to I_BPEmplWorkplaceAddrTP as _BPEmplWorkplaceAddr on $projection.BusinessPartner = _BPEmplWorkplaceAddr.BusinessPartner
{
@ObjectModel.readOnly: true
key BusinessPartner.BusinessPartner as BusinessPartner,
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@Search.ranking: #HIGH
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
@ObjectModel.editableFieldFor: 'BusinessPartner'
BusinessPartner.BusinessPartner as BusinessPartnerForEdit,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.BusinessPartnerCategory,
BusinessPartner.BusinessPartnerUUID,
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@ObjectModel.readOnly: true
@Semantics.user.createdBy: true
BusinessPartner.CreatedByUser,
BusinessPartner.CreationDate,
BusinessPartner.CreationTime,
@Search.defaultSearchElement: true
@Search.fuzzinessThreshold: 0.8
@ObjectModel.readOnly: true
@Semantics.user.lastChangedBy: true
BusinessPartner.LastChangedByUser,
BusinessPartner.LastChangeDate,
BusinessPartner.LastChangeTime,
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.BusinessPartnerIsBlocked,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory:'EXTERNAL_CALCULATION'
BusinessPartner.FirstName,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.LastName,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.OrganizationBPName1,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.OrganizationBPName2,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.OrganizationBPName3,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.OrganizationBPName4,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.LegalForm,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.OrganizationFoundationDate,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.OrganizationLiquidationDate,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.Industry,
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.IsNaturalPerson,
BusinessPartner.IsMale,
BusinessPartner.IsFemale,
BusinessPartner.IsSexUnknown,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.FormOfAddress as FormOfAddressPerson,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.FormOfAddress as FormOfAddressOrganization,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
@ObjectModel.enabled: 'EXTERNAL_CALCULATION'
BusinessPartner.AcademicTitle,
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.NameFormat,
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.NameCountry,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.InternationalLocationNumber1,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.InternationalLocationNumber2,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.InternationalLocationNumber3,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
case
when BusinessPartner.InternationalLocationNumber1 = '0000000'
then cast( ' ' as bu_location1str)
else cast (BusinessPartner.InternationalLocationNumber1 as bu_location1str)
end as InternationalLocationNoPart1,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
case
when BusinessPartner.InternationalLocationNumber2 = '00000'
then cast( ' ' as bu_location2str)
else cast (BusinessPartner.InternationalLocationNumber2 as bu_location2str)
end as InternationalLocationNoPart2,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
cast( BusinessPartner.InternationalLocationNumber3 as bu_location3str ) as InternationalLocationNoPart3,
BusinessPartner.ETag,
BusinessPartner.IsBusinessPurposeCompleted,
BusinessPartner.AuthorizationGroup,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.GenderCodeName as GenderCodeName,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.BusinessPartnerGrouping,
BusinessPartner.BusinessPartnerType,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.CorrespondenceLanguage,
cast('' as ad_addrnum) as AddressID, //Deprecated for performance reasons, do not use
case when BusinessPartner.BusinessPartnerCategory = '1'
then BusinessPartner.LastName
else BusinessPartner.OrganizationBPName1
end as Name,
case when BusinessPartner.BusinessPartnerCategory = '1'
then BusinessPartner.FirstName
else BusinessPartner.OrganizationBPName2
end as AdditionalName,
case when BusinessPartner.BusinessPartnerCategory = '1'
then concat_with_space(FirstName,LastName,1)
else concat_with_space(concat_with_space(concat_with_space(OrganizationBPName1,OrganizationBPName2,1),OrganizationBPName3,1),OrganizationBPName4,1)
end as FullName,
case when BusinessPartner.BusinessPartnerCategory = '1' and BusinessPartner.BusinessPartner <> ''
then concat_with_space(FirstName,LastName,1) else
case when BusinessPartner.BusinessPartnerCategory = '2' and BusinessPartner.BusinessPartner <> ''
then concat_with_space(concat_with_space(concat_with_space(OrganizationBPName1,OrganizationBPName2,1),OrganizationBPName3,1),OrganizationBPName4,1) end
end as BusinessPartnerName,
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.SearchTerm1,
@ObjectModel.mandatory: 'EXTERNAL_CALCULATION'
BusinessPartner.SearchTerm2,
@UI.hidden: true
@Consumption.filter.hidden: true
@ObjectModel.readOnly: true
cast(' ' as abap_boolean preserving type) as AssetRedesignSwitchIsActive,
// @UI.hidden: true
// @Consumption.filter.hidden: true
// @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
// cast(' ' as abap_boolean preserving type) as BusPartAddrLayoutStdIsHidden,
BusinessPartner.BPFirstNameSearchHelp,
BusinessPartner.BPLastNameSearchHelp,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.BirthDate,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.BusinessPartnerBirthDateStatus,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.BusinessPartnerBirthplaceName,
@ObjectModel.readOnly: true
case
when _BPWithEmployeeRoles.BusinessPartner is not null
then
cast('X' as boole_d)
else
cast(' ' as boole_d)
end as BPHasEmployeeRoles,
//For ATC
cast ('' as bu_istype ) as IndustrySystemType,
_BPFinancialServicesExtn.TradingPartner,
BusinessPartner.BusinessPartnerIDByExtSystem,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
BusinessPartner.IsMarkedForArchiving,
BusinessPartner.IndependentAddressID,
@API.element.releaseState: #DEPRECATED
cast ('1' as char30 ) as DataProvider,
@API.element.releaseState: #DEPRECATED
cast (' ' as char30 ) as Score,
////////////// Start of Datacontroller 10+1 fields - Not to be consumed by any other views//////////
@UI.hidden:true
@Consumption.hidden:true
BusinessPartner.DataControllerSet,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController1,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController2,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController3,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController4,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController5,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController6,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController7,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController8,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController9,
@Consumption.hidden:true
@UI.hidden:true
BusinessPartner.DataController10,
////////////// End of Datacontroller 10+1 fields//////////
BusinessPartner.BPDataControllerIsNotRequired,
// @ObjectModel.virtualElement: true
// @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_DC_VALID_STATUS'
// cast(' ' as boolean) as DataControllerIsHidden,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerSupplier,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerCustomer,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerBank,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerTaxNumber,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerAddress,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerContact,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerSupplierCo,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerCustomerCo,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerPurgOrg,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerSalesArea,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerRole,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_PaymentCard,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPIdentificationNumbers,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPIndustry,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerUnloadingPoint,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPCustReceivingPoint,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPCustRcvgPtAddrDepdntInfo,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPCustDepartmentAddrDepdnt,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_CustomerDepartment,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPAdditionalCustomer,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPAdditionalSupplier,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPSupplierTaxGrouping,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPCustomerTaxGrouping,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerLongText,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerCustomerTxt,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerSupplierTxt,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusPartRelationship,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPAddressIndependentPhone,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPAddressIndependentEmail,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPAddressIndependentMobile,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPCustAddressDependentInfo,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPCustUnldgPtAddrDepdnt,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerTaxNumberAdr,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_CustAddrDepdntExtIdentifier,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BusinessPartnerAddrDepILN,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_BPDataController,
_AcademicTitleValueHelp,
_AcademicTitleText,
_CreatedByUser,
_LastChangedByUser,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_BPEmplWorkplaceAddr
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPFINANCIALSERVICESEXTN",
"I_BUSINESSPARTNER",
"P_BPWITHEMPLOYEEROLES"
],
"ASSOCIATED":
[
"E_BP_D",
"I_ACADEMICTITLE",
"I_ACADEMICTITLETEXT",
"I_BPADDITIONALCUSTOMERTP",
"I_BPADDITIONALSUPPLIERTP",
"I_BPADDRDEPDNTINTLLOCNUMBERTP",
"I_BPADDRESSINDEPENDENTEMAILTP",
"I_BPADDRESSINDEPENDENTMOBILETP",
"I_BPADDRESSINDEPENDENTPHONETP",
"I_BPCUSTADDRESSDEPENDENTINFOTP",
"I_BPCUSTDEPTADDRDEPDNTINFOTP",
"I_BPCUSTOMERTAXGROUPINGTP",
"I_BPCUSTRCVGPTADDRDEPDNTINFOTP",
"I_BPCUSTUNLDGPTADDRDEPDNTTP",
"I_BPDATACONTROLLERTP",
"I_BPEMPLWORKPLACEADDRTP",
"I_BPSITERECEIVINGPOINTTP",
"I_BPSUPPLIERTAXGROUPINGTP",
"I_BPUNLOADINGPOINTTP",
"I_BUPAIDENTIFICATIONTP",
"I_BUPAINDUSTRYTP",
"I_BUSINESSPARTNERADDRESSTP",
"I_BUSINESSPARTNERBANKTP",
"I_BUSINESSPARTNERCONTACTTP",
"I_BUSINESSPARTNERCUSTCOTP",
"I_BUSINESSPARTNERCUSTOMERTP",
"I_BUSINESSPARTNERCUSTOMERTXTTP",
"I_BUSINESSPARTNERLONGTEXTTP",
"I_BUSINESSPARTNERPURGORGTP",
"I_BUSINESSPARTNERROLETP",
"I_BUSINESSPARTNERSALESAREATP",
"I_BUSINESSPARTNERSUPLRCOTP",
"I_BUSINESSPARTNERSUPPLIERTP",
"I_BUSINESSPARTNERSUPPLIERTXTTP",
"I_BUSINESSPARTNERTAXNUMBERTP",
"I_BUSPARTADDRDEPDNTTAXNMBRTP",
"I_BUSPARTRELATIONSHIPTP_2",
"I_CUSTADDRDEPDNTIDENTIFIERTP",
"I_CUSTOMERDEPARTMENTTP",
"I_PAYMENTCARDTP",
"I_USER",
"P_BPWITHEMPLOYEEROLES"
],
"BASE":
[
"I_BUSINESSPARTNER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/