I_BUSINESSPARTNERPURGORG

@AbapCatalog.sqlViewName: 'IBUPAPURGORG'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Core view for Purchasing Organization'

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

/*this view is directly built on lfm1 instead of I_SupplierPurchasingOrg ,
since I_SupplierPurchasingOrg fetches purchasng organization data of bp type organization only */
define view I_BusinessPartnerPurgOrg
  as select from I_SupplierPurchasingOrg   //lfm1 replacing with I_SupplierPurchasingOrg as there is neither an association to BP nor a where clause on type 2

  association [1..1] to I_Supplier_to_BusinessPartner as _SupplierToPartner     on  $projection.Supplier = _SupplierToPartner.Supplier
  association [0..1] to E_BPPURORG_D                  as _PurgOrgExt            on  $projection.PurchasingOrganization = _PurgOrgExt.PurchasingOrganization
                                                                                and $projection.Supplier               = _PurgOrgExt.Supplier

  //Associations added for Text Annotation Removal

  association [0..1] to I_ShippingCondition           as _ShipgCndnValueHelp    on  $projection.ShippingCondition = _ShipgCndnValueHelp.ShippingCondition

  association [0..*] to I_ShippingConditionText       as _ShippingConditionText on  $projection.ShippingCondition = _ShippingConditionText.ShippingCondition
 association [1..1] to I_TransportationLocation      as _IncotermsSupChnDvtgLoc      on  $projection.IncotermsSupChnDvtgLocAddlUUID = _IncotermsSupChnDvtgLoc.LocationAdditionalUUID  /*+[hideWarning] { "IDS" : [ 
 "CALCULATED_FIELD_CHECK" ] } */
  association [1..1] to I_TransportationLocation      as _IncotermsSupChnLoc2         on  $projection.IncotermsSupChnLoc2AddlUUID = _IncotermsSupChnLoc2.LocationAdditionalUUID  /*+[hideWarning] { "IDS" : [ 
 "CALCULATED_FIELD_CHECK" ] } */
  association [1..1] to I_TransportationLocation      as _IncotermsSupChnLoc1         on  $projection.IncotermsSupChnLoc1AddlUUID = _IncotermsSupChnLoc1.LocationAdditionalUUID  /*+[hideWarning] { "IDS" : [ 
 "CALCULATED_FIELD_CHECK" ] } */
  
{
  key PurchasingOrganization,
  key _SupplierToPartner._BusinessPartner.BusinessPartner as BusinessPartner,
      _SupplierToPartner.BusinessPartnerUUID              as BusinessPartnerUUID,
      Supplier,
      PurchasingGroup,
      PlannedDeliveryDurationInDays,
      PurchasingIsBlockedForSupplier,
      SupplierRespSalesPersonName,
      ContactPersonPhoneNumber,
      @Semantics.currencyCode: true
      PurchaseOrderCurrency,
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      MinimumOrderAmount,
      CalculationSchemaGroupCode,
      PaymentTerms,
      PricingDateControl,
      SupplierABCClassificationCode,
      //@ObjectModel: {

      // foreignKey.association: '_ShipgCndnValueHelp'

      //}

      @ObjectModel.text.association: '_ShippingConditionText'
      ShippingCondition,
      PurOrdAutoGenerationIsAllowed,
      InvoiceIsGoodsReceiptBased,
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsVersion,
      IncotermsLocation1,
      IncotermsLocation2,
      //fields requested by the TM colleagues

      EvaldReceiptSettlementIsActive,
      AutomaticEvaluatedRcptSettlmt,
      SupplierAccountNumber,
      SupplierConfirmationControlKey,
      IsOrderAcknRqd,
      //_SupplierToPartner._Supplier.AuthorizationGroup,


      //For extensibility

      cast( 'X' as sdraft_is_active preserving type )     as IsActiveEntity,

       //

      SuplrIsSubjToSubsqntSettlement,
      SuplrPurgOrgAgrmtOfBusVolIsRqd,
      SuplrInvcRevalIsAllowed,
      SuplrPurgOrgIsRlvtForPriceDetn,
      IntrastatCrsBorderTrMode,
      ProductUnitGroup,
      RoundingProfile,
      PlanningCycle,

      SuplrDiscountInKindIsGranted,
      // lfm1.nrgew                                                           as SuplrDiscountInKindIsGranted,

      SuplrIsRlvtForSettlmtMgmt,
      InvoiceIsMMServiceEntryBased,
      ProdStockAndSlsDataTransfPrfl,
      EvaldRcptSettlementProfile,
      AbsoluteHandlingSurchargeAmt,
      PercentageHandlingSurchargeAmt,
      MinimumHandlingSurchargeAmt,
      MaximumHandlingSurchargeAmt,
      AutomDebitCrtnIsEnbldOnGI,
       IncotermsSupChnLoc2AddlUUID,
      IncotermsSupChnLoc1AddlUUID,
      IncotermsSupChnDvtgLocAddlUUID,
      DeletionIndicator,

      _SupplierToPartner,
      _ShipgCndnValueHelp,
      _ShippingConditionText,
        _IncotermsSupChnDvtgLoc,
      _IncotermsSupChnLoc1,
      _IncotermsSupChnLoc2
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNER",
"I_SUPPLIERPURCHASINGORG",
"I_SUPPLIER_TO_BUSINESSPARTNER"
],
"ASSOCIATED":
[
"E_BPPURORG_D",
"I_SHIPPINGCONDITION",
"I_SHIPPINGCONDITIONTEXT",
"I_SUPPLIER_TO_BUSINESSPARTNER",
"I_TRANSPORTATIONLOCATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/