I_BUSSOLNORDERITEMRATEELEMENT

CDS View

Subscription Billing Rate Elements

I_BUSSOLNORDERITEMRATEELEMENT is a CDS View in S/4HANA. Subscription Billing Rate Elements. It contains 2 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 2 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
A_BusSolnOrdItmRateElement view from COMPOSITE Subscription Billing Item Rate Elements
A_BusSolnOrdItmRateElmntPrcElm view inner COMPOSITE Item Rate Element Price Element
R_BSOrdItmRateElementTP view_entity from TRANSACTIONAL Business Solution Order Item Rate Element - TP

Fields (2)

KeyField CDS FieldsUsed in Views
KEY BusinessSolutionOrderItem BusinessSolutionOrderItem 1
KEY SubscriptionRateElement SubscriptionRateElement 1 
@EndUserText.label: 'Subscription Billing Rate Elements'

@ClientHandling.algorithm: #SESSION_VARIABLE

@AbapCatalog:{
  sqlViewName: 'IBSOSUBRATEELEM',
  compiler.compareFilter: true,
  preserveKey: true
}

@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@AccessControl:{
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}

@Metadata.ignorePropagatedAnnotations: true
define view I_BusSolnOrderItemRateElement
  as select from crms4d_ratelem_i

  association [1..1] to I_ServiceDocumentItem          as _SubscriptionBillingItem     on  _SubscriptionBillingItem.ServiceObjectType   = 'BUS2000172'
                                                                                       and _SubscriptionBillingItem.ServiceDocument     = $projection.BusinessSolutionOrder
                                                                                       and _SubscriptionBillingItem.ServiceDocumentItem = $projection.BusinessSolutionOrderItem
  association [1..1] to I_SrvcSubscrpnRateElmntType    as _SubscriptionRateElementType on  $projection.SubscriptionRateElementType = _SubscriptionRateElementType.SubscriptionRateElementType
  association [1..1] to I_SrvcSubscrpnRateElmntTypeTxt as _SubscrpnRateElementTypeText on  $projection.SubscriptionRateElementType = _SubscrpnRateElementTypeText.SubscriptionRateElementType
                                                                                       and _SubscrpnRateElementTypeText.Language   = $session.system_language
  association [0..1] to I_Currency                     as _TransactionCurrency         on  $projection.Currency = _TransactionCurrency.Currency
{
  key object_id                                                as BusinessSolutionOrder,
  key number_int                                               as BusinessSolutionOrderItem,
  key rate_element_no                                          as SubscriptionRateElementNumber,

      @ObjectModel.readOnly: true
      product_id                                               as SubscriptionRateElement,

      @ObjectModel.readOnly: true
      rating_type                                              as SubscriptionRateElementType,

      @ObjectModel.readOnly: true
      _SubscrpnRateElementTypeText.SubscrpnRateElementTypeText as SubscrpnRateElementTypeText,

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode: true
      _SubscriptionBillingItem.TransactionCurrency             as Currency,

      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'Currency'
      net_value                                                as SubscrpnRateElementNetAmount,

      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'Currency'
      gross_value                                              as SubscrpnRateElementGrossAmount,

      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'Currency'
      tax_amount                                               as SubscrpnRateElementTaxAmount,

      /* Associations */
      _SubscriptionBillingItem,
      _SubscriptionRateElementType,
      _TransactionCurrency
}
where
      objtype_h                                              = 'BUS2000172'
  and _SubscriptionBillingItem.ServiceDocumentItemObjectType = 'BUS2000189';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTITEM",
"I_SRVCSUBSCRPNRATEELMNTTYPETXT",
"CRMS4D_RATELEM_I"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_SERVICEDOCUMENTITEM",
"I_SRVCSUBSCRPNRATEELMNTTYPE",
"I_SRVCSUBSCRPNRATEELMNTTYPETXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More