I_BUDGETACCOUNTHIERARCHYNODET

CDS View

Budget Account Hierarchy Node - Text

I_BUDGETACCOUNTHIERARCHYNODET is a CDS View in S/4HANA. Budget Account Hierarchy Node - Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_BudgetAccountCoreHierNodeTxt view from COMPOSITE Budget Account Hierarchy Node Text 
@AbapCatalog.sqlViewName: 'IPSMS4CBDACHNT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Budget Account Hierarchy Node - Text'

@VDM.viewType: #BASIC
//@Analytics.dataExtraction: {enabled:true}

@ObjectModel: {
     dataCategory: #TEXT,
     representativeKey: 'HierarchyNode',
     usageType: {
         dataClass: #MASTER,
         serviceQuality: #A,
         sizeCategory: #XL
     }
}

define view I_BudgetAccountHierarchyNodeT
  as select from hrrp_nodet
    inner join   I_BudgetAccountHierarchy on  I_BudgetAccountHierarchy.BudgetAccountHierarchy = hrrp_nodet.hryid
                                          and I_BudgetAccountHierarchy.ValidityEndDate        = hrrp_nodet.hryvalto

  association [0..1] to I_Language               as _Language  on $projection.Language = _Language.Language

  association [1..*] to I_BudgetAccountHierarchy as _Hierarchy on $projection.BudgetAccountHierarchy = _Hierarchy.BudgetAccountHierarchy

{
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast( hrrp_nodet.hryid as psm_hryid_budgetaccount preserving type ) as BudgetAccountHierarchy,
  key hrrp_nodet.hrynode                                                  as HierarchyNode,
      @Semantics.businessDate.to: true
  key cast( hrrp_nodet.hryvalto as fis_datbi preserving type )            as ValidityEndDate,
      @Semantics.language: true
  key hrrp_nodet.spras                                                    as Language,
      @Semantics.text: true
      hrrp_nodet.nodetxt                                                  as HierarchyNodeText,
      @Semantics.text: true
      substring(hrrp_nodet.nodetxt, 1, 20)                                as HierarchyNodeShortText,
      @Semantics.businessDate.from: true
      cast( hrrp_nodet.hryvalfrom as fis_datab preserving type )          as ValidityStartDate,
      _Language,
      _Hierarchy

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUDGETACCOUNTHIERARCHY",
"HRRP_NODET"
],
"ASSOCIATED":
[
"I_BUDGETACCOUNTHIERARCHY",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More