I_BILLINGREQUESTITEM

CDS View

Billg Request Line for Srvc Transaction

I_BILLINGREQUESTITEM is a CDS View in S/4HANA. Billg Request Line for Srvc Transaction. It contains 7 fields. 13 CDS views read from this table.

Used by 13 CDS view(s) 7 fields

CDS Views using this table (13)

ViewTypeJoinVDMDescription
A_BSOrdSrvcContrItmBillgReqItm view from COMPOSITE Service Contract Item BRL Item
A_BusSolnOrdBillgReqItmPrcElm view inner COMPOSITE Service Contract Item BRL Price Elements
A_SrvcContrItmBillgReqItem view from COMPOSITE Billing Request Line
C_BillgReqLineObjPgPrcDets view from CONSUMPTION Billing Request Line Price Details
C_BSOrdProcFlwBillgReqItem view from CONSUMPTION Billing Req Line Attrib for BSOrd Prgrs
C_SrvcContrItmObjPgSettlmtPerd view from CONSUMPTION Settlement Periods
C_SrvcOrdBillingRequestItem view_entity from CONSUMPTION Service Order Item Billing Plan Facet
I_SubscrpnContrItmBillgReqItm view_entity from COMPOSITE Billing Request Item of Contract Item
P_BusSolnOrdSrvcContrFlwLvl2 view inner CONSUMPTION Solution Order Service Contract Flow: Level 2
P_ServiceContractIssueKey view from COMPOSITE
P_SrvcOrdBillgRequestAggrgItem view_entity from COMPOSITE Aggregation CDS for Billing Request
R_SrvcContrBillgReqItmPrcElmTP view_entity inner TRANSACTIONAL Price Element of Billing Request - TP
R_SrvcContrItmBillgReqItemTP view_entity from TRANSACTIONAL Service Contract Item Billg Request - TP

Fields (7)

KeyField CDS FieldsUsed in Views
KEY BillingRequestItem BillingRequestItem,SubsequentDocumentItem 2
KEY ServiceDocument ServiceContract 1
KEY ServiceDocumentItem BusinessSolutionOrderItem,ServiceContractItem 3
KEY ServiceObjectType ServiceObjectType 1
BillgReqItemBillingStatus BillgReqItemBillingStatus 1
BillingBlockReason BillingBlockReason 1
TransactionCurrency TransactionCurrency 1 
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Billg Request Line for Srvc Transaction'

@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@AbapCatalog: {
  sqlViewName: 'IBILLGREQITEM',
  preserveKey:true,
  compiler.compareFilter: true
}
@ObjectModel: {
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #D,
     sizeCategory:   #XXL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
}
@Metadata.ignorePropagatedAnnotations: true
//@Metadata.allowExtensions:true

//@Analytics.dataCategory: #DIMENSION


define view I_BillingRequestItem
  as select from crms4d_billreq_i
  association [1]    to I_ServiceDocumentItem      as _ServiceDocItem           on  $projection.ServiceObjectType   = _ServiceDocItem.ServiceObjectType
                                                                                and $projection.ServiceDocument     = _ServiceDocItem.ServiceDocument
                                                                                and $projection.ServiceDocumentItem = _ServiceDocItem.ServiceDocumentItem

  association [0..1] to I_BillgReqItmSettlmtStatus as _BillgReqItmSettlmtStatus on  $projection.BillgReqItemBillingStatus = _BillgReqItmSettlmtStatus.BillgReqItemBillingStatus

  association [0..1] to I_Currency                 as _TransactionCurrency      on  $projection.transactioncurrency = _TransactionCurrency.Currency
  association [1]    to I_BillingBlockReason       as _BillingBlockReason       on  $projection.BillingBlockReason = _BillingBlockReason.BillingBlockReason
{

  key objtype_h       as ServiceObjectType,
  key object_id       as ServiceDocument,
  key number_int      as ServiceDocumentItem,
  key record_no       as BillingRequestItem,

      bill_date       as BillgReqItemBillingDateTime,
      bill_settl_stat as BillgReqItemBillingStatus,
      settl_from      as SettlementStartDateTime,
      settl_to        as SettlementEndDateTime,

      _ServiceDocItem.BillingPlanTimeZone,

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      _ServiceDocItem.TransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      net_value       as BillgReqItemNetAmount,
      @ObjectModel.foreignKey.association: '_BillingBlockReason'
      billing_block   as BillingBlockReason,
      
      description as BillgReqItemDescription,
      servicesrendereddatetime as ServicesRenderedDateTime,
      price_date as BillgReqItemPricingDate,
      
      _ServiceDocItem,
      _BillgReqItmSettlmtStatus,
      _TransactionCurrency,
      _BillingBlockReason
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SERVICEDOCUMENTITEM",
"CRMS4D_BILLREQ_I"
],
"ASSOCIATED":
[
"I_BILLGREQITMSETTLMTSTATUS",
"I_BILLINGBLOCKREASON",
"I_CURRENCY",
"I_SERVICEDOCUMENTITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More