I_BILLINGPROCESSDOCUMENTTYPE

CDS View

Billing Process Document Type

I_BILLINGPROCESSDOCUMENTTYPE is a CDS View in S/4HANA. Billing Process Document Type. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
I_BillingDocumentRequestType view_entity from BASIC Billing Document Request Type
I_BillingDocumentType_2 view_entity from BASIC Billing Document Type
I_BillingProcessDocTypeStdVH view_entity from COMPOSITE Billing Process Document Type
I_InvoiceListType view_entity from BASIC Invoice List Type 
@AbapCatalog.entityBuffer.definitionAllowed: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL
@EndUserText.label: 'Billing Process Document Type'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'BillingProcessDocumentType'
@ObjectModel.sapObjectNodeType.name: 'BillingProcessDocumentType'
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #SQL_DATA_SOURCE,
                                      #SEARCHABLE_ENTITY,
                                      #EXTRACTION_DATA_SOURCE ]
@ObjectModel.usageType: { dataClass: #CUSTOMIZING, serviceQuality: #A, sizeCategory: #S }
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC

define root view entity I_BillingProcessDocumentType
  as select from tvfk

  composition of exact one to many I_BillingProcessDocTypeText  as _Text
  association              to exact one I_SDDocumentCategory    as _SDDocumentCategory           on $projection.SDDocumentCategory = _SDDocumentCategory.SDDocumentCategory
  association              to one I_BillingDocumentCategory     as _BillingDocumentCategory      on $projection.BillingDocumentCategory = _BillingDocumentCategory.BillingDocumentCategory
  association              to one I_SDDocumentTextDetnProcedure as _BillgProcDocTxtDetnProcedure on $projection.BillgProcDocTxtDetnProcedure = _BillgProcDocTxtDetnProcedure.TextDeterminationProcedure
  association              to one I_SDDocumentTextDetnProcedure as _BillgProcDocItmTxtDetnProced on $projection.BillgProcDocItmTxtDetnProced = _BillgProcDocItmTxtDetnProced.TextDeterminationProcedure

{
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @ObjectModel.text.association: '_Text'
  key cast( fkart as billingprocessdocumenttype preserving type )      as BillingProcessDocumentType,
      @ObjectModel.foreignKey.association: '_SDDocumentCategory'
      vbtyp                                                            as SDDocumentCategory,
      incpo                                                            as IncrementItemNumber,
      @ObjectModel.foreignKey.association: '_BillingDocumentCategory'
      fktyp                                                            as BillingDocumentCategory,
      @ObjectModel.foreignKey.association: '_BillgProcDocTxtDetnProcedure'
      cast( txtgr as billg_proc_doc_text_detn_head preserving type )   as BillgProcDocTxtDetnProcedure,
      @ObjectModel.foreignKey.association: '_BillgProcDocItmTxtDetnProced'
      cast( txtgr_p as billg_proc_doc_text_detn_item preserving type ) as BillgProcDocItmTxtDetnProced,

      _Text,
      _SDDocumentCategory,
      _BillingDocumentCategory,
      _BillgProcDocTxtDetnProcedure,
      _BillgProcDocItmTxtDetnProced
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"TVFK"
],
"ASSOCIATED":
[
"I_BILLINGDOCUMENTCATEGORY",
"I_BILLINGPROCESSDOCTYPETEXT",
"I_SDDOCUMENTCATEGORY",
"I_SDDOCUMENTTEXTDETNPROCEDURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More