I_BILLINGDOCREQITEMPARTNER

CDS View

Billing Document Request Item Partner

I_BILLINGDOCREQITEMPARTNER is a CDS View in S/4HANA. Billing Document Request Item Partner. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_BillingDocReqItemPartner view from COMPOSITE Item Partner 
@ClientHandling.algorithm: #SESSION_VARIABLE 
@EndUserText.label: 'Billing Document Request Item Partner'
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),  
  privilegedAssociations: [ '_Address', '_DfltAddrRprstn' ]
}
@AbapCatalog: {
  sqlViewName: 'ISDBDRQITPT',                
  compiler.compareFilter: true,
  preserveKey: true
}
@ObjectModel: {
   representativeKey: 'PartnerFunction',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]      
}
@VDM.viewType: #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true

define view I_BillingDocReqItemPartner as select from I_BillingDocItemPartnerBasic as Partner
    
    association[1..1] to I_BillingDocumentRequest     as _BillingDocumentRequest  on  $projection.BillingDocumentRequest          = _BillingDocumentRequest.BillingDocumentRequest
    association[1..1] to I_BillingDocumentRequestItem as _Item                      on  $projection.BillingDocumentRequest          = _Item.BillingDocumentRequest
                                                                                    and $projection.BillingDocumentRequestItem      = _Item.BillingDocumentRequestItem    
                                                                                                                                                                                
{
    @Consumption.valueHelpDefinition: [ 
      { entity:  { name:    'I_BillingDocumentRequestStdVH',
                   element: 'BillingDocumentRequest' }
      }]    
    @ObjectModel.foreignKey.association: '_BillingDocumentRequest'
    key cast( Partner.BillingDocument as vbeln_bdr preserving type ) as BillingDocumentRequest,
    
    @Consumption.valueHelpDefinition: [ 
      { entity:  { name:    'I_BillingDocReqItemStdVH',
                   element: 'BillingDocumentRequestItem' },
        additionalBinding: [{ localElement: 'BillingDocumentRequest',
                              element: 'BillingDocumentRequest' }]
      }]
    @ObjectModel.foreignKey.association: '_Item'                                                                                                   
    key cast( Partner.BillingDocumentItem as posnr_bdr preserving type ) as BillingDocumentRequestItem,                                                                                  
                                                 
    @ObjectModel.foreignKey.association: '_PartnerFunction'
    key cast(Partner.PartnerFunction as parvw_unv preserving type ) as PartnerFunction,    
    
    Partner.Customer,
    
    Partner.Supplier,
    
    Partner.Personnel,

    @ObjectModel.foreignKey.association: '_Address'
    Partner.AddressID,

    Partner.ReferenceBusinessPartner,
    Partner.BPRefAddressIDForDocSpcfcAddr,
    Partner.SDDocPartnerAddressRefType,
    Partner.AddressPersonID,
    
    Partner.ContactPerson,
    
    //Association

    @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]    
    _BillingDocumentRequest,
    @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]    
    _Item,
    Partner._PartnerFunction,
    Partner._Address,
    Partner._BusinessPartnerAddress,
    Partner._BPRefAddressForDocSpcfcAddr,
    Partner._DfltAddrRprstn    
}
where _BillingDocumentRequest.SDDocumentCategory = 'EBDR'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLINGDOCITEMPARTNERBASIC",
"I_BILLINGDOCUMENTREQUEST"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_ADDRESS_2",
"I_BILLINGDOCUMENTREQUEST",
"I_BILLINGDOCUMENTREQUESTITEM",
"I_BUSPARTADDRESS",
"I_PARTNERFUNCTION"
],
"BASE":
[
"I_BILLINGDOCITEMPARTNERBASIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More