I_BANKACCOUNTHIERARCHYNODE

CDS View

Bank Account Hierarchy Node

I_BANKACCOUNTHIERARCHYNODE is a CDS View in S/4HANA. Bank Account Hierarchy Node. It contains 2 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 2 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
Fclm_BankAccountGroupNode view from Nodes of Selected Bank Account Group

Fields (2)

KeyField CDS FieldsUsed in Views
BankAccountHierarchy BankAccountHierarchy 1
BankAccountInternalID BankAccountInternalID 1 
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AbapCatalog.sqlViewName: 'IFIBANKACCOUNTHN'
@EndUserText.label: 'Bank Account Hierarchy Node'
@VDM.viewType: #BASIC
@ObjectModel: { dataCategory: #HIERARCHY }
@ObjectModel.representativeKey: 'HierarchyNode'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE 
@Hierarchy.parentChild:
{
  recurse:
  {
    parent: 'ParentNode',
    child:  'HierarchyNode'
  },
  siblingsOrder:
  {
    by: 'HierarchyNode',
    direction: 'ASC'
  },

  directory : '_BankAccountHierarchy'
}
define view I_BankAccountHierarchyNode
as
select from fclm_bam_hierrt
  association[0..*] to I_BankAccountHierarchyNodeText as _Text
    on $projection.BankAccountHierarchy = _Text.BankAccountHierarchy
    and $projection.HierarchyNode = _Text.HierarchyNode
  association[0..1] to I_BankAccount as _BankAccount
    on $projection.BankAccountInternalID = _BankAccount.BankAccountInternalID
  association[0..1] to I_Bank as _Bank
    on $projection.Bank = _Bank.BankInternalID and $projection.BankCountry = _Bank.BankCountry
  association[0..1] to I_BusinessPartner as _BusinessPartner
      on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association[1..*] to I_BankAccountHierarchy as _BankAccountHierarchy
      on $projection.BankAccountHierarchy = _BankAccountHierarchy.BankAccountHierarchy                  
  association [0..1] to I_Country as _BankCountry on $projection.BankCountry = _BankCountry.Country
{
  @ObjectModel.foreignKey.association: '_BankAccountHierarchy'
  key hierid  as BankAccountHierarchy,
  @ObjectModel.text.association: '_Text'
  key nodeid  as HierarchyNode,
  @Semantics.businessDate.to: true
  key valid_to as ValidityEndDate,
  @Semantics.businessDate.from: true
  valid_from as ValidityStartDate,
  nodelevel as HierarchyNodeLevel,
  par_hiernode as ParentNode,
      //--[ GENERATED:012:E6ExH29r7kY4hHBW6NEXPW

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_BankAccountStdVH',
                     element: 'BankAccountInternalID' }
        }]
      // ]--GENERATED

  @ObjectModel.foreignKey.association: '_BankAccount'
  acc_id as BankAccountInternalID,
  @ObjectModel.foreignKey.association: '_BankCountry'
  banks as BankCountry,
      //--[ GENERATED:012:E6ExH29r7kY4hHBW6NEXPW

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_BankStdVH',
                     element: 'BankInternalID' },
          additionalBinding: [{ localElement: 'BankCountry',
                                element: 'BankCountry' }]
        }]
      // ]--GENERATED

  @ObjectModel.foreignKey.association: '_Bank'
  bankl as Bank,
      //--[ GENERATED:012:E6ExH29r7kY4hHBW6NEXPW

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_BusinessPartnerVH',
                     element: 'BusinessPartner' }
        }]
      // ]--GENERATED

  @ObjectModel.foreignKey.association: '_BusinessPartner'
  partner as BusinessPartner,
  _Text, 
  _BankAccount,
  _Bank,
  _BusinessPartner,
  _BankAccountHierarchy,
  _BankCountry
}
where hierid <> ''                                                             
  
  
  
  
  
  
  
  
  
  
  
 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FCLM_BAM_HIERRT"
],
"ASSOCIATED":
[
"I_BANK",
"I_BANKACCOUNT",
"I_BANKACCOUNTHIERARCHY",
"I_BANKACCOUNTHIERARCHYNODETEXT",
"I_BUSINESSPARTNER",
"I_COUNTRY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More