I_BR_NFTRANSPORTEDVOLUME

CDS View

Brazil Nota Fiscal Transported Volume

I_BR_NFTRANSPORTEDVOLUME is a CDS View in S/4HANA. Brazil Nota Fiscal Transported Volume. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_BR_NFTransportedVolume view from BASIC Brazil Nota Fiscal Transported Volume
I_BR_NFTransportedVolume_C view from COMPOSITE Brazil Nota Fiscal Transported Volume 
@AbapCatalog.sqlViewName: 'IBRNFTRANSPVOL'
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Brazil Nota Fiscal Transported Volume'
@VDM.viewType:#BASIC
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,#CDS_MODELING_DATA_SOURCE]
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true 
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations: true

define view I_BR_NFTransportedVolume
  as select from j_1bnftransvol as NFTransportedVolume
  association [0..1] to I_UnitOfMeasure as _BR_NFTransptVolNetWeightUnit on $projection.BR_NFTransptVolNetWeightUnit = _BR_NFTransptVolNetWeightUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure as _BR_NFTransptVolGrossWgtUnit  on $projection.BR_NFTransptVolGrossWgtUnit = _BR_NFTransptVolGrossWgtUnit.UnitOfMeasure
  
{
  key NFTransportedVolume.docnum                                                   as BR_NotaFiscal,
  key NFTransportedVolume.counter                                                  as BR_NFTransptVolumesSequence,
      
      cast(NFTransportedVolume.qvol as logbr_trans_vol_quan preserving type)       as BR_NFTransportedVolumeQtyVal,
            
      cast(NFTransportedVolume.esp as logbr_trans_vol_type preserving type)        as BR_NFTransportedVolumeType,
      cast(NFTransportedVolume.marca as logbr_trans_vol_trademark preserving type) as BR_NFTransptVolumeTrademark,
      cast(NFTransportedVolume.nvol as logbr_trans_vol_number preserving type)     as BR_NFTransportedVolumeID,
      
      @Semantics.unitOfMeasure: true
      cast('KG' as msehi)                                                          as BR_NFTransptVolNetWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'BR_NFTransptVolNetWeightUnit'
      @DefaultAggregation: #NONE
      cast(NFTransportedVolume.pesol as logbr_trans_vol_net preserving type)       as BR_NFTransptVolumeNetWeight,
      
      @Semantics.unitOfMeasure: true
      cast('KG' as msehi)                                                          as BR_NFTransptVolGrossWgtUnit,
      @Semantics.quantity.unitOfMeasure: 'BR_NFTransptVolGrossWgtUnit'
      @DefaultAggregation: #NONE
      cast(NFTransportedVolume.pesob as logbr_trans_vol_gross preserving type)     as BR_NFTransptVolumeGrossWeight,
      
      NFTransportedVolume.nlacre                                                   as BR_NFTransportedVolumeSeal,
      
      _BR_NFTransptVolNetWeightUnit,
      _BR_NFTransptVolGrossWgtUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"J_1BNFTRANSVOL"
],
"ASSOCIATED":
[
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More