I_BR_NFFUEL

@AbapCatalog.sqlViewName: 'IBRNFFUEL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Brazil Nota Fiscal Fuel'
@VDM.viewType:#BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,#CDS_MODELING_DATA_SOURCE]
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.ignorePropagatedAnnotations:true

define view I_BR_NFFuel
  as select from j_1bnffuel as NFFuel
  association [0..1] to I_UnitOfMeasure as _BR_NFPercentageNaturalGasUnit on $projection.BR_NFPercentageNaturalGasUnit = _BR_NFPercentageNaturalGasUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure as _BR_GLPRatioUnit               on $projection.BR_GLPRatioUnit = _BR_GLPRatioUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure as _BR_GLGNNRatioUnit             on $projection.BR_GLGNNRatioUnit = _BR_GLGNNRatioUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure as _BR_GLGNIRatioUnit             on $projection.BR_GLGNIRatioUnit = _BR_GLGNIRatioUnit.UnitOfMeasure
  association [1..1] to I_BR_NFDocument as _BR_NotaFiscal                 on $projection.BR_NotaFiscal = _BR_NotaFiscal.BR_NotaFiscal
  association [0..1] to I_Currency      as _SalesDocumentCurrency         on $projection.SalesDocumentCurrency = _SalesDocumentCurrency.Currency
  association [1..1] to I_BR_NFItem     as _BR_NotaFiscalItem             on $projection.BR_NotaFiscal = _BR_NotaFiscalItem.BR_NotaFiscal 
                                                                         and $projection.BR_NotaFiscalItem = _BR_NotaFiscalItem.BR_NotaFiscalItem
  association [0..1] to I_UnitOfMeasure as _BaseUnit                      on $projection.baseunit = _BaseUnit.UnitOfMeasure                                                                         
{
  key NFFuel.docnum                                                   as BR_NotaFiscal,
  key NFFuel.itmnum                                                   as BR_NotaFiscalItem,
      cast(NFFuel.cprodanp as logbr_anp_product_code preserving type) as BR_ANPCode,
      cast(NFFuel.codif as logbr_codif_auth_code preserving type)     as BR_NFRegisterCODIF,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      cast(NFFuel.qtemp as logbr_billed_fuel_quan preserving type)    as BR_NFeEnvrmtTemperatureFuelQty,
      NFFuel.ufcons                                                   as BR_NFeFuelConsumerRegion,
      @Semantics.unitOfMeasure: true
      cast(' %' as msehi)                                             as BR_NFPercentageNaturalGasUnit,
      @Semantics.quantity.unitOfMeasure: 'BR_NFPercentageNaturalGasUnit'
      @DefaultAggregation: #NONE
      cast(NFFuel.pmixgn as logbr_nfe_pmixgn preserving type)         as BR_NFNaturalGasPercent,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      cast(NFFuel.qbcprod as logbr_nfe_tax_base_quantity preserving type) as BR_NFFuelCIDETaxBaseQuantity,
      NFFuel.valigprod                                                as BR_NFFuelCIDETaxRate,
      @Semantics.amount.currencyCode:'SalesDocumentCurrency'
      NFFuel.vcide                                                    as BR_NFFuelCIDETaxAmount,
      cast(NFFuel.bico as logbr_bico preserving type)                 as BR_NFeFuelNozzle,
      cast(NFFuel.bomba as logbr_bomba preserving type)               as BR_NFeFuelPump,
      cast(NFFuel.tanque as logbr_tanque preserving type)             as BR_NFeFuelTank,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      cast(NFFuel.encini_d as logbr_encini_d preserving type)         as BR_NFeFuelGaugeStartQuantity,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      cast(NFFuel.encfin_d as logbr_encfin_d preserving type)         as BR_NFeFuelGaugeEndQuantity,
      @Semantics.unitOfMeasure: true
      cast(' %' as msehi)                                             as BR_GLPRatioUnit,
      @Semantics.quantity.unitOfMeasure: 'BR_GLPRatioUnit'
      @DefaultAggregation: #NONE
      cast(NFFuel.p_glp as logbr_pglp preserving type)                as BR_GLPRatio,
      @Semantics.unitOfMeasure: true
      cast(' %' as msehi)                                             as BR_GLGNNRatioUnit,
      @Semantics.quantity.unitOfMeasure: 'BR_GLGNNRatioUnit'
      @DefaultAggregation: #NONE
      cast(NFFuel.p_gnn as logbr_pgnn preserving type)                as BR_GLGNNRatio,
      @Semantics.unitOfMeasure: true
      cast(' %' as msehi)                                             as BR_GLGNIRatioUnit,
      @Semantics.quantity.unitOfMeasure: 'BR_GLGNIRatioUnit'
      @DefaultAggregation: #NONE
      cast(NFFuel.p_gni as logbr_pgni preserving type)                as BR_GLGNIRatio,
      cast(NFFuel.v_part as logbr_vpart preserving type)              as BR_GLPNetValueAmount,
      cast(NFFuel.p_bio as logbr_pbio preserving type)                as BR_NFBiodieselMixingIndexRate,
      _BR_NFPercentageNaturalGasUnit,
      _BR_GLPRatioUnit,
      _BR_GLGNNRatioUnit,
      _BR_GLGNIRatioUnit,
      @Semantics.currencyCode:true
      _BR_NotaFiscal.SalesDocumentCurrency as SalesDocumentCurrency,
      _SalesDocumentCurrency,
      @Semantics.unitOfMeasure:true
      _BR_NotaFiscalItem.BaseUnit,
      _BaseUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BR_NFDOCUMENT",
"I_BR_NFITEM",
"J_1BNFFUEL"
],
"ASSOCIATED":
[
"I_BR_NFDOCUMENT",
"I_BR_NFITEM",
"I_CURRENCY",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/