I_BR_NFEPAYMENT

CDS View

Brazil NFe Payment Data

I_BR_NFEPAYMENT is a CDS View in S/4HANA. Brazil NFe Payment Data. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_BR_NFePayment view from BASIC Brazil Nota Fiscal Payment 
@AbapCatalog.sqlViewName: 'IBRNFEPAYMENT'
@AbapCatalog.compiler.compareFilter: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,#CDS_MODELING_DATA_SOURCE]
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Brazil NFe Payment Data'
@AbapCatalog.preserveKey:true
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.personalData.blocking: #NOT_REQUIRED

define view I_BR_NFePayment
  as select from j_1bnfepayment

  association [1..1] to I_Currency                  as _SalesDocumentCurrency     on  $projection.SalesDocumentCurrency = _SalesDocumentCurrency.Currency
  association [1..1] to I_BR_NFDocument             as _BR_NotaFiscal             on  $projection.BR_NotaFiscal = _BR_NotaFiscal.BR_NotaFiscal

  association [0..1] to I_BR_PaymentMethod          as _BR_PaymentMethod          on  _BR_PaymentMethod.PaymentMethod = $projection.PaymentMethod
  association [0..1] to I_BR_PaymentForm            as _BR_PaymentForm            on  _BR_PaymentForm.PaymentForm = $projection.PaymentForm
  association [0..1] to I_BR_PaymentIntegrationType as _BR_PaymentIntegrationType on  _BR_PaymentIntegrationType.PaymentSystemIntegrationType = $projection.PaymentSystemIntegrationType
  association [0..1] to I_BR_CreditCardCompany      as _BR_CreditCardCompany      on  _BR_CreditCardCompany.CreditCardBrand = $projection.CreditCardBrand
{
      @UI.hidden: true
  key docnum                                                                                    as BR_NotaFiscal,

      @UI.lineItem.position: 10
  key counter                                                                                   as SequenceNumber,

      @UI.lineItem.position: 20
      @ObjectModel.foreignKey.association: '_BR_PaymentMethod'
      cast(t_pag as logbr_tpag preserving type)                                                 as PaymentMethod,

      @UI.lineItem.position: 30
      cast(x_pag as logbr_payment_descr preserving type)                                        as BR_NFPaymentMethodManualDesc,

      @UI.lineItem.position: 40
      @Aggregation.default:#SUM
      cast(v_pag as logbr_vpag)                                                                 as PaymentAmount,


      @UI.lineItem.position: 50
      @ObjectModel.foreignKey.association: '_BR_PaymentIntegrationType'
      cast(tp_integra as logbr_tpintegra preserving type)                                       as PaymentSystemIntegrationType,

      @UI.lineItem.position: 60
      cast(concat(concat(concat(concat(concat( LEFT( cnpj, 2), '.'),
                                concat(RIGHT( LEFT( cnpj, 5), 3), '.')),           //MASK: __.___.___/____-__

                                concat(RIGHT( LEFT( cnpj, 8), 3), '/')),
                                concat(LEFT( RIGHT( cnpj, 6), 4), '-')),
                                        RIGHT( cnpj, 2)) as logbr_payment_cnpj preserving type) as BR_CreditCardCompanyCNPJ,

      @UI.lineItem.position: 70
      @ObjectModel.foreignKey.association: '_BR_CreditCardCompany'
      t_band                                                                                    as CreditCardBrand,

      @UI.lineItem.position: 80
      c_aut                                                                                     as CreditCardTransactionAuthznID,

      @UI.lineItem.position: 90
      @ObjectModel.foreignKey.association: '_BR_PaymentForm'
      cast(ind_pag as logbr_indpag preserving type)                                             as PaymentForm,

      @Semantics.currencyCode:true
      _BR_NotaFiscal.SalesDocumentCurrency                                                      as SalesDocumentCurrency,
      _BR_NotaFiscal,
      _SalesDocumentCurrency,

      _BR_PaymentMethod,
      _BR_PaymentForm,
      _BR_PaymentIntegrationType,
      _BR_CreditCardCompany
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BR_NFDOCUMENT",
"J_1BNFEPAYMENT"
],
"ASSOCIATED":
[
"I_BR_CREDITCARDCOMPANY",
"I_BR_NFDOCUMENT",
"I_BR_PAYMENTFORM",
"I_BR_PAYMENTINTEGRATIONTYPE",
"I_BR_PAYMENTMETHOD",
"I_CURRENCY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More