I_BOOPLNGBOMASSIGNMENT

CDS View

PBOM assigned to Planning Routing

I_BOOPLNGBOMASSIGNMENT is a CDS View in S/4HANA. PBOM assigned to Planning Routing. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_ChgImpactPlngRoutingMBOM view from CONSUMPTION Planning Routing MBOM Details 
@AbapCatalog.sqlViewName: 'ICHGIMPLNGROUMBM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@EndUserText.label: 'PBOM assigned to Planning Routing'
define view I_BOOPlngBOMAssignment
  as select from I_BOOMaterialAssgmtChangeState as BOP_TO_MatAssgmnt
    inner join   mast                           as MaterialToBOM on  MaterialToBOM.matnr = BOP_TO_MatAssgmnt.Material
                                                                 and MaterialToBOM.werks = BOP_TO_MatAssgmnt.Plant

    inner join   stko                           as BOMHeader     on  BOMHeader.stlnr = MaterialToBOM.stlnr
                                                                 and BOMHeader.stlal = MaterialToBOM.stlal
                                                                 and BOMHeader.stlty = 'M'

    inner join   I_ProdnBOMChgImpactObjMappg    as ProdBOMUsage  on  ProdBOMUsage.BillOfMaterialVariantUsage = MaterialToBOM.stlan
                                                                 and ProdBOMUsage.ProdnRlvnce                = 'P'

{

       /*I_BOOMaterialAssgmtChangeState Fields*/
  key  BOP_TO_MatAssgmnt.BillOfOperationsType              as BillOfOperationsType,
  key  BOP_TO_MatAssgmnt.BillOfOperationsGroup             as BillOfOperationsGroup,
  key  BOP_TO_MatAssgmnt.BillOfOperationsVariant           as BillOfOperationsVariant,
  key  BOP_TO_MatAssgmnt.BOOToMaterialInternalID           as BOOToMaterialInternalID,
  key  BOP_TO_MatAssgmnt.BOOMatlInternalVersionCounter     as BOOMatlInternalVersionCounter,
  key  cast( MaterialToBOM.stlnr as char8 preserving type) as BillOfMaterial,
  key  MaterialToBOM.stlal                                 as BillOfMaterialVariant,
  key  BOP_TO_MatAssgmnt.Plant                             as Plant,


       BOP_TO_MatAssgmnt.Material,
       BOP_TO_MatAssgmnt.ChangeNumber,
       BOP_TO_MatAssgmnt.IsDeleted,
       BOP_TO_MatAssgmnt.ValidityStartDate,
       BOP_TO_MatAssgmnt.ValidityEndDate,


       /*MAST Table fields - Material to BOM Linkage fields*/
       MaterialToBOM.stlan                                 as BillOfMaterialVariantUsage,
       ProdBOMUsage.ProdnRlvnce                            as ProdnRlvnce,

       /*STKO fields - BOM Header Fields*/
       BOMHeader.bom_versn                                 as BillOfMaterialVersion,
       BOMHeader.versnst                                   as BOMVersionStatus,
       BOMHeader.stlst                                     as BillOfMaterialStatus,
       BOMHeader.stlty                                     as BillOfMaterialCategory


}
//group by Material

where
  BOP_TO_MatAssgmnt.BillOfOperationsType = 'P';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BOOMATERIALASSGMTCHANGESTATE",
"I_PRODNBOMCHGIMPACTOBJMAPPG",
"MAST",
"STKO"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More