I_BOOOPERATIONCHGSTOANBASIC

CDS View

BOO Operation Change State OAN Basic

I_BOOOPERATIONCHGSTOANBASIC is a CDS View in S/4HANA. BOO Operation Change State OAN Basic. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_MfgStdTextVersWhereUsedList view inner CONSUMPTION View for ST Where Used List
I_ProdnModOpActyCompInstance view_entity inner COMPOSITE Prodn Model Op Acty Component Instance
I_ProdnModOpActyComponent view_entity inner COMPOSITE Production Model Activity Component
I_ProdnModOperationActivity view_entity inner COMPOSITE Production Model Operation Activity 
@AbapCatalog.sqlViewName: 'IBOOOCSOANBSC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType:
{
  serviceQuality: #B,
  sizeCategory:   #M,
  dataClass:      #MASTER
}
@ObjectModel:
{
  representativeKey: 'BOOOpInternalVersionCounter'
}
@Search.searchable: true
@EndUserText.label: 'BOO Operation Change State OAN Basic'
define view I_BOOOperationChgStOANBasic
  as select from mpe_oper_details

  -- Bill of Operation Type
  association [1..1] to I_BillOfOperationsType     as _BillOfOperationsType   on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType

  -- Bill of Operation Group
  association [1..1] to I_BillOfOperationsGroup    as _BillOfOperationsGroup  on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                              and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup

  -- Bill of Operation - Operation Internal Id
  association [1..1] to I_BOOOperationInternalID   as _BOOOperationInternalID on  $projection.BillOfOperationsType   = _BOOOperationInternalID.BillOfOperationsType
                                                                              and $projection.BillOfOperationsGroup  = _BOOOperationInternalID.BillOfOperationsGroup
                                                                              and $projection.BOOOperationInternalID = _BOOOperationInternalID.BOOOperationInternalID

  -- Setup OAN Internal Id
  association [0..1] to I_OpActyNtwkInternalID     as _SetupOAN               on  $projection.SetupOpActyNtwk = _SetupOAN.OperationActivityNetwork
  -- Setup OAN
  association [0..1] to I_OperationActivityNetwork as _SetupOANVersion        on  $projection.SetupOpActyNtwk            = _SetupOANVersion.OperationActivityNetwork
                                                                              and $projection.SetupOpActyNtwkVersCounter = _SetupOANVersion.OpActyNtwkVersionCounter

  -- Produce OAN Internal Id
  association [0..1] to I_OpActyNtwkInternalID     as _ProduceOAN             on  $projection.ProduceOpActyNtwk = _ProduceOAN.OperationActivityNetwork
  -- To Produce OAN
  association [0..1] to I_OperationActivityNetwork as _ProduceOANVersion      on  $projection.ProduceOpActyNtwk            = _ProduceOANVersion.OperationActivityNetwork
                                                                              and $projection.ProduceOpActyNtwkVersCounter = _ProduceOANVersion.OpActyNtwkVersionCounter

  -- Teardown OAN Internal Id
  association [0..1] to I_OpActyNtwkInternalID     as _TeardownOAN            on  $projection.TeardownOpActyNtwk = _TeardownOAN.OperationActivityNetwork
  -- Teardown OAN
  association [0..1] to I_OperationActivityNetwork as _TeardownOANVersion     on  $projection.TeardownOpActyNtwk            = _TeardownOANVersion.OperationActivityNetwork
                                                                              and $projection.TeardownOpActyNtwkVersCounter = _TeardownOANVersion.OpActyNtwkVersionCounter

{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key mpe_oper_details.plnty                                      as   BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key mpe_oper_details.plnnr                                      as   BillOfOperationsGroup,

      @ObjectModel.foreignKey.association: '_BOOOperationInternalID'
  key mpe_oper_details.plnkn                                      as   BOOOperationInternalID,

  key mpe_oper_details.counter                                    as   BOOOpInternalVersionCounter,

      // NOT a key field in THIS view !

      mpe_oper_details.versn                                      as   BillOfOperationsVersion,
      
      @ObjectModel.foreignKey.association: '_SetupOAN'
      mpe_oper_details.oan_id_setup                               as   SetupOpActyNtwk,

      @ObjectModel.foreignKey.association: '_SetupOANVersion'
      mpe_oper_details.oan_version_setup                          as   SetupOpActyNtwkVersCounter,

      @ObjectModel.foreignKey.association: '_ProduceOAN'
      mpe_oper_details.oan_id_produce                             as   ProduceOpActyNtwk,

      @ObjectModel.foreignKey.association: '_ProduceOANVersion'
      mpe_oper_details.oan_version_produce                        as   ProduceOpActyNtwkVersCounter,

      @ObjectModel.foreignKey.association: '_TeardownOAN'
      mpe_oper_details.oan_id_teardown                            as   TeardownOpActyNtwk,

      @ObjectModel.foreignKey.association: '_TeardownOANVersion'
      mpe_oper_details.oan_version_teardown                       as   TeardownOpActyNtwkVersCounter,
      
      @Semantics.text: true
      mpe_oper_details.wempf                                      as GoodsRecipientName,
      
      @Semantics.text: true
      mpe_oper_details.ablad                                      as UnloadingPointName,
      
            
      -- Associations
      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BOOOperationInternalID,

      _SetupOAN,
      _SetupOANVersion,

      _ProduceOAN,
      _ProduceOANVersion,

      _TeardownOAN,
      _TeardownOANVersion
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"MPE_OPER_DETAILS"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_BOOOPERATIONINTERNALID",
"I_OPACTYNTWKINTERNALID",
"I_OPERATIONACTIVITYNETWORK"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More