I_ALLOCATIONCYCLEKEYFIELDTP

CDS View

Allocation Cycle Key Field TP

I_ALLOCATIONCYCLEKEYFIELDTP is a CDS View in S/4HANA. Allocation Cycle Key Field TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_AllocationCycleKeyFieldTP view from CONSUMPTION Allocation Cycle Key Field 
@AbapCatalog.sqlViewName: 'ALOCCYCLEFIELDTP'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking:#NOT_REQUIRED

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #M

@EndUserText.label: 'Allocation Cycle Key Field TP'

@VDM.viewType: #TRANSACTIONAL

@ObjectModel:
{
  transactionalProcessingEnabled:true,
  writeDraftPersistence: 'ALOCCYCLEFLDTPD',
  semanticKey: ['AllocationType', 'AllocationCycle', 'AllocationCycleStartDate', 'AllocationCycleSegment', 'AllocDocumentSequenceNumber' ],
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true

//  entityChangeStateId: 'LastChangeTime'

}
define view I_AllocationCycleKeyFieldTP
  as select from I_AllocationKeyField
  association [1..1] to I_AllocationCycleTP as _Cycle on  $projection.AllocationType           = _Cycle.AllocationType
                                                      and $projection.AllocationCycle          = _Cycle.AllocationCycle
                                                      and $projection.AllocationCycleStartDate = _Cycle.AllocationCycleStartDate
{
  key AllocationType,
  key AllocationCycle,
  key AllocationCycleStartDate,
  key AllocationCycleSegment,
  key AllocDocumentSequenceNumber,
      AllocationFieldName,
      AllocationSetName,
      AllocationFieldMinimumValue,
      AllocationFieldMaximumValue,
      AllocationSetId,
      AllocationSetType,
      @ObjectModel: {
               readOnly: true,
               virtualElement,
               virtualElementCalculatedBy: 'ABAP:CL_FCO_ALLOC_KEY_CDS_EXIT'
            }
      cast( '' as ltext )   as AllocationFieldText,

      @ObjectModel.readOnly: true
      cast( '' as boolean ) as AllocKeyFieldIsInitial,
      @ObjectModel.readOnly: true
      cast( '' as boolean ) as AllocKeyFieldIsAllValues,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _Cycle
}
where
  AllocationSetType = '0' and AllocationCycleSegment = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ALLOCATIONKEYFIELD"
],
"ASSOCIATED":
[
"I_ALLOCATIONCYCLETP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More