I_ADDLLEDGEROPLACCTGDOCITEM

@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.sqlViewName: 'IFIADDLDACDOCIT'
@EndUserText.label: 'Additional Ledger Journal Entry Item'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'AccountingDocumentItem'
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #D
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@Analytics: { dataCategory: #DIMENSION }
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #SQL_DATA_SOURCE]
                                     
define view I_AddlLedgerOplAcctgDocItem
  as select from P_Bseg_Add_Com

  association [1..1] to I_JournalEntry               as _JournalEntry                on  $projection.CompanyCode        = _JournalEntry.CompanyCode
                                                                                     and $projection.FiscalYear         = _JournalEntry.FiscalYear
                                                                                     and $projection.AccountingDocument = _JournalEntry.AccountingDocument
  association [1..1] to I_CompanyCode                as _CompanyCode                 on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_FiscalYearForCompanyCode   as _FiscalYear                  on  $projection.FiscalYear  = _FiscalYear.FiscalYear
                                                                                     and $projection.CompanyCode = _FiscalYear.CompanyCode                                                                               
  association [0..1] to I_ControllingArea            as _ControllingArea             on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_GLAccountInChartOfAccounts as _GLAccountInChartOfAccounts  on  $projection.ChartOfAccounts = _GLAccountInChartOfAccounts.ChartOfAccounts
                                                                                     and $projection.GLAccount       = _GLAccountInChartOfAccounts.GLAccount
  association [0..*] to I_ProfitCenter               as _ProfitCenter                on  $projection.ControllingArea = _ProfitCenter.ControllingArea
                                                                                     and $projection.ProfitCenter    = _ProfitCenter.ProfitCenter
  association [0..1] to I_Segment                    as _Segment                     on  $projection.Segment = _Segment.Segment
  association [0..*] to I_CostCenter                 as _CostCenter                  on  $projection.ControllingArea = _CostCenter.ControllingArea
                                                                                     and $projection.CostCenter      = _CostCenter.CostCenter

  association [0..1] to I_ChartOfAccounts            as _ChartOfAccounts             on  $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
  association [1..1] to I_Currency                   as _CompanyCodeCurrency         on  $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
  association [0..1] to I_Currency                   as _FunctionalCurrency          on  $projection.FunctionalCurrency = _FunctionalCurrency.Currency  
  association [0..1] to I_Currency                   as _TransactionCurrency         on  $projection.TransactionCurrency = _TransactionCurrency.Currency
  association [0..1] to I_Currency                   as _BalanceTransactionCurrency  on  $projection.BalanceTransactionCurrency = _BalanceTransactionCurrency.Currency
  association [0..1] to I_Currency                   as _AdditionalCurrency1         on  $projection.AdditionalCurrency1 = _AdditionalCurrency1.Currency
  association [0..1] to I_Currency                   as _AdditionalCurrency2         on  $projection.AdditionalCurrency2 = _AdditionalCurrency2.Currency
  association [0..1] to I_FinancialAccountType       as _FinancialAccountType        on  $projection.FinancialAccountType = _FinancialAccountType.FinancialAccountType
  association [0..1] to I_BusinessArea               as _BusinessArea                on  $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_Material                   as _Material                    on  $projection.Material = _Material.Material
  association [0..1] to I_Product                    as _Product                     on  $projection.Product = _Product.Product
  association [0..1] to I_Plant                      as _Plant                       on  $projection.Plant = _Plant.Plant
  association [0..1] to I_InternalOrder              as _InternalOrder               on  $projection.OrderID = _InternalOrder.InternalOrder
  association [0..1] to I_WBSElementByInternalKey    as _WBSElementInternalID        on  $projection.WBSElementInternalID = _WBSElementInternalID.WBSElementInternalID

  association [0..1] to I_UnitOfMeasure              as _BaseUnit                    on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure

  association [0..1] to I_PostingKey                 as _PostingKey                  on  $projection.PostingKey = _PostingKey.PostingKey
  association [0..1] to I_DebitCreditCode            as _DebitCreditCode             on  $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode
  association [0..1] to I_BusinessArea               as _PartnerBusinessArea         on  $projection.PartnerBusinessArea = _PartnerBusinessArea.BusinessArea
  association [0..1] to I_CompanyCode                as _PartnerCompany              on  $projection.PartnerCompany = _PartnerCompany.CompanyCode
  association [0..1] to I_Partnercompany             as _PartnerCompany_2            on  $projection.PartnerCompany = _PartnerCompany_2.PartnerCompany  
  association [0..1] to I_InventoryValuationType     as _InventoryValuationType      on  $projection.InventoryValuationType = _InventoryValuationType.InventoryValuationType
  association [0..1] to I_Segment                    as _PartnerSegment              on  $projection.PartnerSegment = _PartnerSegment.Segment

  association [1..1] to I_AccountingDocument         as _ClearingAccountingDocument  on $projection.CompanyCode                    = _ClearingAccountingDocument.CompanyCode and 
                                                                                        $projection.FiscalYear                     = _ClearingAccountingDocument.FiscalYear and 
                                                                                        $projection.ClearingAccountingDocument     = _ClearingAccountingDocument.AccountingDocument 
  association [0..1] to I_FiscalYearForCompanyCode   as _ClearingJrnlEntryFiscalYear on $projection.ClearingJournalEntryFiscalYear = _ClearingJrnlEntryFiscalYear.FiscalYear and
                                                                                        $projection.CompanyCode                    = _ClearingJrnlEntryFiscalYear.CompanyCode 
  association [0..1] to I_JournalEntry               as _ClearingJournalEntry        on $projection.CompanyCode                    = _ClearingJournalEntry.CompanyCode and
                                                                                        $projection.ClearingJournalEntryFiscalYear = _ClearingJournalEntry.FiscalYear and
                                                                                        $projection.ClearingJournalEntry           = _ClearingJournalEntry.AccountingDocument
                                                                                         
  association [0..*] to I_TaxCode                    as _TaxCode                     on $projection.TaxCode                        = _TaxCode.TaxCode
  association [0..1] to I_FinancialTransactionType   as _FinancialTransactionType    on $projection.FinancialTransactionType       = _FinancialTransactionType.FinancialTransactionType
  association [0..1] to I_MasterFixedAsset           as _MasterFixedAsset            on $projection.CompanyCode                    = _MasterFixedAsset.CompanyCode and
                                                                                        $projection.MasterFixedAsset               = _MasterFixedAsset.MasterFixedAsset                                                                                        
  association [0..1] to I_FixedAsset                 as _FixedAsset                  on $projection.CompanyCode                    = _FixedAsset.CompanyCode and
                                                                                        $projection.MasterFixedAsset               = _FixedAsset.MasterFixedAsset and
                                                                                        $projection.FixedAsset                     = _FixedAsset.FixedAsset
  association [0..1] to I_AssetTransactionType       as _AssetTransactionType        on $projection.AssetTransactionType           = _AssetTransactionType.AssetTransactionType                                                                                                                                                                                                                                                            

  association [0..1] to I_Purreqvaluationarea        as _ValuationArea               on $projection.ValuationArea                  = _ValuationArea.ValuationArea
  association [0..1] to I_ProjectNetwork             as _ProjectNetwork              on $projection.ProjectNetwork                 = _ProjectNetwork.ProjectNetwork
                                                                                                                                                                                                                                                         
  association [0..*] to I_ProfitCenter               as _PartnerProfitCenter         on $projection.ControllingArea                = _PartnerProfitCenter.ControllingArea and  
                                                                                        $projection.PartnerProfitCenter            = _PartnerProfitCenter.ProfitCenter                                                                               
  association [0..*] to I_CostCenterActivityType     as _CostCtrActivityType         on $projection.ControllingArea                = _CostCtrActivityType.ControllingArea and     
                                                                                        $projection.CostCtrActivityType            = _CostCtrActivityType.CostCtrActivityType
  association [0..1] to I_BusinessProcess            as _BusinessProcess             on $projection.ControllingArea                = _BusinessProcess.ControllingArea and                                                                                        
                                                                                        $projection.BusinessProcess                = _BusinessProcess.BusinessProcess
  association [0..1] to I_FunctionalArea             as _FunctionalArea              on $projection.FunctionalArea                 = _FunctionalArea.FunctionalArea
                                                                                                                                                                                                                                                             
  association [0..1] to I_FunctionalArea             as _PartnerFunctionalArea       on $projection.PartnerFunctionalArea          = _PartnerFunctionalArea.FunctionalArea
                                                                                                                                                                                                                                                            
  association [0..1] to I_GLAccountInChartOfAccounts as _OffsettingAccount           on $projection.ChartOfAccounts                = _OffsettingAccount.ChartOfAccounts and 
                                                                                        $projection.OffsettingAccount              = _OffsettingAccount.GLAccount 
  association [0..1] to I_GLAccountType              as _OffsettingAccountType       on $projection.OffsettingAccountType          = _OffsettingAccountType.GLAccountType


  association [0..1] to I_FinancialAccountType       as _OffsettingAccountType_2     on $projection.OffsettingAccountType          = _OffsettingAccountType_2.FinancialAccountType


  association [0..1] to I_CompanyCode                as _CashLedgerCompanyCode       on  $projection.CashLedgerCompanyCode         = _CashLedgerCompanyCode.CompanyCode
  association [0..1] to I_GLAccountInCompanyCode     as _CashLedgerAccount           on  $projection.CashLedgerCompanyCode         = _CashLedgerAccount.CompanyCode 
                                                                                     and $projection.CashLedgerAccount             = _CashLedgerAccount.GLAccount                                                                                  
                                                                                  
  association [0..1] to I_BudgetPeriod               as _BudgetPeriod                on $projection.BudgetPeriod                   = _BudgetPeriod.BudgetPeriod                                                                                                                                                                                                                                                            
  association [0..1] to I_BudgetPeriod               as _PartnerBudgetPeriod         on  $projection.PartnerBudgetPeriod           = _PartnerBudgetPeriod.BudgetPeriod
  association [0..1] to I_Grant                      as _Grant                       on  $projection.GrantID                       = _Grant.GrantID   
  association [0..1] to I_Grant                      as _PartnerGrant                on  $projection.PartnerGrant                  = _PartnerGrant.GrantID                                                                                    

  association [0..1] to I_CompanyCode                as _PubSecBudgetAccountCoCode   on  $projection.PubSecBudgetAccountCoCode     = _PubSecBudgetAccountCoCode.CompanyCode       
  association [0..1] to I_PubSecBudgetAccount        as _PubSecBudgetAccount         on  $projection.PubSecBudgetAccountCoCode     = _PubSecBudgetAccount.PubSecBudgetAccountCoCode
                                                                                     and $projection.PubSecBudgetAccount           = _PubSecBudgetAccount.PubSecBudgetAccount    

  association [0..1] to I_OffsettingAccount          as _OffsettingAccountWithBP     on  $projection.OffsettingChartOfAccounts     = _OffsettingAccountWithBP.ChartOfAccounts
                                                                                     and $projection.OffsettingAccountType         = _OffsettingAccountWithBP.OffsettingAccountType
                                                                                     and $projection.OffsettingAccount             = _OffsettingAccountWithBP.OffsettingAccount
  association [0..1] to I_ChartOfAccounts            as _OffsettingChartOfAccounts   on  $projection.OffsettingChartOfAccounts     = _OffsettingChartOfAccounts.ChartOfAccounts
  association [0..1] to I_WBSElementBasicData        as _WBSElementBasicData         on  $projection.WBSElementInternalID          = _WBSElementBasicData.WBSElementInternalID  

//  association [0..1] to I_REObjectByIntFinNumber     as _REObjectByIntFinNumber      on  $projection.REInternalFinNumber           = _REObjectByIntFinNumber.REInternalFinNumber


{

      @ObjectModel.foreignKey.association: '_CompanyCode'
  key P_Bseg_Add_Com.bukrs as  CompanyCode,
      @ObjectModel.foreignKey.association: '_JournalEntry'
  key belnr            as  AccountingDocument,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key gjahr            as  FiscalYear,
  key buzei            as  AccountingDocumentItem,

      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      ktopl            as  ChartOfAccounts,
      augdt            as  ClearingDate,
      augcp            as  ClearingCreationDate,

      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_ClearingJrnlEntryFiscalYear'
      auggj               as  ClearingJournalEntryFiscalYear,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'ClearingJournalEntryFiscalYear'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'ClearingJournalEntryFiscalYear'
      cast( auggj  as fis_auggj_no_conv_depre preserving type ) as ClearingDocFiscalYear,

      @Analytics.internalName: #LOCAL
      @ObjectModel.foreignKey.association: '_ClearingJournalEntry'
      augbl            as  ClearingJournalEntry,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'ClearingJournalEntry'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'ClearingJournalEntry'
      @ObjectModel.foreignKey.association: '_ClearingAccountingDocument'
      cast( augbl as fis_augbl_depre preserving type ) as ClearingAccountingDocument,

      @ObjectModel.foreignKey.association: '_PostingKey'
      bschl            as  PostingKey,
      @ObjectModel.foreignKey.association: '_FinancialAccountType'
      koart            as  FinancialAccountType,
      @ObjectModel.foreignKey.association: '_DebitCreditCode'
      shkzg            as  DebitCreditCode,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      gsber            as  BusinessArea,
      @ObjectModel.foreignKey.association: '_PartnerBusinessArea'
      pargb            as  PartnerBusinessArea,
      mwskz            as  TaxCode,
      qsskz            as  WithholdingTaxCode,
      ktosl            as  TransactionTypeDetermination,
      valut            as  ValueDate,
      zuonr            as  AssignmentReference,
      sgtxt            as  DocumentItemText,
      @ObjectModel.foreignKey.association: '_PartnerCompany_2'
      vbund            as  PartnerCompany,
      @ObjectModel.foreignKey.association: '_FinancialTransactionType'
      bewar            as  FinancialTransactionType,
      altkt            as  CorporateGroupAccount,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      kokrs            as  ControllingArea,
      @ObjectModel.foreignKey.association: '_CostCenter'
      kostl            as  CostCenter,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    ''
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: ''
      projn            as  Project,
      @ObjectModel.foreignKey.association: '_InternalOrder'
      aufnr            as  OrderID,
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
      anln1            as  MasterFixedAsset,
      @ObjectModel.foreignKey.association: '_FixedAsset'
      anln2            as  FixedAsset,
      @ObjectModel.foreignKey.association: '_AssetTransactionType'
      anbwa            as  AssetTransactionType,
//      @Semantics.booleanIndicator 

      xopvw            as  IsOpenItemManaged,
//      @Semantics.booleanIndicator 

      xauto            as  IsAutomaticallyCreated,
      @ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
      hkont            as  GLAccount,
//      @Semantics.booleanIndicator 

      xbilk            as  IsBalanceSheetAccount,
      gvtyp            as  ProfitLossAccountType,
      zfbdt            as  DueCalculationBaseDate,
      rebzg            as  InvoiceReference,
      rebzj            as  InvoiceReferenceFiscalYear,
      rebzz            as  InvoiceItemReference,
      rebzt            as  FollowOnDocumentType,
      wverw            as  BillOfExchangeUsage,

      @ObjectModel.foreignKey.association: '_Material'
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'Product'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'Product'
      matnr            as  Material,
      @ObjectModel.foreignKey.association: '_Product'
      matnr            as  Product,

      @ObjectModel.foreignKey.association: '_Plant'
      werks            as  Plant,
      @ObjectModel.foreignKey.association: '_ValuationArea'
      bwkey            as  ValuationArea,
      @ObjectModel.foreignKey.association: '_InventoryValuationType'
      bwtar            as  InventoryValuationType,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      prctr            as  ProfitCenter,
      vname            as  JointVenture,
      recid            as  JointVentureCostRecoveryCode,
      egrup            as  JointVentureEquityGroup,
      vertt            as  TreasuryContractType,
      vertn            as  AssetContract,
      vbewa            as  CashFlowType,

//      @ObjectModel.foreignKey.association: '_REObjectByIntFinNumber'

      cast( imkey as recaimkeyfi preserving type ) as REInternalFinNumber,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'REInternalFinNumber'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'REInternalFinNumber'
      imkey            as  RealEstateObject,

      dabrz            as  SettlementReferenceDate,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'CommitmentItemShortID'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'CommitmentItemShortID'
      fipos                                              as  CommitmentItem,
      cast( fipos as fis_fipos_shortid preserving type ) as  CommitmentItemShortID,

      kstrg            as  CostObject,
      @ObjectModel.foreignKey.association: '_ProjectNetwork'      
      nplnr            as  ProjectNetwork,
      aufpl            as  OrderInternalBillOfOperations,
      aplzl            as  OrderIntBillOfOperationsItem,
      @ObjectModel.foreignKey.association: '_WBSElementBasicData'
      projk            as  WBSElementInternalID,
      
@API.element.releaseState: #DECOMMISSIONED
@API.element.successor:    'ProfitabilitySegment_2'
@VDM.lifecycle.status:    #DEPRECATED
@VDM.lifecycle.successor: 'ProfitabilitySegment_2'
cast( case when paobjnr > '9999999999' then '9999999999' else lpad( paobjnr, 10, '0' ) end as rkeobjnr_numc )  as ProfitabilitySegment,
cast( paobjnr as rkeobjnr_char ) as ProfitabilitySegment_2,       
      
//      @Semantics.booleanIndicator 

      xragl            as  ClearingIsReversed,
      uzawe            as  PaymentMethodSupplement,
      lokkt            as  AlternativeGLAccount,
      fistl            as  FundsCenter,
      geber            as  Fund,
      @ObjectModel.foreignKey.association: '_PartnerProfitCenter'
      pprct            as  PartnerProfitCenter,
      xref1            as  Reference1IDByBusinessPartner,
      xref2            as  Reference2IDByBusinessPartner,
      @Analytics.internalName: #LOCAL      
      kblnr            as  EarmarkedFundsDocument,
      @Analytics.internalName: #LOCAL      
      kblpos           as  EarmarkedFundsDocumentItem,
      @Analytics.internalName: #LOCAL      
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      fkber            as  FunctionalArea,
      rfzei            as  PaymentCardItem,
      ccbtc            as  PaymentCardPaymentSettlement,
      xref3            as  Reference3IDByBusinessPartner,
      agzei            as  ClearingItem,
      bupla            as  BusinessPlace,
      secco            as  TaxSection,
      @ObjectModel.foreignKey.association: '_CostCtrActivityType'
      lstar            as  CostCtrActivityType,
      @ObjectModel.foreignKey.association: '_BusinessProcess'
      prznr            as  BusinessProcess,
      @Analytics.internalName: #LOCAL      
      @ObjectModel.foreignKey.association: '_Grant'
      grant_nbr        as  GrantID,
      measure          as  FundedProgram,
      @ObjectModel.foreignKey.association: '_Segment'
      segment          as  Segment,
      @ObjectModel.foreignKey.association: '_PartnerSegment'
      psegment         as  PartnerSegment,
      @ObjectModel.foreignKey.association: '_PartnerFunctionalArea'
      pfkber           as  PartnerFunctionalArea,
      kstar            as  CostElement,
      netdt            as  NetDueDate,
      @ObjectModel.foreignKey.association: '_OffsettingAccountWithBP'
      gkont            as  OffsettingAccount,
      @ObjectModel.foreignKey.association: '_OffsettingAccountType_2'
      gkart            as  OffsettingAccountType,
      @ObjectModel.foreignKey.association: '_OffsettingChartOfAccounts'
      cast( ( case gkart
                   when 'D' then ' '  
                   when 'K' then ' '  
                   else ktopl 
              end )
      as ktopl) as OffsettingChartOfAccounts,
      pgeber           as  PartnerFund,
      @Analytics.internalName: #LOCAL      
      @ObjectModel.foreignKey.association: '_PartnerGrant'
      pgrant_nbr       as  PartnerGrant,
      @ObjectModel.foreignKey.association: '_BudgetPeriod'
      budget_pd        as  BudgetPeriod,
      @Analytics.internalName: #LOCAL      
      @ObjectModel.foreignKey.association: '_PartnerBudgetPeriod'
      pbudget_pd       as  PartnerBudgetPeriod,
      
      @Analytics.internalName: #LOCAL      
      bstat            as  AccountingDocumentCategory,

      @Analytics.internalName: #LOCAL      
      @ObjectModel.foreignKey.association: '_CashLedgerCompanyCode'
      re_bukrs            as CashLedgerCompanyCode,
      @Analytics.internalName: #LOCAL      
      @ObjectModel.foreignKey.association: '_CashLedgerAccount'
      re_account          as CashLedgerAccount,

      @Analytics.internalName: #LOCAL      
      @ObjectModel.foreignKey.association: '_PubSecBudgetAccountCoCode'
      bdgt_account_cocode as PubSecBudgetAccountCoCode,
      @Analytics.internalName: #LOCAL      
      @ObjectModel.foreignKey.association: '_PubSecBudgetAccount'
      bdgt_account        as PubSecBudgetAccount,

      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      @Semantics.currencyCode:true
      h_hwaer          as  CompanyCodeCurrency,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      dmbtr_shl        as  AmountInCompanyCodeCurrency,
      
// Functional Currency

@ObjectModel.foreignKey.association: '_FunctionalCurrency'
@Semantics.currencyCode:true
rfccur as FunctionalCurrency,
@DefaultAggregation: #SUM
@Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
fcsl_shl as AmountInFunctionalCurrency,      

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      mwsts_shl        as  TaxAmountInCoCodeCrcy,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      bdiff_shl        as  ValuationDiffAmtInCoCodeCrcy,

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      @Semantics.currencyCode:true
      h_waers          as  TransactionCurrency,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      wrbtr_shl        as  AmountInTransactionCurrency,


      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      wmwst_shl        as  TaxAmount,


      @ObjectModel.foreignKey.association: '_BalanceTransactionCurrency'
      @Semantics.currencyCode:true
      pswsl            as  BalanceTransactionCurrency,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'BalanceTransactionCurrency'} }
      pswbt_shl        as  AmountInBalanceTransacCrcy,


      @ObjectModel.foreignKey.association: '_AdditionalCurrency1'
      @Semantics.currencyCode:true
      h_hwae2          as  AdditionalCurrency1,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      bdif2_shl        as  ValuationDiffAmtInAddlCrcy1,


      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency1'} }
      dmbe2_shl        as  AmountInAdditionalCurrency1,

 
      @ObjectModel.foreignKey.association: '_AdditionalCurrency2'
      @Semantics.currencyCode:true
      h_hwae3          as  AdditionalCurrency2,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      dmbe3_shl        as  AmountInAdditionalCurrency2,

      @DefaultAggregation: #SUM
      @Semantics: { amount : {currencyCode: 'AdditionalCurrency2'} }
      bdif3_shl        as  ValuationDiffAmtInAddlCrcy2,


      @ObjectModel.foreignKey.association: '_BaseUnit'
      @Semantics.unitOfMeasure:true
      meins            as  BaseUnit,
      @DefaultAggregation: #SUM
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }