I_ASSETMULTIPLECREATION
Asset Multiple Creation
I_ASSETMULTIPLECREATION is a CDS View in S/4HANA. Asset Multiple Creation. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_AssetMultipleCreationTP | view | from | TRANSACTIONAL | Asset Multiple Creation - TP |
@AbapCatalog.sqlViewName: 'IASTMULTICREATE'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Asset Multiple Creation'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel: {
usageType.serviceQuality: #A,
usageType.sizeCategory: #M,
usageType.dataClass: #MASTER
}
define view I_AssetMultipleCreation
as select from faat_md_multi as Multi
association [1..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [1..1] to I_MasterFixedAsset as _MasterFixedAsset on $projection.CompanyCode = _MasterFixedAsset.CompanyCode
and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
association [1..1] to I_FixedAsset as _FixedAsset on $projection.CompanyCode = _FixedAsset.CompanyCode
and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
and $projection.FixedAsset = _FixedAsset.FixedAsset
association [0..1] to I_AssetClass as _AssetClass on $projection.AssetClass = _AssetClass.AssetClass
association [0..1] to I_AssetAcctDetermination as _AssetAccountDetermination on $projection.AssetAccountDetermination = _AssetAccountDetermination.AssetAccountDetermination
association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [0..1] to I_Country as _AssetCountryOfOrigin on $projection.AssetCountryOfOrigin = _AssetCountryOfOrigin.Country
association [0..1] to I_Currency as _OriginalAcquisitionCurrency on $projection.OriginalAcquisitionCurrency = _OriginalAcquisitionCurrency.Currency
association [0..1] to I_Globalcompany as _PartnerCompany on $projection.PartnerCompany = _PartnerCompany.Company
association [0..1] to I_InternalOrder as _InvestmentOrder on $projection.InvestmentOrder = _InvestmentOrder.InternalOrder
association [0..1] to I_InvestmentReason as _InvestmentReason on $projection.InvestmentReason = _InvestmentReason.InvestmentReason
association [0..1] to I_EnvrnmtlInvestmentReason as _EnvrnmtlInvestmentReason on $projection.EnvrnmtlInvestmentReason = _EnvrnmtlInvestmentReason.EnvrnmtlInvestmentReason
association [0..1] to I_FixedAssetGroup as _FixedAssetGroup on $projection.FixedAssetGroup = _FixedAssetGroup.FixedAssetGroup
association [0..1] to I_FixedAssetPropertyType as _FixedAssetPropertyType on $projection.FixedAssetPropertyType = _FixedAssetPropertyType.FixedAssetPropertyType
association [0..1] to I_UnitOfMeasure as _UnitOfMeasure on $projection.BaseUnit = _UnitOfMeasure.UnitOfMeasure
association [0..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [0..1] to I_InternalOrder as _InternalOrder on $projection.InternalOrder = _InternalOrder.InternalOrder
association [0..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [0..1] to I_Segment as _Segment on $projection.Segment = _Segment.Segment
association [0..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [0..1] to I_Location as _AssetLocation on $projection.AssetLocation = _AssetLocation.Location
and $projection.Plant = _AssetLocation.Plant
association [0..1] to I_Employment as _Employment on $projection.PersonnelNumber = _Employment.EmploymentInternalID
{
@ObjectModel.foreignKey.association: '_CompanyCode'
key comp_code as CompanyCode,
@ObjectModel.foreignKey.association: '_MasterFixedAsset'
key asset_no as MasterFixedAsset,
@ObjectModel.foreignKey.association: '_FixedAsset'
key asset_subno as FixedAsset,
key row_index as RowIndex,
//Root fields
@ObjectModel.foreignKey.association: '_AssetClass'
asset_class as AssetClass,
//screen_layout as AssetScreenLayout,
@ObjectModel.foreignKey.association: '_AssetAccountDetermination'
gl_account_det as AssetAccountDetermination,
@Semantics.text:true
description as FixedAssetDescription,
@Semantics.text:true
add_description as AssetAdditionalDescription,
serial_number as AssetSerialNumber,
inventory_number as Inventory,
@ObjectModel.foreignKey.association: '_Supplier'
supplier_no as Supplier,
@ObjectModel.foreignKey.association: '_AssetCountryOfOrigin'
origin_country as AssetCountryOfOrigin,
manufacturer as AssetManufacturerName,
original_asset as OriginalMasterFixedAsset,
original_subasset as OriginalFixedAsset,
original_acq_date as OriginalFixedAssetValueDate,
@Semantics.fiscal.year: true
original_acq_year as OriginalAcquisitionFiscalYear,
@Semantics.amount.currencyCode: 'OriginalAcquisitionCurrency'
original_acq_value as OriginalAcquisitionAmount,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_OriginalAcquisitionCurrency'
original_acq_value_curr as OriginalAcquisitionCurrency,
inhouse_prod_percent as InHouseProdnPercent,
asset_type_name as AssetTypeName,
@ObjectModel.foreignKey.association: '_PartnerCompany'
trade_id as PartnerCompany,
asset_acquired_used as AssetIsAcquiredUsed,
cast(investment_wbs_origin as ps_s4_pspnr) as InvestmentProjectWBSElement,
@ObjectModel.foreignKey.association: '_InvestmentOrder'
investment_io_origin as InvestmentOrder,
inventory_date as LastInventoryDate,
inventory_note as InventoryNote,
inventory_indicator as InventoryIsCounted,
@ObjectModel.foreignKey.association: '_InvestmentReason'
invest_reason as InvestmentReason,
@ObjectModel.foreignKey.association: '_EnvrnmtlInvestmentReason'
environmental_investment as EnvrnmtlInvestmentReason,
@ObjectModel.foreignKey.association: '_FixedAssetGroup'
asset_super_no as FixedAssetGroup,
property_key as PropertyClass,
@ObjectModel.foreignKey.association: '_FixedAssetPropertyType'
property_ind as FixedAssetPropertyType,
land_tax_office as LocalTaxOffice,
assessment_tax_number as NoticeOfAssessmentTaxID,
assessment_date as LastAssessmentNoticeDate,
land_municipality as Municipality,
land_register_of as LandRegisterDate,
land_register_entry_number as LandRegisterEntrySequence,
land_register_entry as LandRegisterEntryDate,
land_register_volume as LandRegisterVolume,
land_register_page as LandRegisterPage,
land_register_map_no as LandRegisterMap,
land_plot_number as LandPlot,
conveyance_date as ConveyanceDate,
@Semantics.quantity.unitOfMeasure: 'AreaSizeUnit'
surface_area as AreaSize,
@Semantics.unitOfMeasure: true
surface_area_unit as AreaSizeUnit,
real_estate_asset as AssetIsRealEstate,
lease_company as LeaseSupplier,
lease_agreement_no as LeaseAgreement,
lease_agreement_date as LeaseAgreementDate,
lease_notice_date as LeaseTermEndDate,
lease_start_date as LeaseTermStartDate,
lease_years as LeaseDurationInFiscalYears,
lease_periods as LeaseDurationInFiscalPeriods,
lease_type as LeaseType,
lease_data_text as LeasedAssetNote,
@Semantics.unitOfMeasure:true
@ObjectModel.foreignKey.association: '_UnitOfMeasure'
base_unit as BaseUnit,
purchase_order_date as FixedAssetOrderDate,
last_reorg_date as LastReorganizationDate,
object_nr as ObjectInternalID,
//TDD fields
@ObjectModel.foreignKey.association: '_BusinessArea'
business_area as BusinessArea,
cost_center as CostCenter,
activity_type as CostCtrActivityType,
@ObjectModel.foreignKey.association: '_InternalOrder'
internal_order as InternalOrder,
fund as Fund,
grant_id as GrantID,
@ObjectModel.foreignKey.association: '_FunctionalArea'
functional_area as FunctionalArea,
funds_center as FundsCenter,
cast(wbs_element as ps_s4_pspnr) as WBSElementInternalID,
tax_jurisdiction as TaxJurisdiction,
cast(real_estate_key as recaimkeyfi ) as RealEstateObject,
@ObjectModel.foreignKey.association: '_Segment'
segment as Segment,
profit_center as ProfitCenter,
budget_period as BudgetPeriod,
responsible_cost_center as ResponsibleCostCenter,
room as Room,
@ObjectModel.foreignKey.association: '_Plant'
plant as Plant,
@ObjectModel.foreignKey.association: '_AssetLocation'
location as AssetLocation,
car_license_plate as VehicleLicensePlateNumber,
@ObjectModel.foreignKey.association: '_Employment'
personnel_number as PersonnelNumber,
business_place as BusinessPlace,
// Association
_CompanyCode,
_MasterFixedAsset,
_FixedAsset,
_AssetClass,
_AssetAccountDetermination,
_Supplier,
_AssetCountryOfOrigin,
_OriginalAcquisitionCurrency,
_PartnerCompany,
_InvestmentOrder,
_InvestmentReason,
_EnvrnmtlInvestmentReason,
_FixedAssetGroup,
_FixedAssetPropertyType,
_UnitOfMeasure,
_BusinessArea,
_InternalOrder,
_FunctionalArea,
_Segment,
_Plant,
_AssetLocation,
_Employment
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"FAAT_MD_MULTI"
],
"ASSOCIATED":
[
"I_ASSETACCTDETERMINATION",
"I_ASSETCLASS",
"I_BUSINESSAREA",
"I_COMPANYCODE",
"I_COUNTRY",
"I_CURRENCY",
"I_EMPLOYMENT",
"I_ENVRNMTLINVESTMENTREASON",
"I_FIXEDASSET",
"I_FIXEDASSETGROUP",
"I_FIXEDASSETPROPERTYTYPE",
"I_FUNCTIONALAREA",
"I_GLOBALCOMPANY",
"I_INTERNALORDER",
"I_INVESTMENTREASON",
"I_LOCATION",
"I_MASTERFIXEDASSET",
"I_PLANT",
"I_SEGMENT",
"I_SUPPLIER",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/