C_LCMACTIVECNTXTIDVALUEHELP

@AbapCatalog.sqlViewName: 'CLCMACTXIDVH'
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@ObjectModel.semanticKey:  'LglCntntMContext'
@ObjectModel.representativeKey: 'LglCntntMContext'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MIXED
//@ObjectModel.dataCategory: #VALUE_HELP

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Value help for Active LCM Context'
define view C_LCMActiveCntxtIdValueHelp

  as select from I_LglCntntMContextBasic
    inner join   I_LglCntntMNotObsltCntxt as _LglCntntMNotObsltCntxt on I_LglCntntMContextBasic.LglCntntMContextUUID = _LglCntntMNotObsltCntxt.LglCntntMNotObsltContextUUID

  association [0..1] to C_LCMUserValueHelp        as _Owner                  on  _Owner.UserID = $projection.LglCntntMContextOwner

  association [0..1] to C_LglCntntMMainOrgTypeVH  as _LglCntntMMainOrgTypeVH on  $projection.LglCntntMMainOrgType = _LglCntntMMainOrgTypeVH.LglCntntMMainOrgType

  association [0..1] to C_LCMCompanyCodeValueHelp as _CompanyCodeValueHelp   on  $projection.LglCntntMMainOrgCoCode = _CompanyCodeValueHelp.CompanyCode


  association [0..1] to Sgbt_Nte_Cds_Cont         as _Note                   on  _Note.noteid         = $projection.LglCntntMLongTextUUID
                                                                             and _Note.objectnodetype = 'LegalContext'
                                                                             and _Note.notetype       = 'LCM_LONGTEXT'

  //association [0..1] to C_LCMSalesOrganizationVH  as _SalesOrganizationVH    on $projection.LglCntntMMainOrgSalesOrg = _SalesOrganizationVH.SalesOrganization


  //association [0..1] to C_LglCntntMGovLawVH       as _LCMGovLawVH            on $projection.LglCntntMGovLaw = _LCMGovLawVH.LglCntntMGovLaw



{

        @ObjectModel.text.element:  [ 'LglCntntMContextTitle' ]
        @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
        @UI.selectionField.position: 10
        @UI.lineItem.position: 10
        @EndUserText.label: 'Context ID'
  key   LglCntntMContext,

        @UI.hidden: true
        LglCntntMContextUUID,

        @Semantics.text: true
        @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
        @UI.selectionField.position: 15
        @UI.lineItem.position: 15
        @EndUserText.label: 'Context Name'
        LglCntntMContextTitle,

        @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
        @UI.selectionField.position: 20
        @UI.lineItem.position: 20
        @EndUserText.label: 'Context Owner'
        LglCntntMContextOwner,

        @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
        @UI.selectionField.position: 25
        @UI.lineItem.position: 25
        @EndUserText.label: 'Owner First Name'
        @Semantics.text: true
        _OwnerUserDetails.FirstName,

        @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
        @UI.selectionField.position: 30
        @UI.lineItem.position: 30
        @EndUserText.label: 'Owner Last Name'
        @Semantics.text: true
        _OwnerUserDetails.LastName,

        @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
        @UI.selectionField.position: 35
        @UI.lineItem.position: 35
        @EndUserText.label: 'Profile'
        @Semantics.text: true
        LglCntntMProfile,

        @UI.hidden:true
        LglCntntMLongTextUUID,

        @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
        @UI.selectionField: [{exclude: true}]
        @Search.fulltextIndex.required: true        
        @UI.hidden:true
        _Note.content as LglCntntMLongText,

        @UI.hidden:true
        LglCntntMGovLaw,

        @UI.hidden:true
        //_LCMGovLawVH.LglCntntMGovLawText,

        _LglCntntMGovLaw._LglCntntMGovLawText.LglCntntMGovLawText,

        @UI.hidden:true
        LglCntntMCntxtLanguage,

        @UI.hidden: true
        LglCntntMContextValidToDate,

        @UI.hidden: true
        LglCntntMCntxtAccessLvl,

        @UI.hidden: true
        LglCntntMMainOrgType,

        @UI.hidden: true
        _LglCntntMMainOrgTypeVH.LglCntntMMainOrgTypeName,

        @UI.hidden: true
        LglCntntMMainOrgCoCode,

        @UI.hidden: true
        _CompanyCodeValueHelp.CompanyCodeName,

        @UI.hidden: true
        LglCntntMMainOrgPurOrg,

        @UI.hidden: true
        _PurchasingOrganization.PurchasingOrganizationName,

        @UI.hidden: true
        LglCntntMMainOrgSalesOrg,

        @UI.hidden: true
        _SalesOrganizationText[1: Language = $session.system_language ].SalesOrganizationName,
        
        @UI.hidden: true
        LglCntntMIntegrationType,

        @UI.hidden: true
        IsEndOfPurposeBlocked

}
where
       LglCntntMContextStatus      = '02'
  and(
       LglCntntMContextValidToDate >= $session.system_date
    or LglCntntMContextValidToDate = '00000000'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_LCMCOMPANYCODEVALUEHELP",
"C_LGLCNTNTMMAINORGTYPEVH",
"I_LGLCNTNTMCONTEXTBASIC",
"I_LGLCNTNTMGOVLAW",
"I_LGLCNTNTMGOVLAWTEXT",
"I_LGLCNTNTMNOTOBSLTCNTXT",
"I_LGLCNTNTMUSERDETAILS",
"I_PURCHASINGORGANIZATION",
"I_SALESORGANIZATIONTEXT",
"SGBT_NTE_CDS_CONT"
],
"ASSOCIATED":
[
"C_LCMCOMPANYCODEVALUEHELP",
"C_LCMUSERVALUEHELP",
"C_LGLCNTNTMMAINORGTYPEVH",
"SGBT_NTE_CDS_CONT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/