C_GLACCOUNTHIERARCHYNODE

CDS View

API GL Acccount Hierarchy Node

C_GLACCOUNTHIERARCHYNODE is a CDS View in S/4HANA. API GL Acccount Hierarchy Node. It contains 1 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 1 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_GLAccountHierarchyNodeT view inner CONSUMPTION API GL Account Hierarchy Node Text

Fields (1)

KeyField CDS FieldsUsed in Views
NodeType NodeType 1 
@AbapCatalog.sqlViewName: 'CFIGLACCOUNTHN'
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType:  #CONSUMPTION

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'API GL Acccount Hierarchy Node'

@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MIXED

define view C_GLAccountHierarchyNode
  as select from    I_GLAccountHierarchyNode as _Node

    inner join      I_GLAccountHierarchy     as _Hierarchy  on  _Node.GLAccountHierarchy = _Hierarchy.GLAccountHierarchy
                                                            and _Node.ValidityEndDate    = _Hierarchy.ValidityEndDate // Hierarchy directory and hierarchy nodes have the same time slice


    
  association [0..1] to I_GLAcctHierNodeSemanticTag as _SemanticTag on  _SemanticTag.GLAccountHierarchy = _Node.GLAccountHierarchy
                                                                    and _SemanticTag.HierarchyNode      = _Node.HierarchyNode
                                                                    and _SemanticTag.ValidityEndDate    = _Node.ValidityEndDate
                                                                    and (
                                                                       _SemanticTag.SemanticTag         = 'ASSET'
                                                                       or _SemanticTag.SemanticTag      = 'LIAB_EQUIT'
                                                                       //                                                                       or _SemanticTag.SemanticTag      = 'REVENUE'

                                                                       //                                                                       or _SemanticTag.SemanticTag      = 'COST'

                                                                     )

  association [0..*] to C_GLAccountHierarchyNodeT   as _Text        on  $projection.GLAccountHierarchy = _Text.GLAccountHierarchy
                                                                    and $projection.HierarchyNode      = _Text.HierarchyNode
                                                                    and $projection.ValidityEndDate    = _Text.ValidityEndDate
                                                                    and $projection.GLAccount          = '' // just to show that this association is only to be followed if GLAcount is blank


{
      //I_GLAccountHierarchyNode

  key _Node.GLAccountHierarchy,
  key _Node.HierarchyNode,
  key _Node.ValidityEndDate,
      ParentNode,
      HierarchyVersion,
      _Node.ValidityStartDate,
      ChartOfAccounts,
      GLAccount,
      SequenceNumber,
      HierarchyNodeSequence,
      HierarchyNodeLevel,
      _Node.NodeType,
      _SemanticTag.SemanticTag            as SemanticTag,

      case _SemanticTag.SemanticTag
        when 'ASSET'          then 'AST'
        when 'LIAB_EQUIT'     then 'LEQ'
        else
          case _Node.SignIsInverted
            when 'X'          then 'INC'
            else                   'EXP'
          end
      end                                 as SACAccountType,
      
      case _Node.SignIsInverted
        when 'X'              then -1
        else                        1
      end                                as SignFlipFactor,

      /* Associations */
      _Text,
      _GLAccountInChartOfAccounts
      
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_GLACCOUNTHIERARCHY",
"I_GLACCOUNTHIERARCHYNODE",
"I_GLACCTHIERNODESEMANTICTAG"
],
"ASSOCIATED":
[
"C_GLACCOUNTHIERARCHYNODET",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_GLACCTHIERNODESEMANTICTAG"
],
"BASE":
[
"I_GLACCOUNTHIERARCHYNODE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More