C_CNDNCONTRWRKFLWREL

@AbapCatalog.sqlViewName: 'CCWFREL'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

// Todo: check if VDM-annotations should be there because of GFN - DPs...

@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.contract.type: #NONE

@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #INHERITED
@Consumption.semanticObject: 'ConditionContract'

// Todo: Needed? From example

@Metadata.ignorePropagatedAnnotations:true

@ObjectModel: {
   usageType: {
    dataClass: #MIXED,
    serviceQuality: #D,
    sizeCategory:  #L
   },
   semanticKey: [ 'ConditionContract' ],
   representativeKey: 'ConditionContract'
}

@UI: {
  textArrangement: #TEXT_FIRST,
  headerInfo: {
    title: {
        type: #WITH_INTENT_BASED_NAVIGATION,
        value: 'DocumentTitle'
    },
    description: {
      value: 'DataPoint02'
    }
  }
}

@EndUserText.label: 'cds-view to release workflow scenarios for CndnContr'
define view C_CndnContrWrkflwRel
  as select from I_ConditionContract as Contract
  //  Todo: Needed? Try to add Pop-Up

  //  association [0..1] to I_UserContactCard           as _UserContactCard on $projection.CreatedByUser = _UserContactCard.ContactCardID

  association [1..*] to C_CndnContrWrkflwSettlmtCal as _SettlmtCal on _SettlmtCal.ConditionContract = $projection.ConditionContract
{

      /******************
      * Facet-Definition
      *******************/

      @UI.facet: [
        // Information Area

        {
          id:'InformationArea',
          purpose: #STANDARD,
          type: #COLLECTION,
          isSummary,
          position: 10
        },
            {
              label: 'General Information',
              id: 'BasicData',
              parentId: 'InformationArea',
              type: #FIELDGROUP_REFERENCE,
              targetQualifier: 'BasicDataRefGeneralInfos1',
              position: 10
            },
            {
              label: 'Administrational Data',
              id: 'BasicUserData',
              parentId: 'InformationArea',
              type: #FIELDGROUP_REFERENCE,
              targetQualifier: 'BasicUserData',
              position: 20
            },
            {
              label: 'Sales',
              id: 'SuplrOrgData',
              parentId: 'InformationArea',
              type: #FIELDGROUP_REFERENCE,
              targetQualifier: 'SupOrgData',
              position: 30
            },
            {
              label: 'Purchasing',
              id: 'CustOrgData',
              parentId: 'InformationArea',
              type: #FIELDGROUP_REFERENCE,
              targetQualifier: 'CustOrgData',
              position: 40
            },
          // Detail Area (Table)

          {
            id:'SettlmtCalTable',
            type: #LINEITEM_REFERENCE,
            targetQualifier: 'SettlmtCal',
            targetElement: '_SettlmtCal',
            label: 'Settlement Calender',
            position: 10,
            purpose: #STANDARD
          }
        ]


         // Key attribute

      @UI.fieldGroup: [{qualifier: 'BasicDataRefGeneralInfos1', position: 10, importance: #HIGH}]
      @Consumption.semanticObject: 'ConditionContract'
  key Contract.ConditionContract,


      /*****************************
      * Header-Section
      ******************************/

      // DocumentTitle (headerInfo -> Title)

      @Consumption.semanticObject: 'ConditionContract'
      //Deleted - concat_with_space('Release Condition Contract' , ltrim(Contract.ConditionContract, '0'), 1) as DocumentTitle,

      //Reserve 70 chars for the document title. Because of translatability, the title text is set in the backend via service extension class

      concat_with_space(' ' , ' ' , 68)                                                                    as DocumentTitle,

      // Condition Contract Type + Description (headerInfo -> Description)

      @UI.dataPoint: {
        targetValue: 'DataPoint02'
      }
      CndnContrType                                                                                        as DataPoint02,

      // Needed because of inheritance of dcl

      @UI.hidden: true
      CndnContrType,

      @Semantics.text: true
      @UI.dataPoint: {
        targetValue: 'DataPoint03'
      }
      @EndUserText.label: 'Contract Type Desc.'
      _CndnContrType._Text[1: Language = $session.system_language ].CndnContrTypeDesc                      as DataPoint03,

      // Customer / Supplier

      @ObjectModel: {
        foreignKey.association: '_Customer',
        text.element: [ 'CustomerName' ]
      }
      @UI: {
        fieldGroup: [{qualifier: 'SupOrgData', position: 5, importance: #HIGH}],
        textArrangement: #TEXT_FIRST
      }
      Contract.Customer,

      @Semantics.text: true
      @UI.hidden: true
      _Customer.CustomerName,

      @ObjectModel: {
        foreignKey.association: '_Supplier',
        text.element: [ 'SupplierName' ]
      }
      @UI: {
        fieldGroup: [{qualifier: 'CustOrgData', position: 5, importance: #HIGH}],
        textArrangement: #TEXT_FIRST
      }
      Contract.Supplier,

      @Semantics.text: true
      @UI.hidden: true
      _Supplier.SupplierName,



      /*****************************
      * Detail-Section
      ******************************/



      /* General Information */


      // Validity

      @UI: {
        fieldGroup: [{ qualifier:'BasicDataRefGeneralInfos1', importance: #HIGH, position: 40 }]
      }
      Contract.CndnContrValidFrom                                                                          as CndnContrValidFrom,
      @UI: {
          fieldGroup: [{ qualifier: 'BasicDataRefGeneralInfos1', position: 50, importance: #HIGH}]
      }
      Contract.CndnContrValidTo                                                                            as CndnContrValidTo,


      // External Reference

      @UI: {
        fieldGroup: [{qualifier: 'BasicDataRefGeneralInfos1', position: 30, importance: #HIGH}]
      }
      ExternalDocumentReferenceID,


      // Activation Status

      @ObjectModel: {
        text.element: ['CndnContrIsInactiveName']
      }
      @UI: {
        fieldGroup: [{qualifier: 'BasicDataRefGeneralInfos1', position: 60, importance: #HIGH}]
      }
      @Semantics: {
          booleanIndicator: true
      }
      Contract.CndnContrIsInactive,

      @Semantics.text: true
      @Consumption.filter.hidden: true
      @UI.hidden: true
      Contract._CndnContrIsInactive._Text[1: Language = $session.system_language ].CndnContrIsInactiveName as CndnContrIsInactiveName,



      /* Administrational Data */


      // Created By

      @ObjectModel: {
        text.element:  [ 'UserFullName' ]
      }
      @UI: {
        fieldGroup: [{qualifier: 'BasicUserData', position: 10, importance: #HIGH, type: #WITH_INTENT_BASED_NAVIGATION }],
        textArrangement: #TEXT_ONLY
      }
      CreatedByUser,

      @Semantics.text: true
      @UI.hidden: true
      _CreatedByUser.UserDescription                                                                       as UserFullName,


      // Created On

      @UI: {
        fieldGroup: [{qualifier: 'BasicUserData', position: 20, importance: #HIGH}]
      }
      CreationDate,


      // Last Changed By

      @ObjectModel: {
        text.element:  [ 'UserFullName' ]
      }
      @UI: {
        fieldGroup: [{qualifier: 'BasicUserData', position: 30, importance: #HIGH}]
      }
      LastChangedByUser,



      /* Sales */


      // Sales Organization

      @ObjectModel: {
        foreignKey.association: '_SalesOrganization',
        text.element: [ 'SalesOrganizationName' ]
      }
      @UI: {
        fieldGroup: [{qualifier: 'SupOrgData', position: 10, importance: #HIGH}] //SupCustOrgData

      }
      SalesOrganization,

      @UI.hidden:true
      @Semantics.text: true
      _SalesOrganization._Text[1: Language=$session.system_language ].SalesOrganizationName                as SalesOrganizationName,


      // Distribution Channel

      @ObjectModel: {
        foreignKey.association: '_DistributionChannel',
        text.element: [ 'DistributionChannelName' ]
      }
      @UI: {
        fieldGroup: [{qualifier: 'SupOrgData', position: 20, importance: #MEDIUM }] //SupCustOrgData

      }
      DistributionChannel,

      @UI.hidden:true
      @Semantics.text: true
      _DistributionChannel._Text[1: Language=$session.system_language ].DistributionChannelName            as DistributionChannelName,


      // Division

      @ObjectModel: {
        foreignKey.association: '_Division',
        text.element: [ 'DivisionName' ]
      }
      @UI: {
        fieldGroup: [{ qualifier: 'SupOrgData', position: 30, importance: #MEDIUM }] //SupOrgData

      }
      Division,

      @UI.hidden:true
      @Semantics.text: true
      _Division._Text[1: Language=$session.system_language ].DivisionName,



      /* Purchasing */

      // Purchasing Group

      @ObjectModel: {
        foreignKey.association: '_PurchasingGroup',
        text.element: [ 'PurchasingGroupName' ]
      }
      @UI: {
        fieldGroup: [{qualifier: 'CustOrgData', position: 40, importance: #HIGH}] //SupCustOrgData

      }
      PurchasingGroup,

      @UI.hidden:true
      @Semantics.text: true
      _PurchasingGroup.PurchasingGroupName,


      // Purchasing Organisation

      @ObjectModel: {
        foreignKey.association: '_PurchasingOrganization',
        text.element: [ 'PurchasingOrganizationName' ]
      }
      @UI: {
        fieldGroup: [{qualifier: 'CustOrgData', position: 50, importance: #HIGH}] //CustOrgData

      }
      PurchasingOrganization,

      @UI.hidden:true
      @Semantics.text: true
      _PurchasingOrganization.PurchasingOrganizationName,


      // Company Code

      @ObjectModel: {
        text.element: [ 'CompanyCodeName' ]
      }
      @UI: {
        fieldGroup: [{qualifier: 'CustOrgData', position: 60, importance: #HIGH}] //CustOrgData

      }
      CompanyCode,

      @UI.hidden:true
      @Semantics.text: true
      _CompanyCode.CompanyCodeName,


      // PriorSupplier

      @UI.hidden: true
      Contract.PriorSupplier,

      /* Worker related fields */
      @Consumption.hidden: true
      Contract.PersonWorkAgreement,
      @Consumption.hidden: true
      Contract.CndnContrWorkerCostCenter,


      /*****************************
      * Associations
      ******************************/

      //      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]

      //      _UserContactCard,

      _Division,
      _CndnContrType,
      _DistributionChannel,
      _SalesOrganization,
      _PurchasingGroup,
      _PurchasingOrganization,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _SettlmtCal,
      _Customer,
      _Supplier,
      _PriorSupplier,
      @Consumption.hidden: true
      _PersonWorkAgreement

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNDNCONTRISINACTIVE",
"I_CNDNCONTRISINACTIVETEXT",
"I_CNDNCONTRTYPE",
"I_CNDNCONTRTYPETEXT",
"I_COMPANYCODE",
"I_CONDITIONCONTRACT",
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNEL",
"I_DISTRIBUTIONCHANNELTEXT",
"I_DIVISION",
"I_DIVISIONTEXT",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SALESORGANIZATION",
"I_SALESORGANIZATIONTEXT",
"I_SUPPLIER",
"I_USER"
],
"ASSOCIATED":
[
"C_CNDNCONTRWRKFLWSETTLMTCAL",
"I_CNDNCONTRTYPE",
"I_CUSTOMER",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_PERSONWORKAGREEMENT_1",
"I_PURCHASINGGROUP",
"I_PURCHASINGORGANIZATION",
"I_SALESORGANIZATION",
"I_SUPPLIER"
],
"BASE":
[
"I_CONDITIONCONTRACT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/