A_CNSLDTNCUSTOMERHIER

CDS View

Combined Customer Hierarchy

A_CNSLDTNCUSTOMERHIER is a CDS View in S/4HANA. Combined Customer Hierarchy. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_CnsldtnCustomerHierT view inner BASIC Combined Customer Hierarchy Text 
@AbapCatalog:{
  sqlViewName: 'ACSCUSTOMERHIER',
  compiler.compareFilter: true,
  preserveKey: true
  }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL}
  }
@VDM:{
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
  }
@EndUserText.label: 'Combined Customer Hierarchy'
@OData.entitySet.name: 'CustomerHier'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view A_CnsldtnCustomerHier
  as select from I_CnsldtnCustomerHierNode

  association [0..1] to A_CnsldtnCustomer        as _CnsldtnCustomer        on  $projection.Customer = _CnsldtnCustomer.Customer

  association [0..*] to A_CnsldtnCustomerHierT   as _CnsldtnCustomerHierT   on  $projection.AdditionalMasterDataHierarchy = _CnsldtnCustomerHierT.AdditionalMasterDataHierarchy
                                                                            and $projection.HierarchyNode                 = _CnsldtnCustomerHierT.HierarchyNode
                                                                            and $projection.Customer                      = ''

  association [0..*] to A_CnsldtnCustomerHierT   as _CnsldtnCustomerHierT_2 on  $projection.AdditionalMasterDataHierarchy = _CnsldtnCustomerHierT_2.AdditionalMasterDataHierarchy
                                                                            and $projection.HierarchyNode                 = _CnsldtnCustomerHierT_2.HierarchyNode
                                                                            and $projection.ValidityEndDate               = _CnsldtnCustomerHierT_2.ValidityEndDate
                                                                            and $projection.Customer                      = ''

  association [0..*] to A_CnsldtnCustomerT       as _CnsldtnCustomerT       on  $projection.Customer = _CnsldtnCustomerT.Customer

  association [0..1] to A_CnsldtnCustomerHierDir as _CnsldtnCustomerHierDir on  $projection.AdditionalMasterDataHierarchy = _CnsldtnCustomerHierDir.AdditionalMasterDataHierarchy
                                                                            and $projection.ValidityEndDate               = _CnsldtnCustomerHierDir.ValidityEndDate
{
      @ObjectModel.foreignKey.association: '_CnsldtnCustomerHierDir'
  key cast(ConsolidationCustomerHierarchy as fincs_universalhierhierarchyid preserving type ) as AdditionalMasterDataHierarchy,

      @ObjectModel.text.association: '_CnsldtnCustomerHierT_2'
  key HierarchyNode,

      @Semantics.businessDate.to: true
  key ValidityEndDate,

      ParentNode,
      @Semantics.businessDate.from: true
      ValidityStartDate,
      @ObjectModel.text.association: '_CnsldtnCustomerT'
      Customer,

      // STS - compatible ATC cleanup change - to be removed

      cast(HierarchyNodeSequence as abap.char( 56 ) )                                         as SequenceNumber,
      // STS - compatible ATC cleanup change - to be removed


      // STS - compatible ATC cleanup change

      HierarchyNodeSequence,
      // STS - compatible ATC cleanup change


      HierarchyNodeLevel,
      NodeType,

      @Consumption.hidden: true
      cast('CS08' as hrytype preserving type )                                                as MDHierType,
      @Consumption.hidden: true
      cast('CS08' as hrytype preserving type )                                                as HierarchyType,

      //      _CnsldtnCustomerHierNode.HierarchyType,

      @Consumption.hidden: true
      _CnsldtnCustomerHierDir,


      _CnsldtnCustomer,
      _CnsldtnCustomerHierT,
      _CnsldtnCustomerHierT_2,
      _CnsldtnCustomerT
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CNSLDTNCUSTOMERHIERNODE"
],
"ASSOCIATED":
[
"A_CNSLDTNCUSTOMER",
"A_CNSLDTNCUSTOMERHIERDIR",
"A_CNSLDTNCUSTOMERHIERT",
"A_CNSLDTNCUSTOMERT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More