UPOV_NETOBJ_WITH_STATUS

@AbapCatalog.sqlViewName: 'UPOS_NOBJ_SOURCE'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@EndUserText.label: 'Netobjects with Source  Status'
define view UPOV_NETOBJ_WITH_STATUS
  as select from    UPOV_NETOBJS_NETWORK as uom_obj
    inner join      gho_iflot_ext        as floc    on  floc.tplnr           = uom_obj.from_floc
                                                    and floc.gho_netobj_type = 'GHO_WC'
    inner join      gho_iflot_ext        as wl_floc on  wl_floc.tplnr           = floc.gho_wc_ref_id
                                                    and wl_floc.gho_netobj_type = 'GHO_WELL'
    left outer join UPOV_NETOBJS         as well    on well.tplnr = floc.gho_wc_ref_id
    left outer join UPOV_NETOBJS         as wc      on wc.tplnr = uom_obj.from_floc
{
//  uom_obj.status,

  uom_obj.pn_label                                                                as pn_strno,
  cast( uom_obj.pn_label as oiu_dn_no)                                            as dn_no,
  cast('WC' as oiu_from_node_type)                                                as node_type,
  uom_obj.from_label                                                              as obj_strno,
  cast('' as oiu_mp_no)                                                           as mp,
  cast(well.strno as oiu_wl_no)                                                   as well,
  cast(uom_obj.from_label as oiu_wc_no)                                           as wc,
  cast(wl_floc.gho_field  as oiu_fieldid)                                         as field,
  cast(wl_floc.gho_platform  as oiu_pf_no)                                        as platform,
  cast(wl_floc.gho_reservoir as oiu_resrvid)                                      as reservoir,
  uom_obj.datva                                                                   as datva,
  uom_obj.zeita                                                                   as zeita,
  uom_obj.datvb                                                                   as datvb,
  uom_obj.zeitb                                                                   as zeitb

}
where
  uom_obj.from_netobj_type = 'GHO_WC'

union

select from       UPOV_NETOBJS_NETWORK as uom_obj
  inner join      gho_iflot_ext        as floc    on  floc.tplnr           = uom_obj.to_floc
                                                  and floc.gho_netobj_type = 'GHO_WC'
  inner join      gho_iflot_ext        as wl_floc on  wl_floc.tplnr           = floc.gho_wc_ref_id
                                                  and wl_floc.gho_netobj_type = 'GHO_WELL'
  left outer join UPOV_NETOBJS         as well    on well.tplnr = floc.gho_wc_ref_id
  left outer join UPOV_NETOBJS         as wc      on wc.tplnr = uom_obj.from_floc
{
 // uom_obj.status,

  uom_obj.pn_label                                                                                   as pn_strno,
  cast( uom_obj.pn_label as oiu_dn_no)                                                               as dn_no,
  cast('WC' as oiu_from_node_type)                                                                   as node_type,
  uom_obj.to_label                                                                                   as obj_strno,
  cast('' as oiu_mp_no)                                                                              as mp,
  cast(well.strno as oiu_wl_no)                                                                      as well,
  cast(uom_obj.to_label as oiu_wc_no)                                                                as wc,
  cast(wl_floc.gho_field  as oiu_fieldid)                                                            as field,
  cast(wl_floc.gho_platform  as oiu_pf_no)                                                           as platform,
  cast(wl_floc.gho_reservoir as oiu_resrvid)                                                         as reservoir,
  uom_obj.datva                                                                                      as datva,
  uom_obj.zeita                                                                                      as zeita,
  uom_obj.datvb                                                                                      as datvb,
  uom_obj.zeitb                                                                                      as zeitb

}
where
  uom_obj.to_netobj_type = 'GHO_WC'

union

select from UPOV_NETOBJS_NETWORK as uom_obj
{
//  uom_obj.status,

  uom_obj.pn_label                                                                                as pn_strno,
  cast( uom_obj.pn_label as oiu_dn_no)                                                            as dn_no,
  cast('MP' as oiu_from_node_type)                                                                as node_type,
  uom_obj.from_label                                                                              as obj_strno,
  cast(uom_obj.from_label as oiu_mp_no)                                                           as mp,
  cast('' as oiu_wl_no)                                                                           as well,
  cast('' as oiu_wc_no)                                                                           as wc,
  cast(''  as oiu_fieldid)                                                                        as field,
  cast(''  as oiu_pf_no)                                                                          as platform,
  cast('' as oiu_resrvid)                                                                         as reservoir,
  uom_obj.datva                                                                                   as datva,
  uom_obj.zeita                                                                                   as zeita,
  uom_obj.datvb                                                                                   as datvb,
  uom_obj.zeitb                                                                                   as zeitb

}
where
      uom_obj.from_netobj_type <> 'GHO_WC'
  and uom_obj.from_netobj_type <> 'GHO_WELL'
  and uom_obj.from_netobj_type <> 'GHO_PN'
  and uom_obj.from_netobj_type <> 'GHO_FS'

union

select from UPOV_NETOBJS_NETWORK as uom_obj
{
 // uom_obj.status,

  uom_obj.pn_label                                                                              as pn_strno,
  cast( uom_obj.pn_label as oiu_dn_no)                                                          as dn_no,
  cast('MP' as oiu_from_node_type)                                                              as node_type,
  uom_obj.to_label                                                                              as obj_strno,
  cast(uom_obj.to_label as oiu_mp_no)                                                           as mp,
  cast('' as oiu_wl_no)                                                                         as well,
  cast('' as oiu_wc_no)                                                                         as wc,
  cast(''  as oiu_fieldid)                                                                      as field,
  cast(''  as oiu_pf_no)                                                                        as platform,
  cast('' as oiu_resrvid)                                                                       as reservoir,
  uom_obj.datva                                                                                 as datva,
  uom_obj.zeita                                                                                 as zeita,
  uom_obj.datvb                                                                                 as datvb,
  uom_obj.zeitb                                                                                 as zeitb

}
where
      uom_obj.to_netobj_type <> 'GHO_WC'
  and uom_obj.to_netobj_type <> 'GHO_WELL'
  and uom_obj.to_netobj_type <> 'GHO_PN'
  and uom_obj.to_netobj_type <> 'GHO_FS'