S_EAMWorkflowRecipientVH

DDL: S_EAMWORKFLOWRECIPIENTVH SQL: EAMPPWFL Type: view

People Picker For Order Approver

S_EAMWorkflowRecipientVH is a CDS View that provides data about "People Picker For Order Approver" in SAP S/4HANA. It reads from 4 data sources (I_PersonWorkAgrmtOrglDetails, I_PersonWorkAgrmtStatus, I_PersonWorkAgreement_1, I_WorkforcePerson) and exposes 3 fields with key field UserID.

4 data source(s) 3 fields

Data Sources (4)

SourceAliasJoin Type
I_PersonWorkAgrmtOrglDetails _EmployOrgDet inner
I_PersonWorkAgrmtStatus _EmployStatDet inner
I_PersonWorkAgreement_1 _PersonWorkAgreement inner
I_WorkforcePerson _WorkforcePerson inner

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName EAMPPWFL view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #REQUIRED view
EndUserText.label People Picker For Order Approver view
ObjectModel.semanticKey UserID view
ObjectModel.representativeKey UserID view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MIXED view
Search.searchable true view

Fields (3)

KeyFieldSource TableSource FieldDescription
KEY UserID _User UserID
FullName _User PersonFullName
Employee 
@AbapCatalog.sqlViewName: 'EAMPPWFL'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck:  #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'People Picker For Order Approver'

@ObjectModel: {
    semanticKey: 'UserID',
    representativeKey: 'UserID',
    usageType.serviceQuality: #C,
    usageType.sizeCategory: #L,
    usageType.dataClass: #MIXED
}
@Search.searchable: true

define view S_EAMWorkflowRecipientVH 
  as select distinct from I_BusinessUser  as _User   
 inner join I_WorkforcePerson             as _WorkforcePerson     on _WorkforcePerson.BusinessPartnerUUID   = _User.BusinessPartnerUUID
 inner join I_PersonWorkAgreement_1       as _PersonWorkAgreement on _PersonWorkAgreement.Person            =  _WorkforcePerson.Person
 inner join I_PersonWorkAgrmtOrglDetails  as _EmployOrgDet        on _EmployOrgDet.PersonWorkAgreement      = _PersonWorkAgreement.PersonWorkAgreement 
 inner join I_PersonWorkAgrmtStatus       as _EmployStatDet       on  _EmployOrgDet.PersonWorkAgreement     = _EmployStatDet.PersonWorkAgreement
                                                                  and _EmployStatDet.StartDate              <= _EmployOrgDet.EndDate
                                                                  and _EmployStatDet.EndDate                >= _EmployOrgDet.StartDate

 // association [0..1] to S_CTRUSERSTOAUTHPROFILE as _PotentialApprovers on $projection.UserID = _PotentialApprovers.UserID


{
      @ObjectModel.text.element: 'FullName'
      @Search: { defaultSearchElement: true, ranking: #MEDIUM }
  key _User.UserID                      as UserID,

      @Semantics.text: true
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      _User.PersonFullName        as FullName,
      cast( _User.BPIdentificationNumber as eam_employee_id ) as Employee
     // _PotentialApprovers


}
where _EmployOrgDet.StartDate          <= $session.system_date
  and _EmployOrgDet.EndDate            >= $session.system_date
  and _EmployStatDet.WorkAgreementStatus = '1'   
  and _User.IsBusinessPurposeCompleted = ''

Learn More