SRF_Helper_MY_VATDeclaration

@AbapCatalog.sqlViewName: 'SRFMYVATDECLN'
@EndUserText.label: 'Calculated Values for MY VAT Declaration'
@AccessControl.authorizationCheck: #NOT_ALLOWED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #P
define view SRF_Helper_MY_VATDeclaration

  with parameters
    P_TaxBox5aBalance      : mwsts,
    P_TaxBox5bBalance      : mwsts,
    P_TaxBox6aBalance      : mwsts,
    P_TaxBox6bBalance      : mwsts,
    P_TaxBox10Balance      : mwsts,
    P_TaxBox11Balance      : mwsts,
    P_TaxBox12Balance      : mwsts,
    P_TaxBox12aBalance     : mwsts,
    P_TaxBox13Balance      : mwsts,
    P_TaxBox14Balance      : mwsts,
    P_TaxBox15Balance      : mwsts,
    P_TaxBox16Balance      : mwsts,
    P_TaxBox17Balance      : mwsts,
    P_TaxBox18Balance      : mwsts,
    P_Top5OutputTaxAmount  : mwsts,
    P_TotalOutputTaxAmount : mwsts,
    P_SourceCurrency       : abap.cuky( 5 ),
    P_IsCarryForward       : abap.char(1)
  as select from I_SAPClient //dummy select, CDS view only used for calculations

{
  cast ( $parameters.P_TaxBox5aBalance * -1  as mwsts)                                                      as TaxBox5aBalance,
  cast ( $parameters.P_TaxBox5bBalance*-1    as mwsts)                                                      as TaxBox5bBalance,
  cast ( $parameters.P_TaxBox6aBalance       as mwsts)                                                      as TaxBox6aBalance,
  cast ( $parameters.P_TaxBox6bBalance       as mwsts)                                                      as TaxBox6bBalance,
  $parameters.P_IsCarryForward                                                                              as TaxBox09Yes,
  $parameters.P_IsCarryForward                                                                              as TaxBox09No,
  cast ( abs($parameters.P_TaxBox5bBalance*-1 - $parameters.P_TaxBox6bBalance) as mwsts)                    as TaxBox07Balance,
  cast ( $parameters.P_TaxBox10Balance * -1  as mwsts)                                                      as TaxBox10Balance,
  cast ( $parameters.P_TaxBox11Balance * -1  as mwsts)                                                      as TaxBox11Balance,
  cast ( ( $parameters.P_TaxBox12aBalance + $parameters.P_TaxBox12Balance ) * -1   as mwsts)                as TaxBox12aBalance,
  cast ( $parameters.P_TaxBox12Balance * -1  as mwsts)                                                      as TaxBox12Balance,
  cast ( $parameters.P_TaxBox13Balance * -1  as mwsts)                                                      as TaxBox13Balance,
  cast ( $parameters.P_TaxBox14Balance       as mwsts)                                                      as TaxBox14Balance,
  cast ( $parameters.P_TaxBox15Balance * -1  as mwsts)                                                      as TaxBox15Balance,
  cast ( $parameters.P_TaxBox16Balance       as mwsts)                                                      as TaxBox16Balance,
  cast ( $parameters.P_TaxBox17Balance       as mwsts)                                                      as TaxBox17Balance,
  cast ( $parameters.P_TaxBox18Balance * -1  as mwsts)                                                      as TaxBox18Balance,
  cast ( $parameters.P_TotalOutputTaxAmount - $parameters.P_Top5OutputTaxAmount    as mwsts)                as OthersOutputTaxAmount,
  case $parameters.P_TotalOutputTaxAmount
  when 0 then  cast ( 0 as mwsts)
  else
  cast ( Division(  $parameters.P_TotalOutputTaxAmount - $parameters.P_Top5OutputTaxAmount,  $parameters.P_TotalOutputTaxAmount, 4 ) * 100 as mwsts)
  end                                                                                                       as OthersTaxPercentage,
  $parameters.P_TotalOutputTaxAmount                                                                        as TotalOutputTaxAmount,
  case $parameters.P_SourceCurrency
  when '' then cast( 'MYR' as waers )
  else cast( $parameters.P_SourceCurrency as waers ) end
                                                                                                            as SourceCurrency,
  $session.client                                                                                           as SystemClient,
  $session.system_date                                                                                      as SystemDate

}