SHSM_IAOM_CRM_AUFK

@AbapCatalog.sqlViewName: 'SHSMIAOMCRMAUFK'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ClientHandling.algorithm : #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.dataCategory: #VALUE_HELP
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Internal Orders Created from CRM Service'
define view SHSM_IAOM_CRM_AUFK
  as select from    aufk             as au
    inner join      iaom_assignments as ag on ag.object_no = au.objnr
    inner join      iaom_crmsrv_exat as ex on ex.ext_object_id = ag.ext_object_id
    inner join      iaom_ext_obj_inf as ob on  ob.ext_object_id   = ag.ext_object_id
                                           and ob.bus_scenario_id = ag.bus_scenario_id
    left outer join kna1             as ka on ka.kunnr = ex.kunnr
{
  //  au.mandt,

  ex.ext_object_id,
  au.aufnr,
  au.autyp,
  au.auart,
  ex.object_id,
  ex.process_descript,
  ex.process_type,
  ex.service_org_resp,
  ex.service_org,
  ex.enterprise_service_org,
  ex.service_team,
  ex.number_int,
  ex.item_description,
  ex.itm_type,
  ex.service_tech_org,
  ex.category_id,
  ex.kunnr,
  @Consumption.hidden: true
  ka.begru
}
where
      ag.bus_scenario_id =  'CRMSRV'
  and ob.usage_reference <> 'C';