SADL_V_EXP_Query

@AbapCatalog.sqlViewName: 'SADL_V_E_QUERY'
@EndUserText.label: 'view_label'
@AccessControl.authorizationCheck: #NOT_REQUIRED

@Analytics.query : true
define view SADL_V_EXP_Query
  as select from snwd_so 
  association  [0..*]
    to SADL_V_EXP_SalesOrderItem as items // via backlink --> not yet possible

    on node_key = items.salesOrderItemKey
  association 
    to SADL_V_EXP_BusinessPartner as customer
    on buyer_guid = customer.businessPartnerKey
{
    key node_key as salesOrderKey,
    so_id        as salesOrderId,
    created_by   as createdBy,   
    created_at   as createdAt,
    changed_by   as changedBy,
    changed_at   as changedAt,
    @Semantics.currencyCode 
    currency_code as currencyCode,
    @Semantics.amount.currencyCode: 'currencyCode' 
    @DefaultAggregation: #SUM
    gross_amount as grossAmount ,
    @Semantics.amount.currencyCode: 'currencyCode' 
    net_amount   as netAmount,
    @Semantics.amount.currencyCode: 'currencyCode' 
    tax_amount   as taxAmount,
    lifecycle_status as lifecycleStatus,
    billing_status   as billingStatus,
    delivery_status  as deliveryStatus,

    items            as Items,     // make the association public


    buyer_guid       as buyerGuid, // needed for association customer

    customer         as Customer,   // make the association public

    @Consumption.labelElement : 'companyName'
    customer.businessPartnerId as businessPartnerId,
    @DefaultAggregation: #NONE
    customer.company_name as companyName,
    @DefaultAggregation: #NONE
    customer.email_address as companyEmailAddress,
    @Consumption.groupWith : 'businessPartnerId'
    customer.web_address as companyWebAddress

}