Rsrts_Cds_Query_List

@AbapCatalog.sqlViewName: 'RSRTS_CDS_QRY'
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.compiler.compareFilter: true
 
define view Rsrts_Cds_Query_List
  as select from    Rsrts_Cds_Repdir               as repdir
    inner join      ddldependency                  as dep_view         on  dep_view.objectname = repdir.sqlNameQuery
                                                                       and dep_view.state      = 'A'
                                                                       and dep_view.objecttype = 'VIEW'
                                                                       
    inner join      ddldependency                  as dep_stob         on  dep_stob.ddlname    = dep_view.ddlname
                                                                       and dep_stob.state      = dep_view.state
                                                                       and dep_stob.objecttype = 'STOB'
    // only released objects    

    inner join      ARS_APIS_RELEASED_C1_OR_GROUPS as ars_api_released on  ars_api_released.object_type = 'CDS_STOB'
                                                                       and ars_api_released.object_key  = dep_stob.objectname
                                                                       //and ( ars_api_released.state = 'RELEASED' or ars_api_released.state = 'DEPRECATED' ) // DEPRECATED too long!

                                                                       and ars_api_released.state = 'RELEASED'         
                                                                                                                                     
    inner join      ddheadanno                     as headanno         on  headanno.strucobjn = dep_stob.objectname
                                                                       and headanno.name      = 'ANALYTICS.QUERY'
                                                                       and (    headanno.value      = 'true'
                                                                             or headanno.value   = ''
                                                                            )
    inner join      ddldependency                  as dep_cube_view    on  dep_cube_view.objectname = repdir.sqlNameCube
                                                                       and dep_cube_view.state      = 'A'
                                                                       and dep_cube_view.objecttype = 'VIEW'
                                                                       
    inner join      ddldependency                  as dep_cube_stob    on  dep_cube_stob.ddlname    = dep_cube_view.ddlname
                                                                       and dep_cube_stob.state      = dep_stob.state
                                                                       and dep_cube_stob.objecttype = 'STOB'
                                                                       
    left outer join ddheadanno                     as headannotext     on  headannotext.strucobjn = dep_stob.objectname
                                                                       and headannotext.name      = 'ENDUSERTEXT.LABEL'
                                                                       
    left outer join ddddlsrc02bt                   as text             on  text.ddlname    = dep_view.ddlname
                                                                       and text.strucobjn  = dep_stob.objectname
                                                                       and text.as4local   = dep_view.state
                                                                       and text.ddlanguage = $session.system_language
{
  key repdir.compid                                                                                  as compid,
      repdir.infocube                                                                                as infoprovider,
      dep_view.ddlname                                                                               as ddlname,
      dep_stob.objectname                                                                            as view_name,
      dep_view.objectname                                                                            as sql_view_name,
      dep_cube_view.ddlname                                                                          as cube_ddlname,
      dep_cube_stob.objectname                                                                       as cube_view_name,
      dep_cube_view.objectname                                                                       as cube_sql_view_name,
      text.ddtext                                                                                    as description,
      headannotext.value                                                                             as enduser_text_label
      //      case

      //         when text.ddtext is null or text.ddtext = '' then SUBSTRING( headannotext.value, 1, LENGTH( headannotext.value ) )  else text.ddtext end as real_desciption

}