R_TrdgDocIsCompleteText

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@EndUserText.label: 'Document Complete - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'TrdgDocIsComplete'
@ObjectModel.supportedCapabilities: 
[ #CDS_MODELING_ASSOCIATION_TARGET,
  #CDS_MODELING_DATA_SOURCE,
  #LANGUAGE_DEPENDENT_TEXT,
  #SEARCHABLE_ENTITY,
  #SQL_DATA_SOURCE]
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.sizeCategory: #S
@Search.searchable: true
define view entity R_TrdgDocIsCompleteText
  as select from dd07t
  association        to parent R_TrdgDocIsComplete as _TrdgDocIsComplete on $projection.TrdgDocIsComplete = _TrdgDocIsComplete.TrdgDocIsComplete
  association [0..1] to I_Language                 as _Language          on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language,
      @ObjectModel.foreignKey.association: '_TrdgDocIsComplete'
      @ObjectModel.text.element: ['TrdgDocCompleteName']
      @Semantics.text: true
  key cast( dd07t.domvalue_l as wb2_doc_is_complete )   as TrdgDocIsComplete,
      @Consumption.hidden: true
      dd07t.domvalue_l                                  as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      @Consumption.filter.hidden: true
      @UI.textArrangement: #TEXT_ONLY
      ddtext                                            as TrdgDocCompleteName,
      
       //Associations

      _TrdgDocIsComplete,
      _Language
}
where
      dd07t.domname  = 'FLAG'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'