R_TrdgDocBusinessDataBasic

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   compositionRoot: false,
   representativeKey: 'TradingDocument',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   }
}
@Analytics: {
    dataExtraction.enabled: false,
    internalName: #LOCAL
}
@EndUserText.label: 'Business Data of Trading Document'

/* Basic Layer   */

define view entity R_TrdgDocBusinessDataBasic
  as select from wbhd

  //Association

  association [0..1] to R_TrdgDocPurgDelivAddrCat   as _TrdgDocPurgDelivAddrCat     on $projection.TrdgDocPurgDelivAddrCat = _TrdgDocPurgDelivAddrCat.TrdgDocPurgDelivAddrCat
  association [0..1] to R_TrdgDocPurgDocCat         as _TrdgDocPurgDocCat           on $projection.TrdgDocPurgDocCat = _TrdgDocPurgDocCat.PurchasingDocumentCategory
  association [0..1] to I_User                      as _CreatedByUser               on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_Supplier                  as _Supplier                    on $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_PurchasingOrganization    as _PurchasingOrganization      on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
  association [0..1] to I_PurchasingGroup           as _PurchasingGroup             on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..1] to I_Currency                  as _Currency                    on $projection.TrdgDocPurgCurrency = _Currency.Currency
  association [0..1] to I_ExchangeRateType          as _TrdgDocPurgExchangeRateType on $projection.TrdgDocPurgExchangeRateType = _TrdgDocPurgExchangeRateType.ExchangeRateType
  association [0..1] to I_IncotermsClassification   as _PurgIncotermsClassification on $projection.PurgIncotermsClassification = _PurgIncotermsClassification.IncotermsClassification
  association [0..1] to I_IncotermsClassification   as _SlsIncotermsClassification  on $projection.SlsIncotermsClassification = _SlsIncotermsClassification.IncotermsClassification
  association [0..1] to I_ShippingInstruction       as _ShippingInstruction         on $projection.TrdgDocPurgShipgInstrn = _ShippingInstruction.ShippingInstruction
  association [0..1] to I_SupplierConfControlKey    as _SupplierConfControlKey      on $projection.SupplierConfirmationControlKey = _SupplierConfControlKey.SupplierConfirmationControlKey
  association [0..1] to I_PaymentGuaranteeProcedure as _PaymentGuaranteeProcedure   on $projection.PaymentGuaranteeProcedure = _PaymentGuaranteeProcedure.PaymentGuaranteeProcedure
  association [0..1] to I_ShippingType              as _ShippingType                on $projection.ShippingType = _ShippingType.ShippingType
  association [0..1] to I_Plant                     as _SupplyingPlant              on $projection.SupplyingPlant = _SupplyingPlant.Plant
  association [0..1] to I_PaymentTerms              as _TrdgDocPurgPaymentTerms     on $projection.TrdgDocPurgPaymentTerms = _TrdgDocPurgPaymentTerms.PaymentTerms
  association [0..1] to I_PaymentTerms              as _TrdgDocSalesPaymentTerms    on $projection.TrdgDocSalesPaymentTerms = _TrdgDocSalesPaymentTerms.PaymentTerms
  association [0..1] to I_IncotermsVersion          as _TrdgDocPurgIncotermsVersion on $projection.TrdgDocPurgIncotermsVersion = _TrdgDocPurgIncotermsVersion.IncotermsVersion
  association [0..1] to I_IncotermsVersion          as _TrdgDocSlsIncotermsVersion  on $projection.TrdgDocSalesIncotermsVersion = _TrdgDocSlsIncotermsVersion.IncotermsVersion

{
  key tkonn                                                            as TradingDocument,
  key tposn                                                            as TradingDocumentItem,
      @ObjectModel.foreignKey.association: '_PaymentGuaranteeProcedure'
      abssc                                                            as PaymentGuaranteeProcedure,
      akprz                                                            as DepreciationPercentage,
      cast( angnr_mm as wb2_suplr_qtan preserving type )               as SupplierQuotationExternalID,
      bsart                                                            as PurchasingDocumentType,
      @ObjectModel.foreignKey.association: '_SupplierConfControlKey'
      cast( bstae_mm as wb2_suplr_conf_ctrl preserving type )          as SupplierConfirmationControlKey,
      cast( bstdk as wb2_cust_purch_order_date preserving type )       as CustomerPurchaseOrderDate,
      bstdk_e                                                          as CustPurOrdDateByShipToParty,
      cast( bstkd as wb2_po_by_cust_extd preserving type )             as PurchaseOrderByCustomer,
      cast( bstkd_e as wb2_po_by_ship_to_party preserving type )       as PurchaseOrderByShipToParty,
      @ObjectModel.foreignKey.association: '_TrdgDocPurgDocCat'
      bstyp                                                            as TrdgDocPurgDocCat,
      @Semantics.amount.currencyCode: 'TrdgDocPurgCurrency'
      dpamt                                                            as DownPaymentAmount,
      dpdat                                                            as DownPaymentDueDate,
      dppct                                                            as DownPaymentPercentageOfTotAmt,
      dptyp                                                            as DownPaymentType,
      @Semantics.businessDate.at: true
      cast( ebdat as wb2_purg_doc_dte preserving type )                as PurchasingDocumentOrderDate,
      edatu_vbak                                                       as TrdgDocSlsReqdDeliveryDate,
      eindt                                                            as TrdgDocPurgReqdDeliveryDate,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      ekgrp                                                            as PurchasingGroup,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      ekorg                                                            as PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_Supplier'
      elifn                                                            as Supplier,
      erdat                                                            as CreationDate,
      @Semantics.user.createdBy: true
      ernam                                                            as CreatedByUser,
      cast( erzet as wb2_created_at preserving type )                  as CreationTime,
      @ObjectModel.foreignKey.association: '_ShippingInstruction'
      cast( evers_mm as wb2_purg_shipg_instrn preserving type )        as TrdgDocPurgShipgInstrn,
      @ObjectModel.foreignKey.association: '_TrdgDocPurgDelivAddrCat'
      cast( hkla as wb2_purg_deliv_addr preserving type )              as TrdgDocPurgDelivAddrCat,
      ihran                                                            as QuotationSubmissionDate,
      cast( ihrez as wb2_purg_doc_ext_ref preserving type )            as TrdgDocPurgDocExtReference,
      @ObjectModel.foreignKey.association: '_PurgIncotermsClassification'
      inco1_mm                                                         as PurgIncotermsClassification,
      @ObjectModel.foreignKey.association: '_SlsIncotermsClassification'
      inco1_sd                                                         as SlsIncotermsClassification,
      cast( inco2_l_mm   as wb2_inco1_loc_mm preserving type )         as TrdgDocPurgIncotermsLoc1Text,
      cast( inco2_l_sd   as wb2_inco1_loc_sd preserving type )         as TrdgDocSlsIncotermsLoc1Text,
      cast( inco2_mm as wb2_purg_incoterms2 preserving type )          as PurgIncotermsTransferLocation,
      inco2_sd                                                         as SlsIncotermsTransferLocation,
      cast( inco3_l_mm   as wb2_inco2_loc_mm preserving type )         as TrdgDocPurgIncotermsLoc2Text,
      cast( inco3_l_sd   as wb2_inco2_loc_sd preserving type )         as TrdgDocSlsIncotermsLoc2Text,
      @ObjectModel.foreignKey.association: '_TrdgDocPurgIncotermsVersion'
      cast( incov_mm   as wb2_inco1_version_mm preserving type )       as TrdgDocPurgIncotermsVersion,
      @ObjectModel.foreignKey.association: '_TrdgDocSlsIncotermsVersion'
      cast( incov_sd   as wb2_inco1_version_sd preserving type )       as TrdgDocSalesIncotermsVersion,

      cast( kalsm_mm as wb2_purg_prcg_proced preserving type )         as TrdgDocPurgPricingProcedure,
      cast( kdatb_mm as wb2_purg_valdty_start_dte preserving type )    as TrdgDocPurgValidityStartDate,
      cast( kdate_mm as wb2_purg_valdty_end_dte preserving type )      as TrdgDocPurgValidityEndDate,
      kufix                                                            as FixedExchangeRateIsUsed,
      @ObjectModel.foreignKey.association: '_TrdgDocPurgExchangeRateType'
      cast( kurst_mm as wb2_purg_exch_rate_type preserving type )      as TrdgDocPurgExchangeRateType,
      kzabs_mm                                                         as IsOrderAcknRqd,
      kzazu                                                            as OrderCombinationIsAllowed,
      labnr                                                            as PurgDocOrderAcknNumber,
      lcnum                                                            as InternalFinancialDocument,
      cast( lpein_int as wb2_purg_deliv_date_type preserving type )    as TrdgDocPurgDeliveryDateType,
      mndid                                                            as SEPAMandate,
      posex_e                                                          as UnderlyingPurchaseOrderItem,
      posplit                                                          as TrdgDocMnlPOSplit,
      cast( prgrs_vbak as wb2_sls_deliv_dte_type preserving type )     as TrdgDocSlsDeliveryDateType,
      cast( prsdt_mm   as wb2_purch_pricing_date preserving type )     as TrdgDocPurgPricingDate,
      cast( prsdt_sd   as wb2_sales_pricing_date preserving type )     as TrdgDocSalesPricingDate,
      @ObjectModel.foreignKey.association: '_SupplyingPlant'
      reswk                                                            as SupplyingPlant,
      retpc                                                            as RetentionPercentage,
      cast( telf1_mm as wb2_suplr_tel preserving type )                as SupplierPhoneNumber,
      termdes_mm                                                       as PaymentTermsName,
      cast( tkrate_mm as wb2_purg_exch_rate_no_cnext preserving type ) as TrdgDocPurgExchangeRate,
      unsez_mm                                                         as CorrespncInternalReference,
      cast( valdt as wb2_purg_fixedval_date preserving type )          as TrdgDocPurgFixedValueDate,
      cast( valdtd as wb2_sls_fixedval_date preserving type )          as TrdgDocSalesFixedValueDate,
      cast( verkf_mm as wb2_suplr_resp_sls_person preserving type )    as SupplierRespSalesPersonName,
      @ObjectModel.foreignKey.association: '_ShippingType'
      vsart                                                            as ShippingType,
      @ObjectModel.foreignKey.association: '_Currency'
      cast( waers_purch as wb2_purg_currency preserving type )         as TrdgDocPurgCurrency,
      cast( werk_mm as wb2_issuing_plant preserving type )             as IssuingPlant,
      @Consumption: {
          valueHelpDefinition: [{entity: {name: 'I_PaytReceiptPaytMethVH', element:'PaymentMethod'  } } ]
      }
      cast( zlsch as wb2_sls_payt_method preserving type )             as TrdgDocSalesPaymentMethod,
      @ObjectModel.foreignKey.association: '_TrdgDocPurgPaymentTerms'
      zterm                                                            as TrdgDocPurgPaymentTerms,
      @ObjectModel.foreignKey.association: '_TrdgDocSalesPaymentTerms'
      zterm_sales                                                      as TrdgDocSalesPaymentTerms,
      knumv_mm                                                         as TrdgDocPurgDocCndn,
      cast ( kursk_sd as wb2_sls_exchrate_prcdetn preserving type )    as TrdgDocPrcDetnExchRate,
      cast( podkz as  wb2_rlvt_pod_procg preserving type )             as TrdgDocIsRlvtPoDProcg,

      /* Expose Associations */
      _TrdgDocPurgDelivAddrCat,
      _TrdgDocPurgDocCat,
      _CreatedByUser,
      _Supplier,
      _PurchasingOrganization,
      _PurchasingGroup,
      _Currency,
      _TrdgDocPurgExchangeRateType,
      _PurgIncotermsClassification,
      _SlsIncotermsClassification,
      _ShippingInstruction,
      _SupplierConfControlKey,
      _PaymentGuaranteeProcedure,
      _TrdgDocPurgPaymentTerms,
      _TrdgDocSalesPaymentTerms,
      _ShippingType,
      _TrdgDocPurgIncotermsVersion,
      _TrdgDocSlsIncotermsVersion,
      _SupplyingPlant
}
where
  tposn_sub = '000000';