R_ServiceQuotationItemTP

@EndUserText.label: 'Service Quotation Item - TP'
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata: {
  ignorePropagatedAnnotations: true
}

@ObjectModel: {
   representativeKey: 'ServiceQuotationItem',
   semanticKey: ['ServiceQuotationItem'],
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}

define view entity R_ServiceQuotationItemTP
  as select from I_ServiceDocumentItemEnhcd

  association        to parent R_ServiceQuotationTP  as _ServiceQuotationTP   on  $projection.ServiceQuotation = _ServiceQuotationTP.ServiceQuotation

  association [0..1] to I_RespyMgmtTeamHeaderDetail  as _ServiceTeamHeader    on  $projection.RespyMgmtServiceTeam = _ServiceTeamHeader.RespyMgmtTeamID

  association [0..1] to I_CustMgmtExtRefID           as _CustMgmtExtRef       on  $projection.ServiceQuotation         = _CustMgmtExtRef.CustMgmtDocument
                                                                              and $projection.ServiceObjectType        = _CustMgmtExtRef.CustMgmtObjectType
                                                                              and $projection.ServiceQuotationItem     = _CustMgmtExtRef.CustMgmtDocumentItem
                                                                              and _CustMgmtExtRef.CustMgmtExtRefIDType = '0010'

  association [0..1] to I_CustMgmtExtRefID           as _CustMgmtHeaderExtRef on  $projection.ServiceQuotation               = _CustMgmtHeaderExtRef.CustMgmtDocument
                                                                              and $projection.ServiceObjectType              = _CustMgmtHeaderExtRef.CustMgmtObjectType
  //and $projection.ServiceQuotationItem           = _CustMgmtHeaderExtRef.CustMgmtDocumentItem

                                                                              and _CustMgmtHeaderExtRef.CustMgmtExtRefIDType = '0009'
  association [0..1] to I_SrvcMgmtObjectStatus     as _SrvcQtanItmStatus    on  $projection.ServiceQuotationItemUUID = _SrvcQtanItmStatus.SrvcMgmtObjectUUID
                                                                              and (
                                                                                 _SrvcQtanItmStatus.SrvcMgmtObjectStatus         = 'I1002' //IsNew

                                                                                 or _SrvcQtanItmStatus.SrvcMgmtObjectStatus      = 'I1003' //InProcess

                                                                                 or _SrvcQtanItmStatus.SrvcMgmtObjectStatus      = 'I1005' //Completed

                                                                                 or _SrvcQtanItmStatus.SrvcMgmtObjectStatus      = 'I1004' //Released


                                                                               )
                                                                              and _SrvcQtanItmStatus.SrvcMgmtObjectStatusIsInactive = ' '

  association [0..1] to R_SrvcDocItemDocumentFlow    as _RefServiceContract   on  $projection.ServiceQuotation                    = _RefServiceContract.ServiceDocument
                                                                              and $projection.ServiceQuotationItem                = _RefServiceContract.ServiceDocumentItem
                                                                              and _RefServiceContract.PrdcssrSuccssrDocObjectType = 'BUS2000112'
                                                                              and _RefServiceContract.ServiceObjectType           = 'BUS2000116'

  association [0..1] to I_SrvcMgmtObjectStatus       as _SrvcMgmtSendToPlanningStatus on $projection.ServiceQuotationItemUUID=_SrvcMgmtSendToPlanningStatus.SrvcMgmtObjectUUID
                                                                                      and(
                                                                                         _SrvcMgmtSendToPlanningStatus.SrvcMgmtObjectStatus = 'I1927' // Send to Planning

                                                                                      )
                                                                                      and _SrvcMgmtSendToPlanningStatus.SrvcMgmtObjectStatusIsInactive = ' '


  //  Extensibility

  association [0..1] to E_ServiceDocumentItem        as _Extension            on  _Extension.ServiceCategory       = 'BUS2000116'
                                                                              and $projection.ServiceQuotation     = _Extension.ServiceOrderItem
                                                                              and $projection.ServiceQuotationItem = _Extension.ServiceLineExternalID


  association [0..1] to I_CustMgmtPartner            as _ServicePerformer     on  _ServicePerformer.CustMgmtPartnerFunction      = '00000028'
                                                                              and _ServicePerformer.CustMgmtPartFunctionCategory = '0091'
                                                                              and $projection.ServiceQuotation                   = _ServicePerformer.CustMgmtDocument
                                                                              and $projection.ServiceQuotationItem               = _ServicePerformer.CustMgmtDocumentItem


  composition [0..*] of R_SrvcQtanItemRefObjectTP    as _SrvcQtanItemRefObjectTP
  composition [0..*] of R_SrvcQtanItemPriceElementTP as _SrvcQtanItemPriceElementTP
  composition [0..*] of R_SrvcQtanItmFUPSrvcOrdTP    as _SrvcQtanItmFUPSrvcOrdTP
  composition [0..*] of R_SrvcQtanItemPartnerTP      as _SrvcQtanItemPartnerTP
  composition [0..*] of R_SrvcQtanItemDurationTP     as _SrvcQtanItemDurationTP
  composition [0..*] of R_SrvcQtanItemAppointmentTP  as _SrvcQtanItemAppointmentTP
  composition [0..*] of R_SrvcQtanItemUserStatusTP   as _SrvcQtanItemUserStatusTP
  composition [0..*] of R_SrvcQtanItemLongTextTP     as _SrvcQtanItemLongTextTP


{
      //Administrative fields

      @ObjectModel.foreignKey.association: '_ServiceDocument'
  key ServiceDocument                                                                as ServiceQuotation,
  key ServiceDocumentItem                                                            as ServiceQuotationItem,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      ServiceDocumentItemObjectType,
      ServiceDocItemCategory                                                         as ServiceQtanItemCategory,
      ServiceDocumentItemUUID                                                        as ServiceQuotationItemUUID,
      _ParentServiceDocItem.ServiceDocumentItem                                      as ParentServiceQuotationItem,
      ServiceDocumentItemDescription                                                 as ServiceQtanItemDescription,
      Language,

      ServiceDocItemCreationDateTime,
      ServiceDocItemChangedDateTime,
      ServiceDocItemCreatedByUser,
      ServiceDocItemChangedByUser,


      //Item fields

      @ObjectModel.foreignKey.association: '_Product'
      Product,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      ServiceDocumentItemQuantity                                                    as Quantity,
      ServiceDocItemQuantityUnit                                                     as QuantityUnit,
      _WorkCenter.Plant                                                              as MaintenanceWorkCenterPlant,
      _WorkCenter.WorkCenter                                                         as MaintenanceWorkCenter,
      MaintenancePlanningPlant,
      SrvcDocItmBillingRelevance,
      DynItemProcessorPrfl,
      SrvcDocItemCategoryUsage,


      //Partners

      SoldToParty,
      ShipToParty,
      // BillToParty,

      // PayerParty,

      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson                                                                  as ContactPersonBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee                                                            as RespEmployeeBusinessPartnerId,
      _ServicePerformer.CustMgmtBusinessPartner                                      as ServicePerformer,


      //Organizational data

      RespyMgmtServiceTeam,
      // _ServiceTeamHeader.TeamName                                                     as RespyMgmtServiceTeamName,

      _ServiceTeamHeader.RespyMgmtGlobalTeamID                                       as RespyMgmtGlobalTeamID,


      //Status

      cast( case _SrvcQtanItmStatus.SrvcMgmtObjectStatus
      when 'I1002' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceQuotationItemIsNew,
      cast( case _SrvcQtanItmStatus.SrvcMgmtObjectStatus
      when 'I1003' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as SrvcQtanItemIsInProcess,
      cast( case _SrvcQtanItmStatus.SrvcMgmtObjectStatus
      when 'I1004' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceQuotationItemIsReleased,
      cast( case _SrvcQtanItmStatus.SrvcMgmtObjectStatus
      when 'I1005' then 'X'
      else ' '
      end                  as   xfeld preserving type     )                          as ServiceQtanItemIsCompleted,
      ServiceDocumentItemStatus                                                      as SrvcQtanItemStatus,
      @Semantics.booleanIndicator
      ServiceDocumentItemIsRejected                                                  as ServiceQuotationItemIsRejected,

      @Semantics.booleanIndicator
      case QuotationIsAccepted
      when 'Y' then 'X'
      else ''
      end                                                                            as ServiceQuotationItemIsAccepted,
      @Semantics.booleanIndicator
      ServiceDocumentItemHasError                                                    as ServiceQuotationItemHasError,
      @Semantics.booleanIndicator
      case _SrvcMgmtSendToPlanningStatus.SrvcMgmtObjectStatus
        when'I1927'then'X'
        else''
      end                                                                            as SrvcQtanItmIsToBeSentToPlng,
      // Dates and Durations

      //      @Semantics.dateTime:true

      //      RequestedServiceStartDateTime               as  SrvcQtanItmValdtyStartDateTime,

      //      @Semantics.dateTime:true

      //      RequestedServiceEndDateTime                 as    SrvcQtanItmValdtyEndDateTime,


      //Pricing fields

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocItemGrossAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocumentItemTaxAmount,


      //Reference documents

      _CustMgmtExtRef.CustMgmtExtRefID                                               as ServiceQtanItemExtReference,
      _CustMgmtHeaderExtRef.CustMgmtExtRefID                                         as ServiceQtanExtReference,
      cast( _RefServiceContract.CustMgmtPrdcssrTransactionKey as crmt_object_id_db ) as ReferenceServiceContract,
      cast( _RefServiceContract.BusinessTransactionDocItem as crms4_number_int )     as ReferenceServiceContractItem,




      //Associations

      _ServiceDocument,
      _ServicePerformer,
      _Product,
      _ContactPerson,
      _RespEmployee,
      _ServiceObjType,
      _SrvcQtanItmStatus,
      _TransactionCurrency,
      //_ServiceDocOvertimeCat,

      _ServiceQuotationTP,
      _SrvcQtanItemRefObjectTP,
      _SrvcQtanItemPriceElementTP,
      _SrvcQtanItmFUPSrvcOrdTP,
      _SrvcQtanItemPartnerTP,
      _SrvcQtanItemDurationTP,
      _SrvcQtanItemAppointmentTP,
      _SrvcQtanItemUserStatusTP,
      _SrvcQtanItemLongTextTP

}
where
      ServiceObjectType              = 'BUS2000116' //  Service Quotation

  and ServiceDocumentItemIsQuotation is not initial