R_ServiceOrderTP

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}

@EndUserText.label: 'Service Order - TP'
@ObjectModel: {
  sapObjectNodeType.name: 'ServiceOrder',
  semanticKey: ['ServiceOrder'],
  representativeKey: 'ServiceOrder',
   usageType: {dataClass:      #TRANSACTIONAL,
                serviceQuality: #C,
                sizeCategory:   #L}
}

define root view entity R_ServiceOrderTP
  as select from I_ServiceDocumentEnhcd
  composition [0..*] of R_ServiceOrderItemTP        as _ServiceOrderItemTP
  composition [0..*] of R_SrvcOrdPartnerTP          as _SrvcOrdPartnerTP
  composition [0..*] of R_SrvcOrdReferenceObjectTP  as _SrvcOrdReferenceObjectTP
  composition [0..*] of R_SrvcOrdPriceElementTP     as _SrvcOrdPriceElementTP
  composition [0..*] of R_SrvcOrdUserStatusTP       as _SrvcOrdUserStatusTP
  composition [0..*] of R_SrvcOrdFUPSrvcConfTP      as _SrvcOrdFUPSrvcConfTP
  composition [0..*] of R_SrvcOrdFUPBillgDocTP      as _SrvcOrdFUPBillgDocTP
  composition [0..*] of R_SrvcOrdFUPPurchaseOrderTP as _SrvcOrdFUPPurchaseOrderTP
  composition [0..*] of R_SrvcOrdFUPPurReqnTP       as _SrvcOrdFUPPurReqnTP
  composition [0..*] of R_SrvcOrdFUPSrvcEntrSheetTP as _SrvcOrdFUPSrvcEntrSheetTP
  composition [0..*] of R_SrvcOrdFUPSuplrInvcTP     as _SrvcOrdFUPSuplrInvcTP
  composition [0..*] of R_SrvcOrdAppointmentTP      as _SrvcOrdAppointmentTP
  composition [0..*] of R_SrvcOrdDurationTP         as _SrvcOrdDurationTP
  composition [0..*] of R_SrvcOrdFUPMaintOrdTP      as _SrvcOrdFUPMaintOrdTP
  composition [0..*] of R_SrvcOrdLongTextTP         as _SrvcOrdLongTextTP

  association [0..1] to I_CustMgmtExtRefID          as _CustMgmtExtRef           on  $projection.ServiceOrder             = _CustMgmtExtRef.CustMgmtDocument
                                                                                 and $projection.ServiceObjectType        = _CustMgmtExtRef.CustMgmtObjectType
                                                                                 and _CustMgmtExtRef.CustMgmtExtRefIDType = '0001'

  association [0..*] to I_ServiceDocumentSuccessor  as _Confirmation             on  $projection.ServiceOrderUUID                = _Confirmation.ServiceDocumentUUID
                                                                                 and _Confirmation.ServiceDocSuccessorBusObjType = 'BUS2000117'

  association [0..1] to P_SrvcPrdcssrSrvcContr      as _RefServiceContract       on  $projection.ServiceOrderUUID            = _RefServiceContract.ServiceDocumentUUID
                                                                                 and _RefServiceContract.NumberOfOccurrences = 1
  // on  $projection.ServiceOrderUUID                    = _RefServiceContract.ServiceDocumentUUID

  // and _RefServiceContract.PrdcssrSuccssrDocObjectType = 'BUS2000112'

  // and _RefServiceContract.ServiceObjectType           = 'BUS2000116'

  // and _RefServiceContract.ServiceDocumentTemplateType is initial


  association [0..1] to R_SrvcDocDocumentFlow       as _RefServiceTemplate       on  $projection.ServiceOrderUUID                    = _RefServiceTemplate.ServiceDocumentUUID
                                                                                 and _RefServiceTemplate.PrdcssrSuccssrDocObjectType = 'BUS2000116'
                                                                                 and _RefServiceTemplate.ServiceObjectType           = 'BUS2000116'
                                                                                 and _RefServiceTemplate.ServiceDocumentTemplateType is not initial

  association [0..1] to I_RespyMgmtTeamHeaderDetail as _ServiceTeamHeader        on  $projection.RespyMgmtServiceTeam = _ServiceTeamHeader.RespyMgmtTeamID

  association [0..1] to I_StatusObjectUUIDStatus    as _SrvcOrdStatus            on  $projection.ServiceOrderUUID  = _SrvcOrdStatus.StatusObjectUUID
                                                                                 and (
                                                                                    _SrvcOrdStatus.StatusCode      = 'I1002'
                                                                                    or _SrvcOrdStatus.StatusCode   = 'I1003'
                                                                                    or _SrvcOrdStatus.StatusCode   = 'I1004'
                                                                                    or _SrvcOrdStatus.StatusCode   = 'I1005'
                                                                                  )
                                                                                 and _SrvcOrdStatus.StatusIsActive = 'X'

  //FSM Field

  association [0..1] to I_SrvcOrdRefFSMServiceCall  as _SrvcOrdRefFSMServiceCall on  $projection.ServiceOrderUUID                          = _SrvcOrdRefFSMServiceCall.ServiceDocumentUUID
                                                                                 and _SrvcOrdRefFSMServiceCall.PrdcssrSuccssrDocObjectType = 'FSMCALL'


  //! Extensibility support

  association [0..1] to E_ServiceDocument           as _Extension                on  $projection.ServiceObjectType = _Extension.ServiceCategory
                                                                                 and $projection.ServiceOrder      = _Extension.ServiceOrder
  association [0..1] to I_WBSElementBasicData       as _WBSElement               on  _WBSElement.WBSElementInternalID = I_ServiceDocumentEnhcd.WBSElementInternalID

  association [0..1] to P_SrvcDocWithSglPrdcssrQtan as _SinglePredecessorQtan    on  $projection.ServiceOrderUUID = _SinglePredecessorQtan.ServiceDocumentUUID
                                                                                 and $projection.ServiceOrder     = _SinglePredecessorQtan.ServiceDocument
{

      // Administrative fields

  key ServiceDocument                                                                       as ServiceOrder,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,

      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentType                                                                   as ServiceOrderType,
      ServiceDocumentUUID                                                                   as ServiceOrderUUID,
      ServiceDocumentDescription                                                            as ServiceOrderDescription,
      Language,
      PostingDate,
      ServiceDocCreationDateTime,
      ServiceDocChangedDateTime,
      ServiceDocumentCreatedByUser,
      ServiceDocumentChangedByUser,

      // Partners

      @ObjectModel.foreignKey.association: '_SoldToParty'
      SoldToParty,
      @ObjectModel.foreignKey.association: '_ShipToParty'
      ShipToParty,
      @ObjectModel.foreignKey.association: '_BillToParty'
      BillToParty,
      @ObjectModel.foreignKey.association: '_PayerParty'
      PayerParty,

      @ObjectModel.foreignKey.association: '_PaymentTerms'
      PaymentTerms,

      @ObjectModel.foreignKey.association: '_PaymentMethod'
      PaymentMethod,

      SEPAMandate,

      @ObjectModel.foreignKey.association: '_SrvcSEPAMandateRelevance'
      SrvcSEPAMandateRelevance,

      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson                                                                         as ContactPersonBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee                                                                   as RespEmployeeBusinessPartnerId,

      // Organizational Data

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,

      //CRM Org units

      //these feilds are only ON PREMISE

      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SalesOrganizationOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SalesOfficeOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SalesGroupOrgUnitID,
      @Feature: 'BF:API_FULLSCOPE'
      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit_2'
      ServiceOrganization,

      //Service team fields

      RespyMgmtServiceTeam,
      // _ServiceTeamHeader.TeamName                                                                  as RespyMgmtServiceTeamName,

      _ServiceTeamHeader.RespyMgmtGlobalTeamID                                              as RespyMgmtGlobalTeamID,

      // Status

      cast( case _SrvcOrdStatus.StatusCode
      when 'I1002' then 'X'
      else ' '
      end       as   xfeld preserving type     )                                            as ServiceOrderIsNew,
      cast( case _SrvcOrdStatus.StatusCode
      when 'I1003' then 'X'
      else ' '
      end      as   xfeld preserving type     )                                             as ServiceOrderIsInProcess,
      cast( case _SrvcOrdStatus.StatusCode
      when 'I1004' then 'X'
      else ' '
      end      as   xfeld preserving type     )                                             as ServiceOrderIsReleased,
      cast( case _SrvcOrdStatus.StatusCode
      when 'I1005' then 'X'
      else ' '
      end     as   xfeld preserving type     )                                              as ServiceOrderIsCompleted,

      @Semantics.booleanIndicator
      ServiceDocumentIsRejected                                                             as ServiceOrderIsRejected,

      ServiceDocumentStatus                                                                 as ServiceOrderStatus,
      ServiceDocIsReleasedForBilling                                                        as SrvcOrdReldForBillingStatus,
      ServiceDocBillingStatus                                                               as SrvcOrdBillingStatus,
      @Semantics.booleanIndicator
      ServiceDocumentHasError                                                               as ServiceOrderHasError,
      SrvcDocTransferStatus,
      SrvcDocExecutionStatus                                                                as SrvcOrdExecutionStatus,
      SrvcDocRejectionStatus,
      SrvcDocCreditStatus                                                                   as SrvcOrdCreditStatus,

      // Dates and Durations

      RequestedServiceStartDateTime,
      RequestedServiceEndDateTime,
      ErlstRequestedDeliveryDateTime,

      // Service Specific Fields

      @ObjectModel.foreignKey.association: '_ServiceDocumentPriority'
      ServiceDocumentPriority,

      // Pricing Fields

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocGrossAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocTaxAmount,
      PricingDocument,

      // Sales Fields

      PurchaseOrderByCustomer,
      CustomerPurchaseOrderDate,
      @ObjectModel.foreignKey.association: '_SrvcDocumentRejectionReason'
      ServiceDocumentRejectionReason                                                        as ServiceOrderRejectionReason,

      // Reference Documents

      _CustMgmtExtRef.CustMgmtExtRefID                                                      as SrvcOrdExtReference,
      //cast( _RefServiceContract.CustMgmtPrdcssrTransactionKey as crmt_object_id_db )        as ReferenceServiceContract,

      _RefServiceContract.ServiceContract                                                   as ReferenceServiceContract,
      cast( _RefServiceTemplate.CustMgmtPrdcssrTransactionKey as crmt_object_id_db )        as RefServiceOrderTemplate,
      cast( _SinglePredecessorQtan.ReferenceServiceQtan as crms4_reference_document_id_co ) as ReferenceServiceQtan,
      //      ReferenceInHouseRepair,

      //      ReferenceInHouseRepairItem,


      //Shipping

      ShippingCondition,

      _WBSElement.WBSElementExternalID,

      _SrvcOrdRefFSMServiceCall.FSMServiceCall,

      // Associations

      _ServiceObjType,
      _ServiceDocumentType,

      _SoldToParty,
      _ShipToParty,
      _BillToParty,
      _PayerParty,
      _ContactPerson,
      _PaymentTerms,
      _PaymentMethod,
      _SrvcSEPAMandateRelevance,
      _RespEmployee,

      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _SalesOffice,
      _SalesGroup,


      _SalesOrganizationOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _SalesGroupOrgUnit_2,
      _ServiceOrganizationOrgUnit_2,
      _ServiceTeamHeader,

      _ServiceDocumentPriority,

      _TransactionCurrency,

      _SrvcDocumentRejectionReason,

      _Confirmation,

      _ServiceOrderItemTP,
      _SrvcOrdPartnerTP,
      _SrvcOrdReferenceObjectTP,
      _SrvcOrdPriceElementTP,
      _SrvcOrdUserStatusTP,

      _SrvcOrdStatus,

      _SrvcOrdFUPSrvcConfTP,
      _SrvcOrdFUPBillgDocTP,
      _SrvcOrdFUPPurchaseOrderTP,
      _SrvcOrdFUPPurReqnTP,
      _SrvcOrdFUPSrvcEntrSheetTP,
      _SrvcOrdFUPSuplrInvcTP,
      _SrvcOrdFUPMaintOrdTP,

      _SrvcOrdAppointmentTP,
      _SrvcOrdDurationTP,
      _SrvcOrdLongTextTP

}
where
      ServiceObjectType           = 'BUS2000116' // Service Process

  and ServiceDocumentIsQuotation  is initial
  and ServiceDocumentTemplateType is initial