R_ServiceEntrySheetItemTP

DDL: R_SERVICEENTRYSHEETITEMTP Type: view_entity TRANSACTIONAL

Service Entry Sheet Item

R_ServiceEntrySheetItemTP is a Transactional CDS View that provides data about "Service Entry Sheet Item" in SAP S/4HANA. It reads from 1 data source (I_ServiceEntrySheetItem) and exposes 73 fields with key fields ServiceEntrySheet, ServiceEntrySheetItem. It has 3 associations to related views.

1 data source(s) 73 fields

Data Sources (1)

SourceAliasJoin Type
I_ServiceEntrySheetItem I_ServiceEntrySheetItem from

Associations (3)

CardinalityTargetAliasCondition
[1..1] E_ServiceEntrySheetItem _ServiceEntrySheetItmExtension $projection.ServiceEntrySheet = _ServiceEntrySheetItmExtension.ServiceEntrySheet and $projection.ServiceEntrySheetItem = _ServiceEntrySheetItmExtension.ServiceEntrySheetItem
[1..*] R_SESAccountAssignmentTP _AccountAssignment
[1..*] R_SESPricingElementTP _SESPricingElement

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Service Entry Sheet Item view
AccessControl.personalData.blocking #REQUIRED view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view
ObjectModel.representativeKey ServiceEntrySheetItem view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MIXED view
Metadata.ignorePropagatedAnnotations true view

Fields (73)

KeyFieldSource TableSource FieldDescription
KEY ServiceEntrySheet ServiceEntrySheet
KEY ServiceEntrySheetItem ServiceEntrySheetItem
PurchaseOrder PurchaseOrder
PurchaseOrderItem PurchaseOrderItem
PurgDocumentItemDeletionCode IsDeleted
Service Service
ServiceEntrySheetItemDesc ServiceEntrySheetItemDesc
ServicePerformer ServicePerformer
AccountAssignmentCategory AccountAssignmentCategory
MultipleAcctAssgmtDistribution MultipleAcctAssgmtDistribution
WorkItem WorkItem
ConfirmedQuantity ConfirmedQuantity
QuantityUnit QuantityUnit
OrderPriceUnit OrderPriceUnit
OrderPriceUnitToOrderUnitNmrtr OrderPriceUnitToOrderUnitNmrtr
OrdPriceUnitToOrderUnitDnmntr OrdPriceUnitToOrderUnitDnmntr
QtyInPurchaseOrderPriceUnit QtyInPurchaseOrderPriceUnit
NetPriceQuantity NetPriceQuantity
ServicePerformanceDate ServicePerformanceDate
ServicePerformanceEndDate ServicePerformanceEndDate
PerformancePeriodStartDate PerformancePeriodStartDate
PerformancePeriodEndDate PerformancePeriodEndDate
OriginObject OriginObject
Currency Currency
NetPriceAmount NetPriceAmount
MaterialGroup MaterialGroup
IsEndOfPurposeBlocked IsEndOfPurposeBlocked
CreationDateTime CreationDateTime
CreatedByUser CreatedByUser
LastChangeDateTime LastChangeDateTime
LastChangedByUser LastChangeUser
Plant Plant
PurgDocItemExternalReference PurgDocItemExternalReference
PurchaseContract PurchaseContract
PurchaseContractItem PurchaseContractItem
PurchasingOrganization PurchasingOrganization
PurchasingGroup PurchasingGroup
ParentObjectIsDeleted
PurOrderItemPlant PurOrderItemPlant
PurchaseOrderType PurchaseOrderType
Supplier Supplier
PurchaseOrderItemMaterialGroup PurchaseOrderItemMaterialGroup
PurchaseOrderItemQuantity PurchaseOrderItemQuantity
PurchaseOrderItemQuantityUnit PurchaseOrderItemQuantityUnit
PurchaseOrderItemNetAmount PurchaseOrderItemNetAmount
PurchaseOrderCurrency PurchaseOrderCurrency
PurchaseOrderItemCompanyCode PurchaseOrderItemCompanyCode
OverdelivTolrtdLmtRatioInPct OverdelivTolrtdLmtRatioInPct
PurchaseOrderItemCategory PurchaseOrderItemCategory
ExpectedOverallLimitAmount ExpectedOverallLimitAmount
OverallLimitAmount OverallLimitAmount
TotalConfirmedQuantity TotalConfirmedQuantity
OpenQuantity OpenQuantity
OpenAmountInPurchaseOrderCrcy OpenAmountInPurchaseOrderCrcy
NetAmount NetAmount
NetAmountInPurchaseOrderCrcy NetAmountInPurchaseOrderCrcy
NonDeductibleInputTaxAmount NonDeductibleInputTaxAmount
SESNetAmountInclSalesTax SESNetAmountInclSalesTax
TaxCode TaxCode
TaxCountry TaxCountry
TaxDeterminationDate TaxDeterminationDate
TaxJurisdiction TaxJurisdiction
TaxCalculationProcedure TaxCalculationProcedure
MaterialType MaterialType
ConsumptionPosting ConsumptionPosting
InventorySpecialStockType InventorySpecialStockType
PurgDocProductType ProductType
SESItemIsFinalEntry SESItemIsFinalEntry
_AccountAssignment _AccountAssignment
_ServiceEntrySheet _ServiceEntrySheet
_SESPricingElement _SESPricingElement
_AccountAssignmentCategory _AccountAssignmentCategory
_PurOrdUnitOfMsrValHelp _PurOrdUnitOfMsrValHelp 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Service Entry Sheet Item'

@AccessControl.personalData.blocking: #REQUIRED

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.semanticKey:  [ 'ServiceEntrySheet', 'ServiceEntrySheetItem' ]
@ObjectModel.representativeKey: 'ServiceEntrySheetItem'

@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}

@Metadata.ignorePropagatedAnnotations: true

define view entity R_ServiceEntrySheetItemTP
  as select from I_ServiceEntrySheetItem

  composition [1..*] of R_SESAccountAssignmentTP as _AccountAssignment
  composition [1..*] of R_SESPricingElementTP    as _SESPricingElement

  association to parent R_ServiceEntrySheetTP    as _ServiceEntrySheet on $projection.ServiceEntrySheet = _ServiceEntrySheet.ServiceEntrySheet

  ----Extension Association
  association [1..1] to E_ServiceEntrySheetItem       as _ServiceEntrySheetItmExtension on  $projection.ServiceEntrySheet     = _ServiceEntrySheetItmExtension.ServiceEntrySheet
                                                                                        and $projection.ServiceEntrySheetItem = _ServiceEntrySheetItmExtension.ServiceEntrySheetItem

{
      @ObjectModel.foreignKey.association: '_ServiceEntrySheet'
  key ServiceEntrySheet,
  key ServiceEntrySheetItem,
      PurchaseOrder,
      PurchaseOrderItem,
      IsDeleted as PurgDocumentItemDeletionCode,
      Service,
      ServiceEntrySheetItemDesc,
      ServicePerformer,
      @ObjectModel.foreignKey.association: '_AccountAssignmentCategory'
      AccountAssignmentCategory,
      MultipleAcctAssgmtDistribution,
      WorkItem,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
      ConfirmedQuantity,
      QuantityUnit,
      OrderPriceUnit,
      OrderPriceUnitToOrderUnitNmrtr,
      OrdPriceUnitToOrderUnitDnmntr,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
      QtyInPurchaseOrderPriceUnit,
      @Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
      NetPriceQuantity,
      ServicePerformanceDate,
      ServicePerformanceEndDate,
      PerformancePeriodStartDate,
      PerformancePeriodEndDate,
      OriginObject,
//      cast ( OriginObject as objnr_hk preserving type ) as OriginObject,

      Currency,
      @Semantics.amount.currencyCode: 'Currency'
      NetPriceAmount,
      MaterialGroup,
      @Semantics.booleanIndicator:true
      IsEndOfPurposeBlocked,
      CreationDateTime,
      CreatedByUser,
      LastChangeDateTime,
      LastChangeUser                                    as LastChangedByUser,
      Plant,
      PurgDocItemExternalReference,
      PurchaseContract,
      PurchaseContractItem,
      PurchasingOrganization,
      PurchasingGroup,
      @Semantics.booleanIndicator:true
      cast ( ParentObjectIsDeleted as xfeld ) as ParentObjectIsDeleted,
      PurOrderItemPlant,
      PurchaseOrderType,
      Supplier,
      PurchaseOrderItemMaterialGroup,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
      PurchaseOrderItemQuantity,
      @ObjectModel.foreignKey.association: '_PurOrdUnitOfMsrValHelp'
      PurchaseOrderItemQuantityUnit,
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      PurchaseOrderItemNetAmount,
      PurchaseOrderCurrency,
      PurchaseOrderItemCompanyCode,
      OverdelivTolrtdLmtRatioInPct,
      PurchaseOrderItemCategory,
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      ExpectedOverallLimitAmount,
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      OverallLimitAmount,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
      TotalConfirmedQuantity,
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderItemQuantityUnit'
      OpenQuantity,
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      OpenAmountInPurchaseOrderCrcy,
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      NetAmount,
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      NetAmountInPurchaseOrderCrcy,
      @Semantics.amount.currencyCode: 'Currency'
      NonDeductibleInputTaxAmount,
      @Semantics.amount.currencyCode: 'PurchaseOrderCurrency'
      SESNetAmountInclSalesTax,
      TaxCode,
      TaxCountry,
      TaxDeterminationDate,
      TaxJurisdiction,
      TaxCalculationProcedure,
      MaterialType,
      ConsumptionPosting,
      InventorySpecialStockType,
      ProductType as PurgDocProductType,
      SESItemIsFinalEntry,

      /* Associations */
      _AccountAssignment,
      _ServiceEntrySheet,
      _SESPricingElement,
      _AccountAssignmentCategory,
      _PurOrdUnitOfMsrValHelp

}
where
  _ServiceEntrySheet.ServiceEntrySheet is not null

Learn More