R_ServiceContractTP

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata:
{
  ignorePropagatedAnnotations: true
}

@EndUserText.label: 'Service Contract - TP'
@ObjectModel.sapObjectNodeType.name: 'ServiceContract'
@ObjectModel: {
  semanticKey: ['ServiceContract'],
  representativeKey: 'ServiceContract',
  usageType: {dataClass:      #TRANSACTIONAL,
              serviceQuality: #C,
              sizeCategory:   #L}
}
define root view entity R_ServiceContractTP
  as select from I_ServiceDocumentEnhcd

  association [0..1] to I_StatusObjectUUIDStatus  as _SrvcContrStatus       on  $projection.ServiceContractUUID = _SrvcContrStatus.StatusObjectUUID
                                                                            and (
                                                                               _SrvcContrStatus.StatusCode      = 'I1002'
                                                                               or _SrvcContrStatus.StatusCode   = 'I1003'
                                                                               or _SrvcContrStatus.StatusCode   = 'I1004'
                                                                               or _SrvcContrStatus.StatusCode   = 'I1005'
                                                                             )
                                                                            and _SrvcContrStatus.StatusIsActive = 'X'

  association [0..1] to I_CustMgmtExtRefID        as _ExtRefServiceContract on  _ExtRefServiceContract.CustMgmtObjectType   = 'BUS2000112'
                                                                            and $projection.ServiceContract                 = _ExtRefServiceContract.CustMgmtDocument
                                                                            and _ExtRefServiceContract.CustMgmtExtRefIDType = '0003'

  association [0..1] to I_CustMgmtExtRefID        as _ExtRefServiceQtan     on  _ExtRefServiceQtan.CustMgmtObjectType   = 'BUS2000112'
                                                                            and $projection.ServiceContract             = _ExtRefServiceQtan.CustMgmtDocument
                                                                            and _ExtRefServiceQtan.CustMgmtExtRefIDType = '0009'

  association [0..1] to I_CustMgmtExtRefID        as _ExtRefLegalContract   on  _ExtRefLegalContract.CustMgmtObjectType   = 'BUS2000112'
                                                                            and $projection.ServiceContract               = _ExtRefLegalContract.CustMgmtDocument
                                                                            and _ExtRefLegalContract.CustMgmtExtRefIDType = '0021'

  association [0..1] to I_WBSElementBasicData     as _WBSElement            on  _WBSElement.WBSElementInternalID = I_ServiceDocumentEnhcd.WBSElementInternalID

  association [0..1] to R_SrvcDocDocumentFlow     as _RefServiceTemplate    on  $projection.ServiceContractUUID                 = _RefServiceTemplate.ServiceDocumentUUID
                                                                            and _RefServiceTemplate.PrdcssrSuccssrDocObjectType = 'BUS2000112'
                                                                            and _RefServiceTemplate.ServiceObjectType           = 'BUS2000112'
                                                                            and _RefServiceTemplate.ServiceDocumentTemplateType is not initial
  //! Extensibility support

  association [0..1] to E_ServiceDocument         as _Extension             on  $projection.ServiceObjectType = _Extension.ServiceCategory
                                                                            and $projection.ServiceContract   = _Extension.ServiceOrder

  composition [0..*] of R_ServiceContractItemTP   as _ServiceContractItemTP
  composition [0..*] of R_SrvcContrPartnerTP      as _SrvcContrPartnerTP
  //composition [0..*] of R_SrvcContrRefObjectTP       as _SrvcContrReferenceObjectTP

  composition [0..*] of R_SrvcContrPriceElementTP as _SrvcContrPriceElementTP
  composition [0..*] of R_SrvcContrUserStatusTP   as _SrvcContrUserStatusTP
  composition [0..*] of R_SrvcContrAppointmentTP  as _SrvcContrAppointmentTP
  composition [0..*] of R_SrvcContrDurationTP     as _SrvcContrDurationTP
  composition [0..*] of R_SrvcContrFUPBillgDocTP  as _SrvcContrFUPBillgDocTP
  composition [0..*] of R_SrvcContrFUPSrvcOrdTP   as _SrvcContrFUPSrvcOrdTP
  composition [0..*] of R_SrvcContrLongTextTP     as _SrvcContrLongTextTP
  //composition [0..*] of R_SrvcContrFUPBusSolnOrdTP  as _SrvcContrFUPBusSolnOrdTP





{

      // Administrative fields

  key ServiceDocument                                                                as ServiceContract,
      @ObjectModel.foreignKey.association: '_ServiceObjType'
      ServiceObjectType,
      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentType                                                            as ServiceContractType,
      ServiceDocumentUUID                                                            as ServiceContractUUID,
      ServiceDocumentDescription                                                     as ServiceContractDescription,
      Language,
      PostingDate,
      ServiceDocCreationDateTime,
      ServiceDocChangedDateTime,
      ServiceDocumentCreatedByUser,
      ServiceDocumentChangedByUser,

      // Partners

      @ObjectModel.foreignKey.association: '_SoldToParty'
      SoldToParty,
      @ObjectModel.foreignKey.association: '_ShipToParty'
      ShipToParty,
      @ObjectModel.foreignKey.association: '_BillToParty'
      BillToParty,
      @ObjectModel.foreignKey.association: '_PayerParty'
      PayerParty,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPerson                                                                  as ContactPersonBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      ResponsibleEmployee                                                            as RespEmployeeBusinessPartnerId,

      // Billing Relevant Fields

      @ObjectModel.foreignKey.association: '_PaymentTerms'
      PaymentTerms,
      @ObjectModel.foreignKey.association: '_PaymentMethod'
      PaymentMethod,
      SEPAMandate,
      @ObjectModel.foreignKey.association: '_SrvcSEPAMandateRelevance'
      SrvcSEPAMandateRelevance,

      // Organizational Data

      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,
      @ObjectModel.foreignKey.association: '_EnterpriseServiceOrg'
      EnterpriseServiceOrganization,
      //CRM Org units

      //these feilds are only ON PREMISE

      @ObjectModel.foreignKey.association: '_SalesOrganizationOrgUnit_2'
      SalesOrganizationOrgUnitID,

      @ObjectModel.foreignKey.association: '_SalesOfficeOrgUnit_2'
      SalesOfficeOrgUnitID,

      @ObjectModel.foreignKey.association: '_SalesGroupOrgUnit_2'
      SalesGroupOrgUnitID,

      @ObjectModel.foreignKey.association: '_ServiceOrganizationOrgUnit_2'
      ServiceOrganization,

      //Status

      cast( case _SrvcContrStatus.StatusCode
      when 'I1002' then 'X'
      else ' '
      end       as   xfeld preserving type     )                                     as ServiceContractIsNew,
      cast( case _SrvcContrStatus.StatusCode
      when 'I1003' then 'X'
      else ' '
      end      as   xfeld preserving type     )                                      as ServiceContractIsInProcess,
      cast( case _SrvcContrStatus.StatusCode
      when 'I1004' then 'X'
      else ' '
      end      as   xfeld preserving type     )                                      as ServiceContractIsReleased,
      cast( case _SrvcContrStatus.StatusCode
      when 'I1005' then 'X'
      else ' '
      end     as   xfeld preserving type     )                                       as ServiceContractIsCompleted,
      ServiceDocumentStatus                                                          as ServiceContractStatus,
      ServiceDocBillingStatus                                                        as SrvcContrBillingStatus,
      SrvcDocRejectionStatus,
      @Semantics.booleanIndicator
      ServiceDocumentHasError                                                        as ServiceContractHasError,
      SrvcDocTransferStatus,
      SrvcDocCreditStatus                                                            as SrvcContrCreditStatus,


      // GTS Embargo Status

      @ObjectModel.foreignKey.association: '_SrvcDocGTSEmbargoStatus'
      SrvcDocGTSEmbargoStatus,

      // GTS Screening Status

      @ObjectModel.foreignKey.association: '_SrvcDocGTSScreeningStatus'
      SrvcDocGTSScreeningStatus,

      // GTS Legal Control

      @ObjectModel.foreignKey.association: '_SrvcDocGTSLglControlStatus'
      SrvcDocGTSLglControlStatus,

      //Dates and Durations

      @Semantics.dateTime:true
      ServiceContractStartDateTime,
      @Semantics.dateTime:true
      ServiceContractEndDateTime,
      SrvcContrEarliestStartDateTime,
      SrvcContrLatestEndDateTime,
      cast( case ServiceDocumentCanclnParty
       when '' then 0
       else ServiceContractEndDateTime
       end as timestamp preserving type     )                                        as SrvcContrCancellationDateTime,

      // Pricing Fields

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocGrossAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      ServiceDocTaxAmount,
      PricingDocument,

      //Cancellation

      ServiceDocumentCanclnParty                                                     as ServiceContractCanclnParty,
      ServiceDocumentCanclnReason                                                    as ServiceContrCancellationReason,
      @ObjectModel.foreignKey.association: '_ServiceContractCanclnSts'
      ServiceContractCanclnSts,

      //Sales Fields

      PurchaseOrderByCustomer,
      CustomerPurchaseOrderDate,
      @ObjectModel.foreignKey.association: '_SrvcDocumentRejectionReason'
      ServiceDocumentRejectionReason                                                 as ServiceContractRejectionReason,

      //Reference Documents

      _ExtRefServiceContract.CustMgmtExtRefID                                        as SrvcContrExternalReference,
      _ExtRefServiceQtan.CustMgmtExtRefID                                            as ServiceQtanExtReference,
      _ExtRefLegalContract.CustMgmtExtRefID                                          as LegalContractExtReference,
      RefBusinessSolutionOrder,
      cast( _RefServiceTemplate.CustMgmtPrdcssrTransactionKey as crmt_object_id_db ) as RefServiceContractTemplate,
      _WBSElement.WBSElementExternalID,

      //Associations

      _ServiceContractItemTP,
      _SrvcContrPriceElementTP,

      _ServiceDocumentType,
      _ServiceObjType,

      _SoldToParty,
      _ShipToParty,
      _BillToParty,
      _PayerParty,
      _ContactPerson,
      _RespEmployee,

      _PaymentTerms,
      _PaymentMethod,
      _SrvcSEPAMandateRelevance,

      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _SalesOffice,
      _SalesGroup,
      _SrvcDocumentRejectionReason,

      _SalesOrganizationOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _SalesGroupOrgUnit_2,
      _ServiceOrganizationOrgUnit_2,
      _EnterpriseServiceOrg,

      _SrvcContrStatus,

      _SrvcDocGTSEmbargoStatus,
      _SrvcDocGTSScreeningStatus,
      _SrvcDocGTSLglControlStatus,

      _TransactionCurrency,

      _ExtRefServiceContract,
      _ExtRefServiceQtan,
      _ExtRefLegalContract,

      @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
      _ServiceContractCanclnSts,

      _SrvcContrPartnerTP,
      // _SrvcContrReferenceObjectTP,

      _SrvcContrUserStatusTP,
      _SrvcContrFUPBillgDocTP,
      _SrvcContrFUPSrvcOrdTP,
      _SrvcContrAppointmentTP,
      _SrvcContrDurationTP,
      _SrvcContrLongTextTP
      // _SrvcContrFUPBusSolnOrdTP





}
where
      ServiceObjectType           = 'BUS2000112'
  and ServiceDocumentTemplateType = ''