R_SalesOrderTextTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['SalesOrder', 'Language', 'LongTextID']

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@EndUserText.label: 'Sales Order - Text TP'

define view entity R_SalesOrderTextTP
 as select from P_SalesDocumentText( P_SAPClient : $session.client ) as SalesOrderText

    inner join   I_SalesDocumentBasic                                 as SalesDocumentBasic on  SalesDocumentBasic.SalesDocument      = SalesOrderText.SalesDocument
                                                                                            and SalesDocumentBasic.SDDocumentCategory = 'C'

    inner join   I_SalesDocumentType                                  as SalesDocumentType  on SalesDocumentBasic.SalesDocumentType = SalesDocumentType.SalesDocumentType


  association        to parent R_SalesOrderTP  as _SalesOrder           on  $projection.SalesOrder = _SalesOrder.SalesOrder

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBK'

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language
  association [0..1] to I_SDDocumentLongTextID        as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(SalesOrderText.SalesDocument as vdm_sales_order preserving type) as SalesOrder,

  key SalesOrderText.Language,

  key SalesOrderText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      SalesOrderText.LongTextID                                                 as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      SalesOrderText.Language                                                   as LanguageForEdit,
      
      @ObjectModel.virtualElement: true
      SalesOrderText.LongText,

      @Consumption.hidden: true
      SalesDocumentType.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem               as TextDeterminationProcedureItem,

      // For Access control

      @Consumption.hidden: true
      _SalesOrder.SalesOrderType,
      @Consumption.hidden: true
      _SalesOrder.SalesOrganization,
      @Consumption.hidden: true
      _SalesOrder.DistributionChannel,
      @Consumption.hidden: true
      _SalesOrder.OrganizationDivision,


      // Exposed associations

      _SalesOrder,
      _Language,
      _LongTextID
}