R_SalesOrderItemTextTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}
@ObjectModel.semanticKey: ['SalesOrder', 'SalesOrderItem', 'Language', 'LongTextID']

@Metadata.ignorePropagatedAnnotations: true

@AccessControl.authorizationCheck: #CHECK

@EndUserText.label: 'Sales Order Item - Text TP'

define view entity R_SalesOrderItemTextTP
as select from P_SalesDocumentItemText( P_SAPClient : $session.client ) as SalesOrderItemText 

  inner join   I_SalesDocumentItemBasic               as SalesDocumentItemBasic       on  SalesDocumentItemBasic.SalesDocument      = SalesOrderItemText.SalesDocument
                                                                                      and SalesDocumentItemBasic.SalesDocumentItem  = SalesOrderItemText.SalesDocumentItem
                                                                                      and SalesDocumentItemBasic.SDDocumentCategory = 'C'

  inner join   I_SalesDocumentItemCategory            as SalesDocumentItemCategory    on SalesDocumentItemCategory.SalesDocumentItemCategory = SalesDocumentItemBasic.SalesDocumentItemCategory

  association to parent R_SalesOrderItemTP     as _Item                        on  $projection.SalesOrder     = _Item.SalesOrder
                                                                               and $projection.SalesOrderItem = _Item.SalesOrderItem

  association [0..*] to I_TextDeterminationProcedItem as _TextDeterminationProcedItem on  $projection.TextDeterminationProcedure          = _TextDeterminationProcedItem.TextDeterminationProcedure
                                                                                      and $projection.LongTextID                          = _TextDeterminationProcedItem.LongTextID
                                                                                      and _TextDeterminationProcedItem.TextObjectCategory = 'VBBP'

  association [1..1] to R_SalesOrderTP         as _SalesOrder                         on  $projection.SalesOrder = _SalesOrder.SalesOrder

  association [0..1] to I_Language                    as _Language                    on  $projection.LanguageForEdit = _Language.Language

  association [0..1] to I_SDDocumentItemLongTextID    as _LongTextID                  on  $projection.LongTextIDForEdit = _LongTextID.LongTextID

{
  key cast(SalesOrderItemText.SalesDocument as vdm_sales_order preserving type)      as SalesOrder,

  key cast(SalesOrderItemText.SalesDocumentItem as sales_order_item preserving type) as SalesOrderItem,

  key SalesOrderItemText.Language,

  key SalesOrderItemText.LongTextID,

      @ObjectModel.foreignKey.association: '_LongTextID'
      SalesOrderItemText.LongTextID                                                  as LongTextIDForEdit,

      @ObjectModel.foreignKey.association: '_Language'
      SalesOrderItemText.Language                                                    as LanguageForEdit,
      
      @ObjectModel.virtualElement: true
      SalesOrderItemText.LongText,

      @Consumption.hidden: true
      SalesDocumentItemCategory.TextDeterminationProcedure,

      _TextDeterminationProcedItem.TextDeterminationProcedureItem                           as TextDeterminationProcedureItem,

      //    For Access control

      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesDocumentType                                              as SalesOrderType,
      @Consumption.hidden: true
      SalesDocumentItemBasic.OrganizationDivision,
      @Consumption.hidden: true
      SalesDocumentItemBasic.SalesOrganization,
      @Consumption.hidden: true
      SalesDocumentItemBasic.DistributionChannel,

      //     Exposed associations

      _Item,
      _SalesOrder,
      _Language,
      _LongTextID 
}