R_RecipeWithPrimaryOutput

@AbapCatalog.sqlViewName: 'RRCPWITHPO'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck:  #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE

@EndUserText.label: 'Recipe for Key Date with PO Data'
define view R_RecipeWithPrimaryOutput
  with parameters
    @Environment.systemField: #SYSTEM_DATE
    @Semantics.businessDate.at: true
    @Consumption.hidden: true
    P_KeyDate : sydate
  as select from I_RecipeForKeyDate( P_KeyDate: $parameters.P_KeyDate)            as rcp
    inner join   I_RecipeFormulaItemForKeyDate( P_KeyDate: $parameters.P_KeyDate) as formulaItem on  rcp.RecipeUUID              = formulaItem.RecipeUUID
                                                                                                 and formulaItem.RcpFmlaItemType = 'PO'
                                                                                                 and RecipeFmlaItemAltvIsUsed    = 'X'

  association [0..*] to I_ProductText             as _RecipePOMaterialText  on formulaItem.Material = _RecipePOMaterialText.Product
  association [0..*] to I_SpecSubstanceNatureText as _POSubstanceNatureText on $projection.RecipePrimOutpSubstNatr = _POSubstanceNatureText.SpecificationSubstanceNatr
{
      //    recipe

  key rcp.RecipeUUID,
      rcp.RecipeUniqueID,
      rcp.Recipe,
      rcp.RecipePrimaryOutputInternalID,
      rcp.RecipeAlternativeNumber,
      rcp.RecipeVersionNumber,
      rcp.RecipeCreatedByUser,
      rcp.RecipeCreationDateTime,
      rcp.RecipeLastChangedByUser,
      rcp.RecipeLastChangeDateTime,
      rcp.RecipeType,
      rcp.RecipePurpose,
      rcp.RecipeStatus,
      rcp.RecipeStatusSchema,
      rcp.RcpFmlaUUID,
      rcp.RecipeProcessUUID,
      rcp.RecipePropertySpecInternalID,
      rcp.RecipeIsDeleted,
      rcp.RecipeIsArchived,
      rcp.RecipeValidityStartDate,
      rcp.RecipeValidityEndDate,
      rcp.RecipeValidityMinQuantity,
      rcp.RecipeValidityMaxQuantity,
      rcp.RecipeValidityUnit,
      rcp.RecipeAuthorizationGroup,

      //    formulaItem

      formulaItem.RcpFmlaItemUUID,
      formulaItem.RcpFmlaItemType,
      formulaItem.RecipeFmlaItemAltvIsUsed,

      cast( rcp._PrimaryOutputSpecification( P_KeyDate:$session.system_date).SpecificationType  as /plmb/rcp_po_spec_type preserving type )                                    as RecipePrimOutpSpecType,

      //    product

      formulaItem.Material,
      cast(formulaItem.Material as /plmb/rcp_po_material preserving type )                                                                                                     as RecipePrimaryOutputMaterial,
      cast(_RecipePOMaterialText[Language=$session.system_language].ProductName as /plmb/rcp_po_material_name  )                                                               as RecipePrimOutputMaterialName,

      // PO substance nature

      cast( rcp._PrimaryOutputSpecification( P_KeyDate:$session.system_date).SpecificationSubstanceNatr as /plmb/rcp_po_substance_nature preserving type )                     as RecipePrimOutpSubstNatr,
      rcp._PrimaryOutputSpecification( P_KeyDate:$session.system_date)._SubstanceNature._SubstanceNatureText[Language=$session.system_language].SpecificationSubstanceNatrDesc as RecipePrimOutpSubstNatrDesc,

      /* Associations */
      //recipe


      rcp._CreatedByUser,
      rcp._LastChangedByUser,
      rcp._Plant,
      rcp._RecipeDescription,
      rcp._RecipePurpose,
      rcp._RecipeStatus,
      rcp._RecipeType,
      rcp._AuthorizationGroup,
      rcp._PrimaryOutputSpecification,
      rcp._FormulaForKeyDate,

      rcp._LogAccMObjectTypeActive,
      rcp._LogAccMObjectUserAuthzn,
      rcp._LogAccMObjSecureIDAssgmt,

      //product

      _RecipePOMaterialText,

      @Consumption.hidden: true
      _POSubstanceNatureText
}