R_QualityNotificationItemTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Quality Notification Item'

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
  },
  representativeKey: 'NotificationItem'
}

@Metadata.ignorePropagatedAnnotations: true

define view entity R_QualityNotificationItemTP
  as select from I_QualityNotificationItem

    association to parent R_QltyNotificationTP as _QltyNotification on $projection.QualityNotification = _QltyNotification.QualityNotification

    // Compositions to child nodes

    composition [0..*] of R_QltyNotifItemLongTextTP     as _QltyNotifItemLongText
    composition [0..*] of R_QltyNotificationItemCauseTP as _QltyNotificationItemCause

    // Extension

    association [1..1] to E_NotificationItem   as _Extension        on  $projection.QualityNotification = _Extension.Notification
                                                                    and $projection.NotificationItem    = _Extension.NotificationItem

{
      @ObjectModel.foreignKey.association: '_QltyNotification'
  key I_QualityNotificationItem.QualityNotification,
  key I_QualityNotificationItem.NotificationItem,

      I_QualityNotificationItem.NotificationItemExternalID,

      @Semantics.text: true
      I_QualityNotificationItem.NotificationItemText,
      cast( I_QualityNotificationItem.MasterLanguage as vdm_j_masterlanguage ) as MasterLanguage,
//      I_QualityNotificationItem.MasterLanguage,


      I_QualityNotificationItem.Assembly,
      I_QualityNotificationItem.DefectClass,
      I_QualityNotificationItem.NumberOfDefects,
      I_QualityNotificationItem.InspPlanOperationInternalID,
      I_QualityNotificationItem.InspectionCharacteristic,
      I_QualityNotificationItem.InspectionSubsetInternalID,
      I_QualityNotificationItem.MaterialSample,
      I_QualityNotificationItem.DefectiveSingleUnit,
      I_QualityNotificationItem.WorkCenterTypeCode,
      I_QualityNotificationItem.MainWorkCenterInternalID,
      I_QualityNotificationItem.MainWorkCenter,
      I_QualityNotificationItem.MainWorkCenterPlant,
      I_QualityNotificationItem.DefectOrigin,

      I_QualityNotificationItem.ReferencedDefect,

      @Semantics.booleanIndicator: true
      I_QualityNotificationItem.IsDeleted,

      // Codes

      I_QualityNotificationItem.DefectCodeCatalog,
      I_QualityNotificationItem.DefectCodeGroup,
      I_QualityNotificationItem.DefectCode,
      I_QualityNotificationItem.NotifItmObjectPartCodeCtlg,
      I_QualityNotificationItem.NotifItmObjectPartCodeGroup,
      I_QualityNotificationItem.NotifItmObjectPartCode,

      // Quantities

      @Semantics.quantity.unitOfMeasure: 'DefectiveQuantityUnit'
      I_QualityNotificationItem.ExternalDefectiveQuantity,
      @Semantics.quantity.unitOfMeasure: 'DefectiveQuantityUnit'
      I_QualityNotificationItem.InternalDefectiveQuantity,
//      @Semantics.quantity.unitOfMeasure: 'DefectiveQuantityUnit'

//      I_QualityNotificationItem.DefectiveQuantity,   // Only used by Defect application

      I_QualityNotificationItem.DefectiveQuantityUnit, // semantics annotation for UoM not allowed in view entities  



      // Admin Data

      @Semantics.user.createdBy: true
      I_QualityNotificationItem.CreatedByUser,
      @Semantics.systemDate.createdAt: true
      I_QualityNotificationItem.CreationDate,
      @Semantics.time: true
      I_QualityNotificationItem.CreationTime,
      @Semantics.user.lastChangedBy: true
      I_QualityNotificationItem.LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      I_QualityNotificationItem.LastChangeDate,
      @Semantics.time: true
      I_QualityNotificationItem.LastChangeTime,
      // I_QualityNotificationItem.ChangedDateTime,    // Only used by Defect application


      // Associations

      _QltyNotification,
      _QltyNotifItemLongText,
      _QltyNotificationItemCause,
      
      // For auth check mapping role

      I_QualityNotificationItem._Notification
}