R_PPS_PurOrdAcctAssignmentTP

@AccessControl.authorizationCheck: #MANDATORY
@AbapCatalog.viewEnhancementCategory: [#NONE]

@EndUserText.label: 'Purchase Order Account Assignment - TP'
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel: {
    usageType: {
      sizeCategory: #L,
      serviceQuality: #C,
      dataClass: #MASTER
    }
  }


@Metadata.ignorePropagatedAnnotations: true
define view entity R_PPS_PurOrdAcctAssignmentTP
  as select from I_PurOrdAccountAssignment

  association [1..1] to R_PPS_PurchaseOrderTP            as _PurchaseOrder             on  $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder

  association        to parent R_PPS_PurchaseOrderItemTP as _PurchaseOrderItem         on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                                       and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
  association [0..1] to I_CompanyCode                    as _CompanyCode               on  $projection.CompanyCode = _CompanyCode.CompanyCode
  //@JIRA-KEY<S4PPS-9276> - Start

  association [0..1] to I_Fund                           as _Fund                      on  _Fund.Fund                    = $projection.Fund
                                                                                       and _Fund.FinancialManagementArea = $projection.FinancialManagementArea
                                                                                       and _Fund.ValidityEndDate         > $session.system_date
  association [0..1] to I_FundsCenter                    as _FundsCenter               on  _FundsCenter.FundsCenter             = $projection.FundsCenter
                                                                                       and _FundsCenter.ValidityEndDate         > $session.system_date
                                                                                       and _FundsCenter.FinancialManagementArea = $projection.FinancialManagementArea

  association [1..1] to R_PPS_PurOrdAcctAssgmtExtn       as _AccAssignmentExtension    on  $projection.PurchaseOrder           = _AccAssignmentExtension.PurchaseOrder
                                                                                       and $projection.PurchaseOrderItem       = _AccAssignmentExtension.PurchaseOrderItem
                                                                                       and $projection.AccountAssignmentNumber = _AccAssignmentExtension.PPSPurgDocAcctAssgmtNumber

  association [0..*] to I_GLAccountText                  as _GLAccountText             on  $projection.GLAccount = _GLAccountText.GLAccount
                                                                                    //   and $projection.chartofaccounts = _GLAccountText.ChartOfAccounts

  //association [0..*] to I_CommitmentItemText             as _CommitmentItemDescription on  _CommitmentItemDescription.Language                = $session.system_language //Internal Incident: 2370136889

  //                                                                                   and _CommitmentItemDescription.CommitmentItem          = $projection.commitmentitem

  //                                                                                 and _CommitmentItemDescription.FinancialManagementArea = $projection.FinancialManagementArea


  //@JIRA-KEY<S4PPS-9276> - End

{
  key PurchaseOrder,
  key PurchaseOrderItem,
  key AccountAssignmentNumber,
      _PurchaseOrderItem.AccountAssignmentCategory,

      @Consumption.hidden: true
      PurchasingDocument,
      @Consumption.hidden: true
      PurchasingDocumentItem,

      CostCenter,
      //      _CostCenterText.CostCenterDescription,

      //      _GLAccountText.GLAccountLongName,

      //      _CostCenterActivityTypeText.CostCtrActivityTypeDesc,

      MasterFixedAsset,
      ProjectNetwork,
      cast( NetworkActivity as ps_s4_vornr preserving type )                                                  as NetworkActivity,

      @Consumption.hidden: true
      OrderQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      Quantity,
      MultipleAcctAssgmtDistrPercent,

      @Semantics.booleanIndicator: true
      cast (' ' as char1 )                                                                                    as IsMultipleAccountAssignment,


      //@Consumption.hidden: true

      DocumentCurrency,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      PurgDocNetAmount,
      IsDeleted,
      GLAccount,

      BusinessArea,
      SalesOrder,
      SalesOrderItem,
      SalesOrderScheduleLine,
      FixedAsset,
      OrderID,
      OrderOperation,
      UnloadingPointName,
      ControllingArea,
      CostObject,
      ProfitabilitySegment_2                                                                                  as ProfitabilitySegment,
      ProfitCenter,
      cast(  WBSElementInternalID as ps_s4_pspnr preserving type )                                            as WBSElementInternalID,
      WBSElementExternalID,
      ProjectNetworkInternalID,
      //CommitmentItem,

      _CommitmentItemShortID.CommitmentItem,
      CommitmentItemShortID,
      FundsCenter,
      Fund,

      FunctionalArea,
      @Consumption.hidden: true
      LastChangedDate,
      GoodsRecipientName,
      IsFinallyInvoiced,
      cast( REInternalFinNumber as recaimkeyfi preserving type )                                              as RealEstateObject,
      NetworkActivityInternalID,
      PartnerAccountNumber,
      JointVentureRecoveryCode,
      SettlementReferenceDate,
      OrderInternalID,
      OrderIntBillOfOperationsItem,
      TaxCode,
      TaxJurisdiction,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NonDeductibleInputTaxAmount,

      CostCtrActivityType,
      BusinessProcess,
      GrantID,

      BudgetPeriod,
      EarmarkedFundsDocument,
      // EarmarkedFundsItem,

      EarmarkedFundsDocumentItem,

      ValidityDate,

      //@JIRA-KEY<S4PPS-12976>

      //      cast ( hextobin( '00000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000000' ) as pps_e_control_flag preserving type ) as PPSFieldChangeIndicatorBinary,

      cast ( hextobin( _PurchaseOrder.PPSFieldChangeIndicatorString ) as pps_e_control_flag preserving type ) as PPSFieldChangeIndicatorBinary,

      //      @UI.hidden: true

      _CompanyCode.ChartOfAccounts,
      ServiceDocumentType,
      ServiceDocument,
      ServiceDocumentItem,
      _PurchaseOrderItem.HighestMessageSeverityLevel,
      CreationDate,
      IsAcctLineFinal,
      AcctLineFinalReason,
      @Consumption.hidden: true
      CompanyCode,
      //@JIRA-KEY S4PPS-8102

      //_PurchaseOrderItem.AccountAssignmentIsUnfunded,

      //      _PurchaseOrderItem.AccountAssignmentSmartNumber,

      _PurchaseOrder._CompanyCode.FinancialManagementArea                                                     as FinancialManagementArea,
      /* Associations */
      _BusinessArea,
      _BusinessAreaText,
      _BusinessProcess,
      _BusinessProcessText,
      _CommitmentItemShortID,
      //_CommitmentItemDescription,

      _CompanyCode,
      _ControllingArea,
      _CostCenter,
      _CostCenterActivityType,
      _CostCenterActivityTypeText,
      _CostCenterText,
      _FixedAssetWorklist,
      _FunctionalArea,
      _FunctionalAreaText,
      _GLAccount,
      _GLAccountText,
      _ProfitCenter,
      _ProfitCenterText,
      _PurchaseOrder,
      _PurchaseOrderItem,
      _SalesDocumentScheduleLine,
      _SalesOrder,
      _SalesOrderItem,
      _TaxCode,
      _TaxCodeText,
      _TaxJurisdiction,
      _TaxJurisdictionText,
      _WBSElement,
      _WBSElementByInternalKey,
      //@JIRA-KEY<S4PPS-9276> - Start

      _Fund,
      _FundsCenter,
      //@JIRA-KEY<S4PPS-9276> - End

      //_AccAssignmentExtension.AccountAssignmentIsUnfunded

      _AccAssignmentExtension.PPSAccountAssignmentIsUnfunded
}
where
      _PurchaseOrder.PurchaseOrder         is not null
  and _PurchaseOrderItem.PurchaseOrderItem is not null
  and I_PurOrdAccountAssignment.IsDeleted  <> 'L' // "@JIRA-KEY<S4PPS-9795>