R_POSubcontractingComponent

@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@AbapCatalog.sqlViewName: 'RMMPOSUBCOMP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Internal Basic View for PO Subcontracting Components'
define view R_POSubcontractingComponent
  as select from R_PurgDocSubcontrgComponent
    inner join   I_PurchaseOrder on R_PurgDocSubcontrgComponent.PurchasingDocument = I_PurchaseOrder.PurchaseOrder


  association [1..1] to I_PurchaseOrder           as _PurchaseOrder     on  $projection.PurchaseOrder = _PurchaseOrder.PurchaseOrder
  association [1..1] to I_PurchaseOrderItem       as _PurchaseOrderItem on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                        and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
  association [1..1] to I_PurOrdScheduleLineBasic as _ScheduleLine      on  $projection.PurchaseOrder             = _ScheduleLine.PurchaseOrder
                                                                        and $projection.PurchaseOrderItem         = _ScheduleLine.PurchaseOrderItem
                                                                        and $projection.PurchaseOrderScheduleLine = _ScheduleLine.PurchaseOrderScheduleLine

{


      @ObjectModel.foreignKey.association: '_PurchaseOrder'
  key PurchasingDocument     as PurchaseOrder,
      @ObjectModel.foreignKey.association: '_PurchaseOrderItem'
  key PurchasingDocumentItem as PurchaseOrderItem,
      @ObjectModel.foreignKey.association: '_ScheduleLine'
  key ScheduleLine           as PurchaseOrderScheduleLine,
  key ReservationItem,
  key RecordType,
  
      Reservation,
      Material,
      BaseUnit,
      RequiredQuantity,
      RequirementDate,
      RequirementTime,
      Plant,
      LatestRequirementDate,
      OrderLevelValue,
      OrderPathValue,
      BillOfMaterialItemNumber,
      SortField,
      BOMItemCategory,
      MaterialComponentIsPhantomItem,
      IsBulkMaterialComponent,
      AccountAssignmentCategory,
      InventorySpecialStockType,
      ConsumptionPosting,
      InventorySpecialStockValnType,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'MaterialProvisionType'
      IsMaterialProvision,
      MaterialProvisionType,
      DebitCreditCode,
      ReservationIsFinallyIssued,
      QuantityInEntryUnit,
      EntryUnit,
      MaterialQtyToBaseQtyNmrtr,
      MaterialQtyToBaseQtyDnmntr,
      WithdrawnQuantity,
      QuantityIsFixed,
      ComponentScrapInPercent,
      OperationScrapInPercent,
      IsNetScrap,
      LeadTimeOffset,
      QuantityDistributionKey,
      MaterialRevisionLevel,
      MaterialCompIsVariableSized,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'VariableSizeItemQuantity'
      cast(NumberOfVariableSizeComponents as pph_roanz preserving type) as NumberOfVariableSizeComponents,
      VariableSizeItemQuantity,
      VariableSizeItemUnit,
      VariableSizeComponentUnit,
      VariableSizeComponentQuantity,
      UnitOfMeasureForSize1To3,
      Size1,
      Size2,
      Size3,
      FormulaKey,
      StorageLocation,
      ProductionSupplyArea,
      Batch,
      BOMItemDescription,
      BOMItemText2,
      ChangeNumber,

      _PurchaseOrder,
      _PurchaseOrderItem,
      _ScheduleLine,
      _Material,
      _Product,
      _VariableSize1To3Unit,
      _VariableSizeCompUnit,
      _BaseUnit,
      _EntryUnit
}